小ワザ/マップ移動

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
-
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

#const BODYSIZE        16   ; 移動キャラクターの体の大きさ
#const WAITTIME        16   ; メインループ待ち時間[ms]
#const WINX            300  ; ウィンドウサイズ（横）
#const WINY            300  ; ウィンドウサイズ（縦）
 
#enum  BACKGROUNDCOLOR = 0  ; 背景の色
#enum  BODYCOLOR            ; キャラクターの色
 
    x = 0 : y = 0           ; キャラクター位置を初期化
 
// *** ウィンドウとパレットの初期化 **********************************
    screen 0, WINX, WINY, 1
 
    palette BACKGROUNDCOLOR , 255 , 255 , 255
    palette BODYCOLOR       , 255 ,   0 ,   0, 1
 
    palcolor BACKGROUNDCOLOR
    boxf 0, 0, WINX, WINY   ; 背景色で塗りつぶし
 
    gosub *drawSquare       ; キャラクターを描画する
 
// *** メインルーチン ************************************************
    repeat
        await WAITTIME
        stick key , 0b1001111 , 1
        if key & 0b1001111 == 0 {
            ; 有効なキーが入力されていないので何もしない
            continue
        }
        redraw 0
        gosub *eraseSquare  ; キャラクターを消去する
        gosub *keyFlag      ; スピードと移動量を決める
        gosub *move         ; キャラクターを移動させる
        gosub *drawSquare   ; キャラクターを描画する
        redraw 1
    loop
    stop
 
// *** キャラクターを消去 ********************************************
*eraseSquare
    palcolor BACKGROUNDCOLOR
    boxf x, y, x + BODYSIZE, y + BODYSIZE
    return
 
// *** スピードと移動量を決める **************************************
*keyFlag
    ; Ctrlキーを押している間だけ加速
    if key & 64 {
        speed = 2
    } else {
        speed = 1
    }
    ; 移動量を決定
    vx = (key>>2&1) - (key&1)
    vy = (key>>3&1) - (key>>1&1)
    return
 
// *** キャラクターを移動させる **************************************
*move
    x += vx * speed
    y += vy * speed
    ; マップから出ないように
    x = limit(x, 0, WINX - BODYSIZE)
    y = limit(y, 0, WINY - BODYSIZE)
    return
 
// *** キャラクターを描画 ********************************************
*drawSquare
    palcolor BODYCOLOR
    boxf x, y, x + BODYSIZE, y + BODYSIZE
    return

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

#const BODYSIZE     16          ; 移動キャラクターの体の大きさ
#const WAITTIME     16          ; メインループ待ち時間[ms]
#const WINX         300         ; ウィンドウサイズ（横）
#const WINY         300         ; ウィンドウサイズ（縦）
#const MAPX         480         ; マップの全体サイズ（横）
#const MAPY         480         ; マップの全体サイズ（縦）
#const TURF         32          ; 草の間隔
 
#enum MAINSCREEN = 0            ; メインウィンドウのID
#enum MAPBUFFER                 ; マップを保存するバッファのID
 
    randomize
    cx = 0 : cy = 0             ; キャラクター位置を初期化
    originX = 0 : originY = 0   ; マップ描画位置を初期化
 
// *** マップを準備 **************************************************
    ; マップを描画
    buffer MAPBUFFER, MAPX, MAPY
    repeat MAPY / TURF
        up_cnt = cnt
        tmp = cnt\2 * TURF / 2
        repeat MAPX / TURF
            pos cnt*TURF + tmp, up_cnt*TURF
            mes "\""
        loop
    loop
 
    ; 建物を描画（おまけ）
    font "Webdings", 32
    pos 270, 100 : mes "H"
    pos  80, 300 : mes "G"
    pos 370, 320 : mes "P"
 
// *** ウィンドウ初期化 **********************************************
    screen MAINSCREEN, WINX, WINY
    gmode 0, WINX, WINY
    gosub *draw         ; キャラクタとマップを描画
 
// *** メインルーチン ************************************************
*main
    await WAITTIME
    stick key , 0b1001111 , 1
    if key & 0b1001111 == 0 {
        ; 有効なキーが入力されていないので何もしない
        goto *main
    }
    redraw 0
    gosub *fixSpeed ; スピードと移動量を決める
    gosub *move     ; キャラクターを移動させる
    gosub *draw     ; マップとキャラクターの描画
    redraw 1
    goto *main
 
 
// *** スピードと移動量を決める **************************************
*fixSpeed
    ; Ctrlキーを押している間だけ加速
    speed = (key>>6 & 1) + 1        ; = (ctrlが押されていれば1) + 1 
 
    ; 移動量を決定
    vx = (key>>2&1) - (key&1)
    vy = (key>>3&1) - (key>>1&1)
    return
 
// *** キャラクターを移動させる **************************************
*move
    cx += vx * speed
    cy += vy * speed
 
    ; マップから出ないように
    cx = limit(cx, 0, MAPX - BODYSIZE)
    cy = limit(cy, 0, MAPY - BODYSIZE)
 
    ; マップ描画位置調整
    ; 基本はキャラクターの(WINX/2, WINY/2)だけ左上から描画
    originX = limit(cx - WINX/2, 0, MAPX - WINX)
    originY = limit(cy - WINY/2, 0, MAPY - WINY)
    return
 
// *** マップとキャラクターを描画 ************************************
*draw
    pos 0, 0 : gcopy MAPBUFFER, originX, originY
 
    color 255
    x = cx - originX
    y = cy - originY
    boxf x, y, x + BODYSIZE, y + BODYSIZE
    return