Module/拡張版getkey

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
|
!
 
 
 
 
 
-
|
-
|
!
|
-
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
-
|
-
|
!
!
 
 
 
 
 

#ifndef __MODULE_GETKEYEX__
#define __MODULE_GETKEYEX__
 
#module "mod_getkeyex"
 
#undef getkey
 
#uselib "user32.dll"
#func GetKeyboardState "GetKeyboardState" var
 
#define FLAG_DOWN        $1
#define FLAG_TRIGGER    $2
 
#deffunc getkey_init
    sdim data, 256
    dim  flag, 256
    return
 
;---------------------------------------------------------------------
; getkey p1, [p2]
;---------------------------------------------------------------------
; ※ p2 を指定した場合は標準的な動作をします(トリガ状態は取得されません)
; 
; キーボード及びマウスボタンの状態をチェックして数値型配列変数に代入します。
; 返される値は、キーが押されているか、押された瞬間(トリガ)か、を加算した
; 値が入っています。
; それぞれ、
; キーが押されていれば、1を加算します。
; 押された瞬間(トリガ)ならば、2を加算します。
; 何も押されていなかった場合は、0 になっています。
#deffunc getkey array p1, int p2
    if p2 {
        ; 標準動作
        getkey@hsp p1, p2
        return
    }
    ; 拡張動作
    GetKeyboardState data
    repeat 256
        ; フラグ設定
        ; 拡張マクロONしていないとコンパイルできないので peek@hsp にしてある
        if peek@hsp(data, cnt) & $80 {
            flag(cnt) |= FLAG_TRIGGER
            if flag(cnt) & FLAG_DOWN {
                flag(cnt) &= FLAG_TRIGGER ^ $ff
            }
            flag(cnt) |= FLAG_DOWN
        } else {
            flag(cnt) &= (FLAG_DOWN | FLAG_TRIGGER) ^ $ff
        }
        p1(cnt) = flag(cnt)
    loop
    return
 
#global
 
getkey_init
 
#endif
 
#if 0
;-----------------------------------------------------------
; テスト
 
;#include "mod_getkeyex.as"
 
*main
    getkey key, 32
    title "スペースの状態"+key
 
    getkey key
 
    redraw 0
    color 255,255,255 : boxf
    color 0,0,0
    pos 0,0
    ;「マウス左ボタン」が押された瞬間
    if 3 = key(1)  : mes "マウス左ボタンが押された" : else : mes ""
    ;「１」キーが押された瞬間
    if 3 = key(97)  : mes "１が押された" : else : mes ""
    ;「２」キーが押されている。
    if 0 < key(98) : mes "２キーが押されている" : else : mes ""
    ;「３」キーが押されている。
    if 0 < key(99) { 
        if 3 = key(99) {
            mes "３が押された瞬間！！！！！！！！！"
        } else {
            mes "３キーが押されている"
        }
    }
    redraw 1
 
    wait 100
    goto *main
#endif