小ワザ/モーダルダイアログ

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67

    ;
    ; 擬似モーダルダイアログボックス for HSP 3.0a
    ;                              written by kz3
    ;                           advised by はぁ？
 
    #uselib "user32.dll"
    #func   EnableWindow    "EnableWindow"      int,int
    #cfunc  GetWindowLong   "GetWindowLongA"    int,int
    #func   SetWindowLong   "SetWindowLongA"    int,int,int
    #func   SetWindowPos    "SetWindowPos"      int,int,int,int,int,int,int
 
    ; Window Style
    #define WS_MINIMIZEBOX      $00020000
    #define WS_MAXIMIZEBOX      $00010000
    #define WS_THICKFRAME       $00040000
 
    ; GetWindowLong()
    #define GWL_STYLE           (-16)
    #define GWL_HWNDPARENT      (-8)
 
    ; SetWindowPos()
    #define SWP_NOSIZE          $0001
    #define SWP_NOMOVE          $0002
    #define SWP_NOZORDER        $0004
    #define SWP_FRAMECHANGED    $0020
 
    onexit goto *destroy
 
    screen 0, 640, 480
    title strf("メインウィンドウ(ID%d)",ginfo(3))
    button goto "OPTION", *OpenModalDlg
    hwnd_main = hwnd
 
    screen 2, 300, 300,4+2
    title strf("擬似モーダルダイアログ(ID%d)",ginfo(3))
    button goto "OK", *ok
    hwnd_dlg = hwnd
 
    style = GetWindowLong(hwnd_dlg, GWL_STYLE)
    style = style & (WS_MINIMIZEBOX|WS_MAXIMIZEBOX|WS_THICKFRAME) ^ style
    SetWindowLong hwnd_dlg, GWL_STYLE, style
    SetWindowLong hwnd_dlg, GWL_HWNDPARENT, hwnd_main
    SetWindowPos hwnd_dlg, 0, 0, 0, 0, 0, SWP_NOSIZE|SWP_NOMOVE|SWP_NOZORDER|SWP_FRAMECHANGED
 
    stop
 
 *OpenModalDlg
    gsel 0
    mainx = ginfo.4: mainy = ginfo.5
    mainw = ginfo.10: mainh = ginfo.11
    EnableWindow hwnd_main, 0
 
    gsel 2
    width ,, mainx+(mainw-ginfo.10)/2, mainy+(mainh-ginfo.11)/2
    gsel 2,1
 
    stop
 
 *ok
    gsel 2,-1
    EnableWindow hwnd_main, 1
    gsel 0,1
    stop
 
 *destroy
    if (iparam = 0) & (wparam = 2) : goto *ok
    end