便利ツール/hsed3/ライトフラットバー

ライトフラットバー †

[編集]

ライト(お手軽)フラットバーは、キャレットの行(line)しか表示されないHSPエディタのステータスバーに重なるようにして表示される編集情報バーです。

ライトフラットバー

↑

インストールとアンインストール †

[編集]

インストールはhsp31b7でスクリプトをコンパイルし、実行ファイルを作成するだけです。
実行ファイルをエディタのスタートアップに登録すると起動と同時にライトフラットバーが起動して便利です。
アンインストールは実行ファイルを削除するだけです。

↑

確認のとれている動作環境 †

[編集]

hsp3.1b7以上(必須)
WindowsXP HE SP2

↑

機能と仕様 †

[編集]

キャレットの桁(col)と行(row)を表示する。(rowとlineは同等です)
編集中のスクリプトのサイズを表示する。
改行コードの種類を表示する。
hspコンパイラのバージョンを表示する。
メニュー選択時にメニューの説明を表示することが出来ない。

↑

スクリプト †

[編集]

スクリプトを読む

hsed_infobar6.hsp

;
; 編集情報を表示するライトフラットバーをエディタにくっつける
;
#include "hsedsdk.as"
#include "gdi32.as"
#include "user32.as"
#include "kernel32.as"
 
//-------------------------------------
//  実行ファイル自動作成パラメータ
//-------------------------------------
#packopt name "hsed_infobar"
#packopt hide 1
#packopt runtime "runtime/hsp3c.hrt"
 
#const HWND_FLAT  0
#const HWND_ABOUT 2
 
#define HEADER    "Light FlatBar ver.0.6\n\n"
#define FOOTER    "for HSP script editor powered by \"hsedsdk.as\"\n"+\
                  "created by kz3"
 
//-------------------------------------
//  このスクリプトで用いる命令・関数
//-------------------------------------
#module
#uselib "user32.dll"
#func _wsprintf "wsprintfA" var, str, var
#deffunc ClientToClient int hw_from, var v2, int hw_to
  ClientToScreen hw_from, varptr(v2)
  ScreenToClient hw_to, varptr(v2)
  return
#defcfunc rcequal var v1, var v2
  EqualRect varptr(v1), varptr(v2)
  return stat
#defcfunc strfs str p1, int p2, local s, local r
  s = p1: sdim r, strlen(s)+abs(p2)+1
  _wsprintf r, "%"+p2+"s", s
  return r
#defcfunc getinfo int p1, int p2, int p3, str p4
  return strf(" col : %-10d",p1)+strf(", row : %-10d",p2)+strf(", size : %-10d",p3)+", "+strfs(p4,-10)
#global
 
//-------------------------------------
//  アプリケーションの準備
//-------------------------------------
  ; 多重起動防止(v4->v5)
  ; スタートアップに失敗して手動で起動させたときの対策
  CreateMutex 0, 0, "hsed_infobar": hMutex = stat
  GetLastError: errcode = stat
  if errcode = 183 {
    if hMutex: CloseHandle hMutex: hMutex = 0
    end
  }
 
  ; 必要なウィンドウハンドルを取得
  ; 関連付けしたファイルからの起動でタイミングにより失敗することがあるため
  ; ウェイトをかける(v4->v5)
  ; ウェイト方法を変更(v5->v6)
  FindWindow "onipad", 0: if stat = 0: end
  repeat
    wait 1
    hsed_exist: if stat {
      hIF = hIF@hsedsdk
      break
    }
  loop
  sendmsg hIF, HSED_GETWND, HGW_STATUSBAR, 0  : hStatus = stat
  sendmsg hIF, HSED_GETWND, HGW_MAIN, 0       : hMain   = stat
 
  ; 初期データ
  LoadIcon 0, 32516: hIcon = stat       ; IDI_ASTERISK
  cr_type = "","CRLF","CR","LF","AUTO"  ; 改行コードリスト
  pcx = -1: pcy = -1: psize = -1: pcr = 0
  newRect = 0, 0, 0, 0
  oldRect = -1, -1, -1, -1
  dim rcText, 4
 
//-------------------------------------
//  ライト(お手軽)フラットバーの作成
//-------------------------------------
  GetClientRect hStatus, varptr(newRect)        ; ステータスバーの大きさ(高さ)を取得
  bgscr HWND_FLAT, ginfo_dispx, newRect.3, 2    ; ウィンドウをデスクトップ幅いっぱいに広げる
  hFlatbar = hwnd                               ; フラットバーのハンドルを保存しておく
 
  ; フラットバーをメインウィンドウの子にする
  ClientToClient hStatus, newRect, hMain        ; クライアント座標の変換
 
  GetWindowLong hwnd, $FFFFFFF0: dwStyle = stat
  dwStyle = dwStyle & $80000000 ^ dwStyle       ; - WS_POPUP
  dwStyle = dwStyle | $40000000                 ; + WS_CHILD
  SetWindowLong hwnd, $FFFFFFF0, dwStyle
 
  ; エディタのメインウィンドウをオーナーにする(v1->v2)
  SetWindowLong hwnd, $FFFFFFF8, hMain
  SetParent hwnd, hMain
  MoveWindow hwnd, newRect.0, newRect.1, newRect.2, newRect.3, 1
 
//-------------------------------------
//  トップレベルのウィンドウに送られるメッセージを受け取るための
//  バージョン情報ウィンドウを作る(v4->v5)
//-------------------------------------
  screen HWND_ABOUT, 320, 140, 2+4: hAbout = hwnd
  title "バージョン情報"
  GetWindowLong hwnd, $FFFFFFF0: dwStyle = stat
  dwStyle = dwStyle & $00080000 ^ dwStyle       ; - WS_SYSMENU
  SetWindowLong hwnd, $FFFFFFF0, dwStyle
  SetWindowLong hwnd, $FFFFFFF8, hFlatbar       ; オーナーはフラットバー
  SetWindowPos hwnd, 0, 0, 0, 0, 0, $0027
 
  objsize 100: pos (ginfo_winx-100)/2, ginfo_winy - 24 - 10
  button gosub "OK", *about_ok                  ; ダイアログを閉じるボタン
  sendmsg objinfo(stat,2), $000000F4, $01, -1   ; 枠の太いボタンに変更
  objsel 0
 
  ; コンパイラのバージョンを取得(v3->v4)
  hsed_initduppipe: if stat: end
  sendmsg hIF, HSED_GETVER, HGV_HSPCMPVER, hDupWritePipe@hsedsdk
  if stat > 0 {
    retsize = stat
    sdim hsp_ver, retsize
    ReadFile@hsedsdk hReadPipe@hsedsdk, hsp_ver, retsize, retsize2, 0
    ; 取得した情報は加工しない(v4->v5)
  }
  else {
    hsp_ver = "HSP script preprocessor Undefined version" ; 未定義
  }
  hsed_uninitduppipe
 
  ; バージョン情報をあらかじめ用意
  about =   HEADER
  about +=  FOOTER
 
  gosub *DrawAbout
 
  ; メッセージ割り込み設定(v4->v5)
  oncmd gosub *ON_SETFOCUS,       $00000007
  oncmd gosub *ON_SETTINGCHANGE,  $0000001A
  oncmd gosub *ON_SYSCOLORCHANGE, $00000015
 
  onclick gosub *OnAboutDialog  ; フラットバーを右クリックでダイアログ表示(v2->v3)
  onkey gosub *about_ok_key     ; キー割り込みでダイアログを閉じる
 
  SetActiveWindow hMain         ; エディタをアクティブにする(v0->v1)
  SetFocus hMain                ; エディタのフォーカスを当てる(v1->v2)
 
//-------------------------------------
//  メインループ
//  割り込み発生後はメインループに戻ってくる
//-------------------------------------
  repeat
 
    wait 10
 
    ; ステータスバーとフラットバーの表示状態の同期をとる
    IsWindowVisible hStatus
    if stat = 0: gsel HWND_FLAT, -1: else: ShowWindow hFlatbar, 8
 
    ; 現在のウィンドウの位置を取得
    GetClientRect hStatus, varptr(newRect): if stat = 0: break
    ClientToClient hStatus, newRect, hMain
 
    ; エディタの大きさが以前から変わっているかどうか
    if rcequal( newRect, oldRect ) = 0 {
 
      ; 新しい大きさを保存
      CopyRect varptr(oldRect), varptr(newRect)
 
      ; フラットバーの位置を合わせる
      MoveWindow hFlatbar, newRect.0, newRect.1, newRect.2, newRect.3, 1
 
      ; 古い情報のテキストを整形
      info = getinfo( pcx, pcy, psize, cr_type(pcr) )
      gosub *DrawFlatbar
 
    }
 
    sendmsg hIF, HSED_GETCARETVPOS, -1, 0:  cx    = stat
    sendmsg hIF, HSED_GETCARETLINE, -1, 0:  cy    = stat
    sendmsg hIF, HSED_GETTEXTLENGTH,-1, 0:  size  = stat
    sendmsg hIF, HSED_GETLINECODE,  -1, 0:  cr    = stat
 
    ; 編集内容に変更があるかどうか
    if( pcx ! cx ) | ( pcy ! cy ) | ( psize ! size ) | ( pcr ! cr ) {
 
      ; 新しい情報を保存
      pcx = cx: pcy = cy: psize = size: pcr = cr
 
      CopyRect varptr(newRect), varptr(oldRect)
 
      ; 新しい情報のテキストを整形
      info = getinfo( cx, cy, size, cr_type(cr) )
      gosub *DrawFlatbar
 
    }
 
  loop
 
  if hMutex: CloseHandle hMutex: hMutex = 0
  end
 
//-------------------------------------
//  フラットバーの描画
//-------------------------------------
*DrawFlatbar
  gsel HWND_FLAT
  redraw 0
    ClientToClient hMain, newRect, hStatus
    DrawFrameControl hdc, varptr(newRect), 3, 0x0008
  
    CopyRect varptr(rcText), varptr(newRect)
  
    ; ヘルプアイコン描画(v2->v3)
    iconsize = rcText.3-4
    DrawIconEx hdc, rcText.0+2, (rcText.3-iconsize)/2, hIcon, iconsize, iconsize, 0, 0, 3
  
    ; 描画時にフォントとカラーを設定する(v1->v2)
    syscolor 18: sysfont 17
    rcText.0 = rcText.3: rcText.2 -= rcText.3
    DrawText hdc, varptr(info), -1, varptr(rcText), $00008024
  redraw 1
  return
 
//-------------------------------------
// バージョン情報を描画(v4->v5)
//-------------------------------------
*DrawAbout
  gsel HWND_ABOUT
  redraw 0
    syscolor 15: boxf
    syscolor 18: sysfont 17
  
    GetSystemMetrics $0000000B: cxIcon = stat
    GetSystemMetrics $0000000C: cyIcon = stat
  
    DrawIconEx hdc, 10, 10, hIcon, cxIcon, cyIcon, 0, 0, 3
  
    pos 20+cxIcon, 10
    mes about
 
    syscolor 21: line ginfo_winx, ginfo_cy+10, 0, ginfo_cy+10
    syscolor 20: line ginfo_winx, ginfo_cy+1,  0, ginfo_cy+1
    syscolor 18
    pos 20+cxIcon
    mes ""
    mes "on " + hsp_ver
  redraw 1
  return
  
//-------------------------------------
// 右クリックでダイアログ表示(v2->v3)
//-------------------------------------
*OnAboutDialog
  if ginfo_act = HWND_ABOUT: return
  if wparam = 2 {
    CopyRect varptr(rcText), varptr(newRect)
    ClientToClient hMain, rcText, hStatus
    rcIcon = rcText.0+2, (rcText.3-iconsize)/2, rcIcon.0+iconsize, rcIcon.1+iconsize
    PtInRect varptr(rcIcon), lparam & $ffff, lparam>>16 & $ffff
    if stat {
 
      ; dialogは音が鳴るので自分でダイアログをつくる(v4->v5)
      gsel HWND_FLAT
      dx = ginfo_wx1 + ( lparam & $ffff )     ; クリックしたディスプレイ座標
      dy = ginfo_wy1 + ( lparam>>16 & $ffff ) ; クリックしたディスプレイ座標
      gsel HWND_ABOUT
      width 320, 140, dx, dy-ginfo_sizey      ; ダイアログ左下の角に合わせる
 
      EnableWindow hMain, 0
      gsel HWND_ABOUT, 1
 
    }
  }
  return
 
//-------------------------------------
//  ダイアログを閉じる
//-------------------------------------
*about_ok
  ; エディタを有効にしてからダイアログを非表示にする
  EnableWindow hMain, 1
  gsel HWND_ABOUT, -1
  return
 
*about_ok_key
  if ginfo_act ! HWND_ABOUT: return
  if wparam = $0d {
    ; EnterキーでOKクリック
    gosub *about_ok
  }
  return
 
//-------------------------------------
//  メッセージ割り込み
//-------------------------------------
*ON_SETFOCUS
  gsel HWND_ABOUT: objsel 0
  return
 
// やっぱり必要(v4->v5)
*ON_SETTINGCHANGE
*ON_SYSCOLORCHANGE
  ; 最後に描画した内容で描画しなおす
  gosub *DrawFlatbar
  gosub *DrawAbout
  return

↑

コメント †

[編集]

GWL_STYLEが定義されていなかったのを修正し、フラットバーをクリックするとエディタが非アクティブになるのを改善しました。(v1->v2) -- kz3 2007-03-11 (日) 20:11:32
実行するまでどのバージョンのエディタなのか分からないという要望があったので、(そのエディタが使用する)コンパイラのバージョンを表示するようにしました。常に見えていたほうがいいかなと...。 -- kz3 2007-03-13 (火) 23:47:17
v6にて一度に多くのファイル・大きいファイルを読み込んだ時も失敗しないように改善されました。(HSP3WishList?:177) -- kz3 2007-03-16 (金) 01:27:09

添付ファイル:

hsed_infobar6.hsp 289件 [詳細]

便利ツール/hsed3/ライトフラットバー

OFFICIAL/関連

TUTORIAL

TOPICS

ETC

EDIT

REFERENCE

LOG

お知らせ

HSP Web-Ring

最新の40件

ライトフラットバー †

インストールとアンインストール †

確認のとれている動作環境 †

機能と仕様 †

スクリプト †

hsed_infobar6.hsp

コメント †