ノートパッド⇔文字列配列変換、操作モジュール

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155

#module multi_str_array str_array,count,index
    #modinit int size
    // インスタンス作成。文字列配列str_arrayを、大きさsizeの一次元配列で確保
        sdim str_array,128,size
        count = 0:index = 0
        return
    #modfunc secure_at_multi_str_array int size
    //	文字列配列str_arrayを確保しなおす
        sdim str_array,128,size
        count = 0:index = 0
        return
        
//	getterとsetter
    #modfunc get_count_at_multi_str_array var to_ret
    //	モジュール変数countの値をto_retに代入して取得
        to_ret = count
        return
    #modfunc set_youso_at_multi_str_array str to_set,int _index
    //	文字列配列str_arrayの_indexの要素へto_setを代入
    //	要素がcountより大きい場合、代入は行わず、statに-1を代入
        if _index > count{return -1}
        str_array._index = to_set
        return 1
    #modfunc get_youso_at_multi_str_array var to_ret,int _index
    //	文字列配列str_arrayの_indexの要素をto_getに代入して取得
    //	要素がcountより大きい場合、to_retに空文字列を代入して、statに-1を代入
        if _index > count{to_ret="":return -1}
        to_ret = str_array._index
        return 1
        
//	文字列のpushとpop
    #modfunc push_youso_at_multi_str_array str to_push
    //	文字列配列str_arrayに引数として受け取ったto_pushの値を追加
        str_array.count = to_push
        count++
        return
    #modfunc pop_youso_at_multi_str_array var to_pop
    //	文字列配列str_arrayの最後の要素を変数to_popに代入して取得
    //	文字列配列str_arrayの最後の要素は空文字列になる（削除のつもり）
        count--
        to_pop = str_array.count
        str_array.count = ""
        return
        
//	ノートパッド関連命令を改造した命令
    #modfunc array2note_at_multi_str_array var note_str
    //	文字列配列str_arrayを配列じゃない文字列変数note_strに展開
        note_str = ""
        if count >= 1{note_str+=str_array.0}
        repeat (count-1),1
            note_str+="\n"+str_array.cnt
        loop
        return
    #modfunc note2array_at_multi_str_array var note_str
    //	文字列変数note_strをノートパッド命令の対象にして
    //	文字列配列str_arrayにコピー。配列の大きさをcountに確保
        notesel note_str
        count = notemax
        if notemax > length(str_array){sdim str_array,128,notemax}
        repeat notemax
            noteget str_array.cnt, cnt
        loop
        noteunsel
        return
    #modfunc arraysave_at_multi_str_array str p_file_name,local p_str_tmp
    //	モジュール変数（配列）を連結してファイルに保存します
    //	複数行文字列に変換して保存します
        array2note_at_multi_str_array thismod,p_str_tmp
        notesel p_str_tmp
        notesave p_file_name
        noteunsel
        return
    #modfunc arrayload_at_multi_str_array str p_file_name,local p_str_tmp
    //	テキストファイルをモジュール変数（配列）に読み込みます
    //	読み込んだ複数行文字列の各行を配列要素に変換します
        notesel p_str_tmp
        noteload p_file_name
        noteunsel
        note2array_at_multi_str_array thismod,p_str_tmp
        return
 
//	ノートパッド命令を使用した、要素の追加、削除、及び
//	命令の初期処理と終了処理
 
//	begin_add_or_del_at_multi_str_array命令を呼び出して
//	その中で、noteselを使っていて
//	finish_add_or_del_at_multi_str_array命令の中で
//	noteunselを使用しているので
//	begin_add_or_del_at_multi_str_array命令を呼び出してから
//	finish_add_or_del_at_multi_str_array命令のを呼び出すまで
//	notesel命令でノートパッド命令の対象を変更しないで下さい
//	notesel命令でノートパッド命令の対象を変更したい時は
//	一度、finish_add_or_del_at_multi_str_array命令を使用して、追加、削除を終了して
//	また、追加、削除したい時に、begin_add_or_del_at_multi_str_array命令を呼び出して下さい
 
    #modfunc begin_add_or_del_at_multi_str_array
    //	ノートパッドにモジュール変数（配列）を出力して
    //	それに、要素の追加用にノートパッド命令の対象にする
    //	noteadd_at_multi_str_array命令、及び
    //	notedel_at_multi_str_array命令を呼び出す前に使用する
        sdim var_of_inner2note,4096
        array2note_at_multi_str_array thismod,var_of_inner2note
        notesel var_of_inner2note
        return
    #modfunc noteadd_at_multi_str_array str to_add,int index_to_add,int mode_to_add
    //	ノートパッドに要素を追加する
        noteadd to_add,index_to_add,mode_to_add
        return
    #modfunc notedel_at_multi_str_array int index_to_del
    //	ノートパッドから要素を削除する
        notedel index_to_del
        return
    #modfunc finish_add_or_del_at_multi_str_array
    //	ノートパッドの対象を配列に展開する
    //	noteadd_at_multi_str_array命令、及び
    //	notedel_at_multi_str_array命令で、要素の追加、削除
    //	を行った後に呼び出す
        count = notemax
        if notemax > length(str_array){sdim str_array,128,notemax}
        repeat notemax
            noteget str_array.cnt, cnt
        loop
        sdim var_of_inner2note,1        
        noteunsel
        return
 
    
//	文字列連続出力用の命令
    #modfunc output_begin_at_multi_str_array
    //	文字列連続出力の準備
        index = 0
        if count <= 0 { return -1 }
        return 1
    #modfunc output_at_multi_str_array var to_ret
    //	文字列連続出力命令
        if index >= count { return -1 }
        to_ret = str_array.index
        index++
        return 1
 
//	デバッグ用命令
    #modfunc logmes_at_multi_str_array
    //	文字列配列str_arrayの値をログ出力（デバッグ用）
        logmes "count = "+count
        repeat count
            logmes str_array.cnt
        loop
        return
    #modfunc print_at_multi_str_array
    //	文字列配列str_arrayの値を出力（デバッグ用）
        repeat count
            mes str_array.cnt
        loop
        return 
#global

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58

#include "multi_str_array.hsp"
 
//	note2array_at_multi_str_array のテスト
//	get_count_at_multi_str_array  のテスト
    s="ふるいけや\nかわずとびこむ\nみずのおと"
    newmod haiku,multi_str_array,5
    note2array_at_multi_str_array haiku,s
    c = 0
    get_count_at_multi_str_array haiku,c
    mes c
 
//	array2note_at_multi_str_array のテスト
//	set_youso_at_multi_str_array  のテスト
    t=""
    array2note_at_multi_str_array haiku,t
    print_at_multi_str_array haiku
    mes "t:"+t
    set_youso_at_multi_str_array haiku,"古池や",0
    mes "stat:"+stat
    set_youso_at_multi_str_array haiku,"作：松尾芭蕉",10
    mes "stat:"+stat
    print_at_multi_str_array haiku
 
//	get_youso_at_multi_str_array のテスト
    u=""
    get_youso_at_multi_str_array haiku,u,1
    mes "stat:"+stat
    mes "u:"+u
    get_youso_at_multi_str_array haiku,u,10
    mes "stat:"+stat
    mes "u:"+u
    print_at_multi_str_array haiku
    logmes_at_multi_str_array haiku
 
//	push_youso_at_multi_str_array のテスト
//	pop_youso_at_multi_str_array  のテスト
    pos 200,0
    push_youso_at_multi_str_array haiku,"作：松尾芭蕉"
    print_at_multi_str_array haiku
    logmes_at_multi_str_array haiku
    v=""
    pop_youso_at_multi_str_array haiku,s4
    mes "v:"+v
    print_at_multi_str_array haiku
    logmes_at_multi_str_array haiku
 
//	output_begin_at_multi_str_array のテスト
//	output_at_multi_str_array のテスト
    pos 400,0
    w=""
    output_begin_at_multi_str_array haiku
    if stat==1{output_at_multi_str_array haiku,w}
    while stat==1
        mes w
        output_at_multi_str_array haiku,w
        await 1
    wend
    stop

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50

#include "multi_str_array.hsp"
 
 
//	arraysave_at_multi_str_array のテスト
    s="ふるいけや\nかわずとびこむ\nみずのおと"
    newmod haiku,multi_str_array,5
    note2array_at_multi_str_array haiku,s
    arraysave_at_multi_str_array haiku,"tmp.txt"
    s=""
    notesel s
    noteload "tmp.txt"
    mes s
    mes ""
    noteadd "水の音",2,1
    notesave "tmp.txt"
 
//	arrayload_at_multi_str_array のテスト
    arrayload_at_multi_str_array haiku,"tmp.txt"
    u=""
    output_begin_at_multi_str_array haiku
    if stat==1{output_at_multi_str_array haiku,u}
    while stat==1
        mes u
        output_at_multi_str_array haiku,u
        await 1
    wend
 
//	begin_add_or_del_at_multi_str_array のテスト
//	noteadd_at_multi_str_array のテスト
//	finish_add_or_del_at_multi_str_array のテスト
    begin_add_or_del_at_multi_str_array haiku
    noteadd_at_multi_str_array haiku,"begin:",0,1
    noteadd_at_multi_str_array haiku,"ふ\nる\nい\nけ\nや",1,0
    finish_add_or_del_at_multi_str_array haiku
    pos 200,0
    v=""
    array2note_at_multi_str_array haiku,v
    mes v
    
//	notedel_at_multi_str_array のテスト
    begin_add_or_del_at_multi_str_array haiku
    notedel_at_multi_str_array haiku,0
    notedel_at_multi_str_array haiku,5
    finish_add_or_del_at_multi_str_array haiku
    pos 400,0
    w=""
    array2note_at_multi_str_array haiku,w
    mes w
    
    stop