衝突判定

衝突判定 †

[編集]

衝突判定

シューティングといえばやっぱりこれが無いと。
　

↑

サンプル †

[編集]

いきなりサンプルです。ならうより慣れろということで…？

以下のサンプルでは自機との衝突判定を行います。判定は次の組み合わせが対象です。
- 矩形と矩形
- 矩形と線分

操作方法：キーボードのカーソルキーを使ってください。

衝突判定サンプル

st_sample01.as

 
;
;	衝突判定サンプル(v.2.61)
;
;矩形同士の判定、矩形と線分の判定を行います。
;
 
 
;#################################################################################
;
;	判定とかもろもろのモジュール
;
 
#module
 
;----------------------------------------
;矩形の枠のみを描画する
;	パラメータはboxfと同じ
#deffunc boxl int, int, int, int
    mref x1, 0
    mref y1, 1
    mref x2, 2
    mref y2, 3
 
    line x1, y1, x2, y1
    line x2, y1, x2, y2
    line x2, y2, x1, y2
    line x1, y2, x1, y1
    return
 
;----------------------------------------
;矩形と矩形との衝突判定
;mgetcoli_bb p1, p2[, p3]
;	矩形限定です。bbはBoxとBoxの略。
;	配列変数の中は、矩形の対角２点の座標が(x1,y1)-(x2,y2)だった場合、
;		p1.0 = x1
;		p1.1 = y1
;		p1.2 = x2
;		p1.3 = y2
;	としてください。（boxfのパラメータをそのまま順に配列にしするだけです。）
;	p2も同様です。
;	p3に0以外を指定すると、対角２点の位置関係を無視して処理します。0のときこれを考慮します。
;	statに判定結果が返されます。
;		0 : 衝突していない
;		1 : 衝突している
#deffunc mgetcoli_bb val, val, int
    mref bp1, 48    ;判定座標（矩形の対角点を2点）
    mref bp2, 49    ;判定座標
    mref fsw, 2        ;スワップフラグ
    mref outstat, 64
    outstat = 0
 
    dim bpsw,4,2    ;bp1,bp2を書き換えないための処置
    memcpy bpsw, bp1, 16
    memcpy bpsw, bp2, 16, 16
    if fsw {
        ;強制的に左上-右下座標になるよう入れ替えます。
        repeat 2
            if bpsw.0.cnt>bpsw.2.cnt : bpsw.0.cnt+=bpsw.2.cnt : bpsw.2.cnt=bpsw.0.cnt-bpsw.2.cnt : bpsw.0.cnt-=bpsw.2.cnt
            if bpsw.1.cnt>bpsw.3.cnt : bpsw.1.cnt+=bpsw.3.cnt : bpsw.3.cnt=bpsw.1.cnt-bpsw.3.cnt : bpsw.1.cnt-=bpsw.3.cnt
        loop
    }
    ; 自分の四隅が対象より外でなければ当たっている（外にいれば１となるので!で否定しています）
    ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    if (bpsw.0.0>bpsw.2.1) | (bpsw.2.0<bpsw.0.1) | (bpsw.1.0>bpsw.3.1) | (bpsw.3.0<bpsw.1.1) ! 1 : outstat=1
    return
 
 
;----------------------------------------
;矩形と線分の衝突判定
;	矩形限定です。blはBoxとLineの略。
;mgetcoli_bl p1, x1, y1, x2, y2
;	p1:矩形の対角２点を指定した配列変数。(p1.0～p1.3)
;	線分の両端座標：(x1, y1) - (x2, y2)
;	statに判定結果が返されます。
;		0 : 衝突していない
;		1 : 衝突している
#deffunc mgetcoli_bl val, int, int, int, int
    mref crpos, 48    ;判定座標
    mref x1, 1    ;ライン両端
    mref y1, 2
    mref x2, 3
    mref y2, 4
    mref outstat, 64
    outstat = 0
 
    ;線分の範囲内に矩形が存在するかチェック
    dim crpos2, 4
    crpos2 = x1, y1, x2, y2
    mgetcoli_bb crpos, crpos2, 1
    if stat=0 : return
 
    ;４点のラインに対する位置をチェック
    ht = 0
    a = crpos.0 : b1 = crpos.1 : b2 = crpos.3
    gosub *hantei
    a = crpos.2 : b1 = crpos.1 : b2 = crpos.3
    gosub *hantei
 
    ;当たり判定
    if (ht=4)|(ht=-4) {
        outstat = 0        ;全て一致（はずれている）
    } else {
        outstat = 1        ;どれかひとつでも一致しなかった（重なっている）
    }
 
    return
 
*hantei
    if x1!x2 {
        ;x座標がaの時の直線のy座標(bb)を求める。
        ;bb = ( (y1-y2)*a + (x1*y2)-(x2*y1) ) / (x1-x2)
        bb = y1-y2*a + (x1*y2)-(x2*y1) / (x1-x2)
        ;x座標が同じ2点が線に対して上にあるか下にあるか調べる。
        if bb>b1 : ht += -1    ;上（線より）
        if bb<b1 : ht += 1    ;下
        if bb>b2 : ht += -1    ;上（線より）
        if bb<b2 : ht += 1    ;下
    } else {
        if x1>a : ht += -1    ;左
        if x1<a : ht += 1    ;右
    }
    return
 
#global
;#################################################################################
 
;
;	初期化
;
title "衝突判定サンプル"
;自機
#define JIKIMV 3    ;自機の移動量
dim intJikiPos, 2    ;自機の場所
dim intJikiHitA, 2    ;自機の当たり判定サイズ
dim hanteiA, 4
intJikiPos = winx/2, winy/2
intJikiHitA = 30, 40
 
;敵
dim intTekiA, 4
intTekiA = 50,50, 100,100
 
;レーザー
dim lz, 4    ;ライン座標（始点と終点）
lz = winx/2, 100, 0, winy-100
dlz = 1
 
 
;
;	メイン
;
*main
    redraw 0
    ;
    ;	画面の初期化
    ;
    color 255,255,255 : boxf : color 0,0,0
 
    ;
    ;	移動処理
    ;
    stick key, 255
    gosub *keiinput
 
    ;レーザーの移動
    if lz.2>=winx : dlz = -1
    if lz.2<=0 : dlz = 1
    lz.2+= dlz*3
 
    ;
    ;	衝突判定
    ;
    fhit = 0    ;判定フラグ
    ;自機とレーザーの衝突判定
    hanteiA = intJikiPos.0, intJikiPos.1, intJikiPos.0 + intJikiHitA.0, intJikiPos.1 + intJikiHitA.1
    mgetcoli_bl hanteiA, lz.0, lz.1, lz.2, lz.3
    if stat : fhit = 1
    ;自機と敵との衝突判定と敵の描画
    mgetcoli_bb hanteiA, intTekiA, 1
    if stat : fhit = 1
    ;自機と領域との衝突判定と領域描画
    ff=200,50,winx-100,30
    mgetcoli_bb ff, hanteiA
    if stat : fhit = 1
 
    ;
    ;	オブジェクト描画
    ;
    ;レーザー描画
    line lz.0, lz.1, lz.2, lz.3
    pos lz.0-32, lz.1-16 : mes "レーザー"
    ;敵描画
    boxl intTekiA.0, intTekiA.1, intTekiA.2, intTekiA.3        ;敵の衝突領域
    pos intTekiA.0, intTekiA.1 : mes "敵"
    ;領域描画
    boxl ff.0, ff.1, ff.2, ff.3
 
    ;自機の衝突判定領域を描画
    if fhit=1 : color 255,0,0
    boxl hanteiA.0, hanteiA.1, hanteiA.2, hanteiA.3
    pos hanteiA.0, hanteiA.1 : mes "自機"
 
    redraw 1
    await 5
goto *main
 
stop
 
 
 
;###########################
;サブルーチン
;###########################
 
;キー入力
*keiinput
    if key&1 : addx = -JIKIMV
    if key&2 : addy = -JIKIMV
    if key&4 : addx =  JIKIMV
    if key&8 : addy =  JIKIMV
    if key&128 : end
 
    ;自機移動量設定
    intJikiPos.0+= addx
    intJikiPos.1+= addy
    addx = 0 : addy = 0
 
return

[hsp3] こちらに投稿されたものです。

衝突判定サンプル

;
;	衝突判定サンプル(v.2.61)
;	勝手に Ver 3.x 化 by inovia
;
;矩形同士の判定、矩形と線分の判定を行います。
;
 
 
;#################################################################################
;
;	判定とかもろもろのモジュール
;
 
#module
 
;----------------------------------------
;矩形の枠のみを描画する
;	パラメータはboxfと同じ
#deffunc boxl int x1, int y1, int x2, int y2
 
    line x1, y1, x2, y1
    line x2, y1, x2, y2
    line x2, y2, x1, y2
    line x1, y2, x1, y1
    return
 
;----------------------------------------
;矩形と矩形との衝突判定
;mgetcoli_bb p1, p2[, p3]
;	矩形限定です。bbはBoxとBoxの略。
;	配列変数の中は、矩形の対角２点の座標が(x1,y1)-(x2,y2)だった場合、
;		p1.0 = x1
;		p1.1 = y1
;		p1.2 = x2
;		p1.3 = y2
;	としてください。（boxfのパラメータをそのまま順に配列にしするだけです。）
;	p2も同様です。
;	p3に0以外を指定すると、対角２点の位置関係を無視して処理します。0のときこれを考慮します。
;	statに判定結果が返されます。
;		0 : 衝突していない
;		1 : 衝突している
#deffunc mgetcoli_bb var bp1, var bp2, int fsw
 
    outstat = 0
 
    dim bpsw,4,2    ;bp1,bp2を書き換えないための処置
    memcpy bpsw, bp1, 16
    memcpy bpsw, bp2, 16, 16
    //dialog
    if fsw {
        ;強制的に左上-右下座標になるよう入れ替えます。
        repeat 2
            if bpsw.0.cnt>bpsw.2.cnt : bpsw.0.cnt+=bpsw.2.cnt : bpsw.2.cnt=bpsw.0.cnt-bpsw.2.cnt : bpsw.0.cnt-=bpsw.2.cnt
            if bpsw.1.cnt>bpsw.3.cnt : bpsw.1.cnt+=bpsw.3.cnt : bpsw.3.cnt=bpsw.1.cnt-bpsw.3.cnt : bpsw.1.cnt-=bpsw.3.cnt
        loop
    }
    ; 自分の四隅が対象より外でなければ当たっている（外にいれば１となるので!で否定しています）
    ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    if ((bpsw.0.0>bpsw.2.1) | (bpsw.2.0<bpsw.0.1) | (bpsw.1.0>bpsw.3.1) | (bpsw.3.0<bpsw.1.1)) ! 1 : outstat=1
    return outstat
 
 
;----------------------------------------
;矩形と線分の衝突判定
;	矩形限定です。blはBoxとLineの略。
;mgetcoli_bl p1, x1, y1, x2, y2
;	p1:矩形の対角２点を指定した配列変数。(p1.0～p1.3)
;	線分の両端座標：(x1, y1) - (x2, y2)
;	statに判定結果が返されます。
;		0 : 衝突していない
;		1 : 衝突している
#deffunc mgetcoli_bl array crpos, int x1, int y1, int x2, int y2
 
    outstat = 0
 
    ;線分の範囲内に矩形が存在するかチェック
    dim crpos2, 4
    crpos2 = x1, y1, x2, y2
    mgetcoli_bb crpos, crpos2, 1
    if stat=0 : return outstat
 
    ;４点のラインに対する位置をチェック
    ht = 0
    a = crpos.0 : b1 = crpos.1 : b2 = crpos.3
    gosub *hantei
    a = crpos.2 : b1 = crpos.1 : b2 = crpos.3
    gosub *hantei
 
    ;当たり判定
    if (ht=4)|(ht=-4) {
        outstat = 0        ;全て一致（はずれている）
    } else {
        outstat = 1        ;どれかひとつでも一致しなかった（重なっている）
    }
 
    return outstat
 
*hantei
    if x1!x2 {
        ;x座標がaの時の直線のy座標(bb)を求める。
        ;bb = ( (y1-y2)*a + (x1*y2)-(x2*y1) ) / (x1-x2)
        bb = ((y1-y2)*a + (x1*y2)-(x2*y1)) / (x1-x2)
        ;x座標が同じ2点が線に対して上にあるか下にあるか調べる。
        if bb>b1 : ht += -1    ;上（線より）
        if bb<b1 : ht += 1    ;下
        if bb>b2 : ht += -1    ;上（線より）
        if bb<b2 : ht += 1    ;下
    } else {
        if x1>a : ht += -1    ;左
        if x1<a : ht += 1    ;右
    }
    return
 
#global
;#################################################################################
 
;
;	初期化
;
title "衝突判定サンプル"
;自機
#define JIKIMV 3    ;自機の移動量
dim intJikiPos, 2    ;自機の場所
dim intJikiHitA, 2    ;自機の当たり判定サイズ
dim hanteiA, 4
intJikiPos = ginfo_winx/2, ginfo_winy/2
intJikiHitA = 30, 40
 
;敵
dim intTekiA, 4
intTekiA = 50,50, 100,100
 
;レーザー
dim lz, 4    ;ライン座標（始点と終点）
lz = ginfo_winx/2, 100, 0, ginfo_winy-100
dlz = 1
 
 
;
;	メイン
;
*main
    ;title ""+fhit
    redraw 0
    ;
    ;	画面の初期化
    ;
    color 255,255,255 : boxf : color 0,0,0
 
    ;
    ;	移動処理
    ;
    stick key, 255
    gosub *keiinput
 
    ;レーザーの移動
    if lz.2>=ginfo_winx : dlz = -1
    if lz.2<=0 : dlz = 1
    lz.2+= dlz*3
 
    ;
    ;	衝突判定
    ;
    fhit = 0    ;判定フラグ
    ;自機とレーザーの衝突判定
    hanteiA = intJikiPos.0, intJikiPos.1, intJikiPos.0 + intJikiHitA.0, intJikiPos.1 + intJikiHitA.1
    mgetcoli_bl hanteiA, lz.0, lz.1, lz.2, lz.3
    if stat : fhit = 1
    ;自機と敵との衝突判定と敵の描画
    mgetcoli_bb hanteiA, intTekiA, 1
    if stat : fhit = 1
    ;自機と領域との衝突判定と領域描画
    ff=200,50,ginfo_winx-100,30
    mgetcoli_bb ff, hanteiA
    if stat : fhit = 1
 
    ;
    ;	オブジェクト描画
    ;
    ;レーザー描画
    line lz.0, lz.1, lz.2, lz.3
    pos lz.0-32, lz.1-16 : mes "レーザー"
    ;敵描画
    boxl intTekiA.0, intTekiA.1, intTekiA.2, intTekiA.3        ;敵の衝突領域
    pos intTekiA.0, intTekiA.1 : mes "敵"
    ;領域描画
    boxl ff.0, ff.1, ff.2, ff.3
 
    ;自機の衝突判定領域を描画
    if fhit=1 : color 255,0,0
    boxl hanteiA.0, hanteiA.1, hanteiA.2, hanteiA.3
    pos hanteiA.0, hanteiA.1 : mes "自機"
 
    redraw 1
    await 5
goto *main
 
stop
 
 
 
;###########################
;サブルーチン
;###########################
 
;キー入力
*keiinput
    if key&1 : addx = -JIKIMV
    if key&2 : addy = -JIKIMV
    if key&4 : addx =  JIKIMV
    if key&8 : addy =  JIKIMV
    if key&128 : end
 
    ;自機移動量設定
    intJikiPos.0+= addx
    intJikiPos.1+= addy
    addx = 0 : addy = 0
 
return

↑

アルゴリズム †

[編集]

↑

線分と線分 †

[編集]

→Math/線分同士の公差判定

↑

矩形と矩形 †

[編集]

「対角２点がもう片方の対角２点の外側にない場合、衝突している」としています。
矩形の対角２点は通常、左上座標 - 右下座標として処理されます。
あえて左下座標 - 右上座標のように指定すると通常とは異なる衝突判定を行います。
（例：レーザーの上にある領域）
p3に1を指定すると対角２点が、左上座標 - 右下座標でなくても左上座標 - 右下座標としたときと同様の判定を行います。
p3に1が指定された場合、配列内の順番を左上座標 - 右下座標になるよう入れ替えています。

関連ページ：当たり判定モジュール

[hsp3]

矩形同士の衝突判定

#module
;矩形描写モジュール
#deffunc rectangle int x, int y, int w, int h
    line x+w, y, x, y : line x+w, y+h : line x, y+h : line x, y
    return
#global
ex = 200 : ey = 150 : ew = 150 : eh = 150;設置された矩形（ｘ座標、ｙ座標、矩形の幅、矩形の高さ）
px = 0 : py = 0 : pw = 100 : ph = 100;操作する矩形（上と同じ）
*main
    stick key, 15
    if key & 1{ px-- }
    if key & 2{ py-- }
    if key & 4{ px++ }
    if key & 8{ py++ }
    redraw 0
    color 255, 255, 255 : boxf : color
    ;衝突判定（矩形同士が接触すると色が変わる）
    if px<ex+ew & px+pw>ex & py<ey+eh & py+ph>ey{ color 255 }    
    rectangle ex, ey, ew, eh
    rectangle px, py, pw, ph
    redraw 1
    await 1
    goto *main

↑

矩形と線分 †

[編集]

矩形の四隅が線分の上にあるか下にあるかを調べ、全て同じ側にあれば衝突していません。
１つでも違うものがあれば線分をまたいでいます。
線分を対角線とした矩形領域内に自機が入っていなければ、線分と自機の衝突はありません。
スクリプト中の式は直線の式y=ax+bです。線分の両端２点が分かっているので連立方程式を解けば導くことが出来ます。

↑

円と円（おまけ） †

[編集]

円の中心どうしの距離を求め、それが半径の和以下ならば衝突しています。半径の和より大きければ衝突していません。

[hsp3]

円同士の衝突判定

par=50;操作する円の半径
cx=300 : cy=200 : car=100;設置された円のｘ座標、ｙ座標、半径
*main
    px=mousex : py=mousey
    redraw 0
    color 255, 255, 255 : boxf
    color 0, 255
    ;設置円描写
    circle cx-car, cy-car, cx+car, cy+car
    if powf(cx-px, 2)+powf(cy-py, 2) <= powf(car+par, 2){
        color 255
    }else{
        color 0, 0, 255
    }
    ;操作円描写（円同士がぶつかると色が変わる）
    circle px-par, py-par, px+par, py+par
    redraw
    await 1
    goto *main

↑

円と直線（おまけ） †

[編集]

点と直線の距離を求める公式（Math/Basic参照）を使う。
円と直線の距離を求め、それが円の半径以下ならば衝突しています。

円と線分の場合、中心から線分に垂線が引けるとは限らないので判定がややこしくなります。

[hsp3]

円と直線の衝突判定

 
 
 
 
 
 
 
 
 
 
-
|
|
|
|
|
|
|
|
!
 
 
 
 
 
 
 
 
-
|
-
|
!

#include"hspdef.as"
;円の情報、左上座標と半径
ax = 100 : ay = 100
ar = 30; radius : 半径
;上と同様、直線の情報、傾き角度と直線上の一座標
bx = 0 : by = ginfo_winy/2
b_theta = deg2rad(0)
gosub *draw
repeat
    stick key, 15;入力受付
    if 0<key & key<=15{
        redraw 0;ちらつき防止用
        if ( key & 1 ) : ax --
        if ( key & 2 ) : ay --
        if ( key & 4 ) : ax ++
        if ( key & 8 ) : ay ++
        gosub *draw
        ;直線上の一点から見た円の中心座標ベクトル
        redraw 1;ここで描画
    }
    await 1
loop
*draw
    color : boxf;画面クリア
    color 0, 255, 0
    ;直線描画
    line int(640.0 * cos(b_theta)) + bx, int(640.0 * sin(b_theta)) + by, bx, by
    cx = ax+ar-bx : cy = ay+ar-by
    if ( absf( sin(b_theta) * cx - cos(b_theta) * cy ) <= ar ) {
        color 255, 255, 0
    }else{
        color 255, 0, 0
    }
    ;円描画
    circle ax, ay, ar * 2 + ax, ar * 2 + ay
    return

↑

拡張 †

[編集]

拡張性皆無なスクリプトになってしまいました…orz

矩形と矩形
- 矩形にしか使えません…。しかも斜めに回転した矩形とかはダメ。

矩形と線分
- 線分との衝突判定を利用すれば、多角形図形の判定に使えそうですが…重くならないかな？
  いやすでに重いのかも…。
- 放物線などの曲線ではどうするんだろう。同じことやっても衝突しない場合が出てくるし。例えば曲線の凸の部分が四隅の間を通って矩形内に入ることも考えられる。直線と曲線の判定をするのかな？うーめんどくさい。(-_-lll

処理速度がどうなってるか分からないので…プラグインを探して使ったほうが早くて扱いやすいと思います。(^ ^;
よいアイデアありましたら修正お願いします。

↑

一般化への挑戦 †

[編集]

モジュールからmgetcoli_blの一部変更とivouter2dを追加することで一般化への1stステップ。
これなら直線で構成された形状なら何でも対応可能なはずです。
処理の内容は、線分に対して各点が右にいるか左にいるかで判断します。

右にいるか左にいるかの判断には外積を用います。
使い方：上のモジュールから「mgetcoli_bl」命令の部分を削除して下の命令２つを入れてください。

モジュール

 ;	for HSP 2.61
 
 ;----------------------------------------
 ;ベクトル外積(2D版)
 ;fvouterみたいなもんです（2次元用）
 ;結果はstatに返されます。
 #deffunc ivouter2d val, int, int
     mref iv, 48
     mref xv, 1
     mref yv, 2
     mref ostat, 64
 
     ostat = (iv.0*yv) - (iv.1*xv)
 
     return
 
 
 ;----------------------------------------
 ;矩形と線分の衝突判定
 ;	矩形限定です。blはBoxとLineの略。
 ;mgetcoli_bl p1, x1, y1, x2, y2
 ;	p1:矩形の対角２点を指定した配列変数。(p1.0～p1.3)
 ;	線分の両端座標：(x1, y1) - (x2, y2)
 ;	statに判定結果が返されます。
 ;		0 : 衝突していない
 ;		1 : 衝突している
 #deffunc mgetcoli_bl val, int, int, int, int
     mref crpos, 48    ;判定座標
     mref x1, 1    ;ライン両端
     mref y1, 2
     mref x2, 3
     mref y2, 4
     mref outstat, 64
     outstat = 0
 
     ;線分の範囲内に矩形が存在するかチェック
     dim crpos2, 4
     crpos2 = x1, y1, x2, y2
     mgetcoli_bb crpos, crpos2, 1
     if stat=0 : return
 
 
     ;４点のラインに対する位置をチェック
     dim intLine,3
     intLine = x2-x1, y2-y1, 0    ;線分ベクトル化
     ht = 0
     repeat 2
         i = cnt*2
         j=0
         repeat 2
             j = cnt*2+1
             ;比較点が線分の左右どちらがわにあるかを調べます。
             ivouter2d intLine, crpos.i-x1, crpos.j-y1
             if stat>0 : ht++ : else : ht--
         loop
     loop
 
     ;当たり判定
     if (ht=4)|(ht=-4) {
         outstat = 0        ;全て一致（はずれている）
     } else {
         outstat = 1        ;どれかひとつでも一致しなかった（重なっている）
     }
 
     return
 
 ;*hantei～returnは削除

公式板でレーザーの話が出たので、（判定の話じゃなかったのですが）レーザーの衝突判定を作ってみたくなったので作ってみました。
今回思いつきと勢いで作成したもので、人のスクリプトとか調べてません。もっと効率のいいやり方あるかもしれませんのでいい方法があったら適当に書き換えてくださいませ…m(_ _;)m -- GENKI? 2005-09-11 02:12:12 (日)

皆さん気づかれているかと思いますが、僕は実際にゲームは作ったことありません＾＾；なので考え方は思いつくが実装法はそんなにバリバリ書けるってわけじゃないんですよねぇ・・・；；
GENKIさんのスクリプトを読んで図に書いていろいろ追ってますよ。で矩形と矩形の衝突チェックだけ自分なりの方法できたのでコメントつけておきます＾＾
mgetcoli_bb命令の定義内の「２点間で重なるかで判断」の処理を変えて、「対象となる範囲に自分がいなければいなければ当たっている」という考えのもと作った部分ソースがこんな感じです。

 /*
	;２点間が重なるかで判断
	if (bp1.0>bp2.0)&(bp1.0>bp2.2) & (bp1.2>bp2.0)&(bp1.2>bp2.2) !1 : fb++
	if (bp1.0<bp2.0)&(bp1.0<bp2.2) & (bp1.2<bp2.0)&(bp1.2<bp2.2) !1 : fb++
	if (bp1.1>bp2.1)&(bp1.1>bp2.3) & (bp1.3>bp2.1)&(bp1.3>bp2.3) !1 : fb++
	if (bp1.1<bp2.1)&(bp1.1<bp2.3) & (bp1.3<bp2.1)&(bp1.3<bp2.3) !1 : fb++
	if fb=4 : outstat = 1
	return
 */
    ; 自分の四隅が対象より外でなければ当たっている（外にいれば１となるので!で否定しています）
    ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    if (bp1.0>bp2.2) | (bp1.2<bp2.0) | (bp1.1>bp2.3) | (bp1.3<bp2.1) ! 1 : outstat=1
    return

これで出来てるハズ･･･。今度は矩形vs線を追います＾＾ -- kz3 2005-09-11 12:23:27 (日)

サンクス。でも残念これじゃだめっス。
矩形の対角点はからなず左上・右下座標で指定するとは限らないからです。右上・左下座標で指定するかもしれない。
これは実際にレーザーが左側にきたときに衝突しない現象で確認できます。
それで先に左上・右下座標になるように並べ替えて（ソートして）おくべきだったかなーと。
…しまったboxfはマニュアルでは左上、右下座標だった。説明まずいや。 -- GENKI? 2005-09-11 14:24:08 (日)
はい、気づきました。そこは線分処理側の最初に対角線をなす矩形を渡すときに座標変換して渡すとか･･･ -- kz3 2005-09-11 15:09:16 (日)
あ、並べ替えてって書いてましたね＾＾；失礼･･･矩形処理は他とそろえて左上座標-右下座標にしたほうがいいですよね -- kz3 2005-09-11 15:12:23 (日)
重ねてサンクスです。スクリプト差し替えました。左上座標-右下座標になるよう並び替えるオプションをつけました。
あえて左上座標-右下座標にしていない場合も考慮する形になりました。利用方法がいまいちないけど。^ ^; -- GENKI? 2005-09-11 17:45:16 (日)
なんか凄そうなので読んでみようと思います。 -- kz3 2005-09-17 09:18:20 (土)

↑

楕円と点 †

[編集]

楕円は２焦点から外周までの距離の合計が一定と言う性質を持っています。
そこで、２焦点から任意座標までの距離を算出することで、それが一定値以下なら楕円の内側、一定値以上なら外側として判定できます。
[hsp3]

楕円と点の衝突判定

 
 
 
 
 
 
 
 
 
 
-
|
|
|
|
!
-
|
|
|
|
!

#module
;焦点座標を求める
;楕円（ellipse）
;焦点（focal point）
#deffunc ellipsefp double ea, double eb, var efpx1, var efpy1, var efpx2, var efpy2, var fpln
;ea	:中心からのxサイズ（長半径か短半径）
;eb	:中心からのyサイズ（長半径か短半径）
;efpx1,efpy1	:焦点座標[duble]
;efpx2,efpy2	:焦点座標[duble]
;fpln	:２焦点から楕円外周までの距離（２つの合計）[duble]
    if ea >= eb {
        d = ea*ea - eb*eb
        efpx1 =  sqrt(d) : efpy1 = 0.0
        efpx2 = -sqrt(d) : efpy2 = 0.0
        fpln = ea * 2
    }
    if eb > ea {
        d = eb*eb - ea*ea
        efpx1 = 0.0 : efpy1 =  sqrt(d)
        efpx2 = 0.0 : efpy2 = -sqrt(d)
        fpln = eb * 2
    }
    return
 
#global
;###########################################################
 
 
ddim ellab, 2
ddim ellc, 2, 2
ddim mpos, 2
ellab = 100.0, 50.0
cx = ginfo_winx/2
cy = ginfo_winy/2
 
*main
    redraw 1 : await 16 : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
 
    ;マウス座標取得
    mpos = mousex, mousey
 
    ;焦点座標
    ellipsefp ellab(0), ellab(1),  ellc(0,0),ellc(1,0),  ellc(0,1),ellc(1,1), elll
 
    ;マウスと焦点までの距離合計
    ln =  sqrt( (ellc(0,0)+cx-mpos(0))*(ellc(0,0)+cx-mpos(0)) + (ellc(1,0)+cy-mpos(1))*(ellc(1,0)+cy-mpos(1)) )
    ln += sqrt( (ellc(0,1)+cx-mpos(0))*(ellc(0,1)+cx-mpos(0)) + (ellc(1,1)+cy-mpos(1))*(ellc(1,1)+cy-mpos(1)) )
 
 
    ;
    ;	描画処理
    ;
    pos 0,0
 
    if ln<=elll : mes "衝突" : color 255
 
    ;楕円描画
    circle cx-ellab(0), cy-ellab(1),  cx+ellab(0), cy+ellab(1), 0
    ;焦点座標
    r=3
    circle ellc(0,0)-r+cx, ellc(1,0)-r+cy,  ellc(0,0)+r+cx, ellc(1,0)+r+cy
    circle ellc(0,1)-r+cx, ellc(1,1)-r+cy,  ellc(0,1)+r+cx, ellc(1,1)+r+cy
 
    ;マウスと焦点を結ぶ直線
    line mpos(0), mpos(1), ellc(0,0)+cx, ellc(1,0)+cy
    line ellc(0,1)+cx, ellc(1,1)+cy
 
    goto *main

↑

楕円と楕円 †

[編集]

簡単にできそうで、意外にに難問です。

ちなみに検索すると解法が見つかります。
http://marupeke296.com/COL_2D_No7_EllipseVsEllipse.html
見つかりますが、よく分かりませんでした。＿|￣|○

そこで、もう少しいい加減にやってみることにします。

マウスのほうの楕円が半径1.0の円になるように縦横比を変換。
円と楕円の判定という形にします。
楕円の方を外側に1.0だけ膨らませればいいのですが、難しいので単純に半長軸と半短軸に＋1.0します。（この方法では1.0より近い場所も出てくるので正確さを求めることが出来ません。）
短径/長径が小さいと誤差が出やすいようです

ともかくこれで点と楕円の判定という形になりました。
あとは「楕円と点」で書いた方法で判定します。

[hsp3]

楕円と楕円の衝突判定

#module
;焦点座標を求める
;楕円（ellipse）
;焦点（focal point）
#deffunc ellipsefp double ea, double eb, var efpx1, var efpy1, var efpx2, var efpy2, var fpln
;ea	:中心からのxサイズ（長半径か短半径）
;eb	:中心からのyサイズ（長半径か短半径）
;efpx1,efpy1	:焦点座標[duble]
;efpx2,efpy2	:焦点座標[duble]
;fpln	:２焦点から楕円外周までの距離（２つの合計）[duble]
    if ea >= eb {
        d = ea*ea - eb*eb
        efpx1 =  sqrt(d) : efpy1 = 0.0
        efpx2 = -sqrt(d) : efpy2 = 0.0
        fpln = ea * 2
    }
    if eb > ea {
        d = eb*eb - ea*ea
        efpx1 = 0.0 : efpy1 =  sqrt(d)
        efpx2 = 0.0 : efpy2 = -sqrt(d)
        fpln = eb * 2
    }
    return
 
#global
;#############################################################
 
ddim ellab, 2    ;半長軸、半短軸
ddim ellc, 2, 2    ;焦点座標
ellab = 100.0, 50.0    ;正にしておく
cx = ginfo_winx/2
cy = ginfo_winy/2
 
;マウス座標の楕円
dim mpos, 2        ;マウス座標
dim ellmab, 2
ellmab = 70, 20
dim ellmc, 2, 2
 
;計算用
ddim dellab, 2    ;半長軸、半短軸
ddim dellc, 2, 2    ;焦点座標
ddim dmpos, 2        ;マウス座標
 
*main
    redraw 1 : await 16 : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
 
    ;マウス座標取得
    mpos = mousex, mousey
 
    dellab = double( ellab(0)) , double( ellab(1) )    ;計算用変数に対象円の値をコピー
    dmpos = double(mpos(0)), double(mpos(1))
    ;マウス円を半径1.0の円になるよう変形する。
    repeat 2
        dellab(cnt) /= ellmab(cnt)
        dellab(cnt) += 1.0
        dmpos(cnt) /= ellmab(cnt)
    loop
    dcx = double(cx) / ellmab(0)    ;楕円中心座標
    dcy = double(cy) / ellmab(1)
 
    ;焦点座標
    ellipsefp dellab(0), dellab(1),  dellc(0,0),dellc(1,0),  dellc(0,1),dellc(1,1), delll
 
    ;マウスと焦点までの距離合計
    ln =  sqrt( (dellc(0,0)+dcx-dmpos(0))*(dellc(0,0)+dcx-dmpos(0)) + (dellc(1,0)+dcy-dmpos(1))*(dellc(1,0)+dcy-dmpos(1)) )
    ln += sqrt( (dellc(0,1)+dcx-dmpos(0))*(dellc(0,1)+dcx-dmpos(0)) + (dellc(1,1)+dcy-dmpos(1))*(dellc(1,1)+dcy-dmpos(1)) )
 
    ;衝突判定
    ;	マウスと楕円の焦点との距離で比較する
    if ln<=delll : mes "衝突" : color 255
 
    ;デバッグ用
/*
	r = 1.0
	d = 10
	circle (dcx-dellab(0))*d, (dcy-dellab(1))*d,  (dcx+dellab(0))*d, (dcy+dellab(1))*d, 0
	circle (dcx-dellab(0)+1.0)*d, (dcy-dellab(1)+1.0)*d,  (dcx+dellab(0)-1.0)*d, (dcy+dellab(1)-1.0)*d, 0
	circle (dmpos(0)-r)*d, (dmpos(1)-r)*d,  (dmpos(0)+r)*d, (dmpos(1)+r)*d, 0
*/
 
    ;焦点座標
    if ellab(0) > ellab(1) {
        ellc(0,0) =  int(sqrt(ellab(0)*ellab(0) - ellab(1)*ellab(1))), 0
        ellc(0,1) = -int(sqrt(ellab(0)*ellab(0) - ellab(1)*ellab(1))), 0
    }
    if ellab(1) > ellab(0) {
        ellc(0,0) = 0,  int(sqrt(ellab(1)*ellab(1) - ellab(0)*ellab(0)))
        ellc(0,1) = 0, -int(sqrt(ellab(1)*ellab(1) - ellab(0)*ellab(0)))
    }
 
 
    ;
    ;	描画処理
    ;
 
    ;楕円描画
    circle cx-ellab(0), cy-ellab(1),  cx+ellab(0), cy+ellab(1), 0
    circle mpos(0)-ellmab(0), mpos(1)-ellmab(1),  mpos(0)+ellmab(0), mpos(1)+ellmab(1), 0
    ;焦点座標
    r=3
    circle ellc(0,0)-r+cx, ellc(1,0)-r+cy,  ellc(0,0)+r+cx, ellc(1,0)+r+cy
    circle ellc(0,1)-r+cx, ellc(1,1)-r+cy,  ellc(0,1)+r+cx, ellc(1,1)+r+cy
 
    ;マウスと焦点を結ぶ直線
    line mpos(0), mpos(1), ellc(0,0)+cx, ellc(1,0)+cy
    line ellc(0,1)+cx, ellc(1,1)+cy
 
    goto *main

このスクリプトの場合、短径/長径が近い２つの楕円の判定であれば、小さい誤差で判定できます。

↑

WinAPIを使用する †

[編集]

IntersectRect?を使用したものです。

当たり判定

;for HPS3
;	矩形-矩形の当たり判定
;	（と接触領域の取得）
;
 
#uselib "user32.dll"
#func IntersectRect "IntersectRect" var,var,var
 
    dim b1,4
    dim b2,4
    dim bir,4
 
    b1 = ginfo_winx/2-50,ginfo_winy/2-50, ginfo_winx/2+50,ginfo_winy/2+50
    b2 = 150,150,250,250
 
 
*main
    redraw 1 : await 16 : redraw 0
    color 255,255,255 : boxf : color 0,0,0
 
    b2 = mousex,mousey,mousex+100,mousey+100
    IntersectRect bir,b1,b2    ;当たり判定
        if stat=1 : hit = "当たり" : else : hit = "衝突していない"
 
    color 255,0,0
    boxf b1.0,b1.1, b1.2,b1.3
    color 0,255,0
    boxf b2.0,b2.1, b2.2,b2.3
 
    color 0,0,0 : pos 0,0
    mes "IntersectRect : " + hit
    mes ""+bir.0+", "+bir.1+" - "+bir.2+", "+bir.3
    color 255,255,0
    boxf bir.0,bir.1, bir.2,bir.3
 
    goto *main

↑

対応する四辺が平行な矩形同士の交差判定 †

[編集]

対応する四辺が平行な矩形同士の交差判定
上のコメントでkz3さんが書いていることの補足説明。

添付ファイル:

st_sample01.as 804件 [詳細]

OFFICIAL/関連

TUTORIAL

TOPICS

ETC

EDIT

REFERENCE

LOG

お知らせ

HSP Web-Ring

最新の40件

衝突判定 †

サンプル †

st_sample01.as

アルゴリズム †

線分と線分 †

矩形と矩形 †

矩形と線分 †

円と円（おまけ） †

円と直線（おまけ） †

拡張 †

一般化への挑戦 †

楕円と点 †

楕円と楕円 †

WinAPIを使用する †

対応する四辺が平行な矩形同士の交差判定 †