INIファイル操作モジュール

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

// iniファイル操作モジュール
 
#ifndef IG_INI_FILE_MODULE_AS
#define IG_INI_FILE_MODULE_AS
 
// put で書き込み、get で読み込み
//	(s: 文字列, d: 小数, i: 整数)
 
#module mod_ini
 
#uselib "kernel32.dll"
#func   WritePrivateProfileString "WritePrivateProfileStringA" sptr,sptr,sptr,sptr
#func   GetPrivateProfileString   "GetPrivateProfileStringA"   sptr,sptr,sptr,int,int,sptr
#cfunc  GetPrivateProfileInt      "GetPrivateProfileIntA"      sptr,sptr,int,sptr
 
#define ctype double_to_str@mod_ini(%1) strf("\"%%.16e\"", %1)
#define null 0
 
/*-----------------------------------------------*
.* ini: ファイルパスを設定する
.* 
.* @prm path: ファイルパス
.*   (絶対パスか相対パスに限る。ファイル名のみではダメ。)
.*-----------------------------------------------*/
#deffunc ini_setpath str _path
    _ini_path = _path
    
    // 読み出し用のバッファを最小値で確保する
    sdim _strbuf, 512
    return
    
/*-----------------------------------------------*
.* ini: 値を書き込む
.*
.* @prm str section: セクション名
.* @prm str key:     キー名
.* @prm any value:   値 (文字列型に変換可能な型のみ)
.* 
.* @memo: 文字列型の値は "" で括った形で書き込むべき。
.*-----------------------------------------------*/
#define global ini_put(%1, %2, %3) ini_put_impl %1, %2, str(%3)
#deffunc ini_put_impl str sec, str key, str value
    WritePrivateProfileString sec, key, value, _ini_path
    return
    
// マクロ
#define global ini_puts(%1, %2, %3) ini_put_impl %1, %2, "\"" + (%3) + "\""
#define global ini_putd(%1, %2, %3) ini_put_impl %1, %2, double_to_str@mod_ini(%3)
#define global ini_puti ini_put
 
/*-----------------------------------------------*
.* ini: 値を読み込む
.*
.* 名前の最後に v がつくものは命令で、第一引数に変数をとる。
.* 　そうでないものは関数で、値は関数の返り値で返す。
.* 指定したキーが存在しない場合は、default に指定された値が返る。
.* 
.* @prm[var] dst:    (v) 受け取る変数 (文字列型でなければ初期化される)
.* @prm str section: セクション名
.* @prm str key:     キー名
.* @prm str default: 既定値 ("")
.* @prm int size:    読み込む文字数の最大 (∞)
.*-----------------------------------------------*/
// コア部分
// @ pSec, pKey を 実体, nullptr で切り替えて複数の操作をする。
#deffunc ini_getv_something_impl var dst, int pSec, int pKey, int pDef, int size_,  local size
    if ( vartype(dst) != 2 ) { sdim dst }
    size = limit(size_, 64, 0xFFFF)            // 最小でも 64 は確保する
    
*LReTry:
    // 読み出す分のバッファを確保
    memexpand dst, size
    
    // 読み込み
    GetPrivateProfileString pSec, pKey, pDef, varptr(dst), size, _ini_path
    
    // 文字数が足りなかった
    if ( (stat == size - 1 || stat == size - 2) && size_ <= 0 ) {
        size += size + 512        // バッファを拡大して取得し直す
        goto *LReTry
    }
    
    return
    
// 文字列
#define global ini_getsv(%1, %2, %3, %4 = "", %5 = 0) ini_getsv_ %1, %2, %3, %4, %5
#deffunc ini_getsv_ var dst, str sec_, str key_, str def_, int size_,  local sec, local key, local def
    sec = sec_
    key = key_
    def = def_
    ini_getv_something_impl dst, varptr(sec), varptr(key), varptr(def), size_
    return
    
#define global ctype ini_gets(%1, %2, %3 = "", %4 = 0) ini_gets_(%1, %2, %3, %4)
#defcfunc ini_gets_ str sec, str key, str def, int size_
    ini_getsv _strbuf, sec, key, def, size_
    return _strbuf
    
// 小数
#define global ini_getdv(%1, %2, %3, %4 = 0) %1 = ini_getd(%2, %3, %4)
 
#define global ctype ini_getd(%1, %2, %3 = 0) ini_getd_(%1, %2, %3)
#defcfunc ini_getd_ str sec, str key, double def
    ini_getsv _strbuf, sec, key, double_to_str@mod_ini(def), 32        // 32[byte]もあれば十分
    return double(_strbuf)
    
// 整数
#define global ini_getiv(%1, %2, %3, %4 = 0) %1 = ini_geti(%2, %3, %4)
 
#defcfunc ini_geti str sec, str key, int def
;	ini_getsv _strbuf, sec, key, str(def), 32
;	return int(_strbuf)
    return GetPrivateProfileInt( sec, key, def, _ini_path )
    
/*-----------------------------------------------*
.* ini: セクション, キーを列挙する
.*
.* @prm array dst:     受け取る変数(配列)
.* @prm[str]  section: セクション (enumKey の場合)
.* @prm int   size:    読み込む文字数の最大 (∞)
.*-----------------------------------------------*/
#deffunc ini_enumSection array dst_arr, int bufsize
    ini_getv_something_impl _strbuf, null, null, null, bufsize
    sdim dst_arr, stat
    SplitByNull dst_arr, _strbuf, stat
    return
    
#deffunc ini_enumKey array dst_arr, str section_, int bufsize,  local section
    section = section_
    ini_getv_something_impl _strbuf, varptr(section), null, null, bufsize
    sdim dst_arr, stat
    SplitByNull dst_arr, _strbuf, stat
    return
    
// cnv: '\0' 区切り文字列 -> 配列
#deffunc SplitByNull@mod_ini array dst, var buf, int maxsize,  local idx
    idx = 0
    sdim dst
    repeat
        if ( idx >= maxsize ) { break }        // (2013/10/23) コメント参照
        getstr dst(cnt), buf, idx, , maxsize
    ;	logmes dst(cnt)
        idx += strsize + 1
    loop
    return
    
#ifdef _DEBUG
// すべてのセクションのキーを列挙しデバッグ出力する
 #deffunc ini_dbglog  local seclist, local sec, local keylist, local key, local stmp
    logmes "\n(ini_dbglog): @" + _ini_path
    ini_enumSection seclist            // セクションを列挙
    
    foreach seclist : sec = seclist(cnt)
        logmes strf("[%s]", sec)
        ini_enumKey keylist, sec    // キーを列挙
        foreach keylist : key = keylist(cnt)
            ini_getsv stmp, sec, key, , 512
            logmes ("\t" + key + " = \"" + stmp + "\"")
        loop
    loop
    return
#else
 #define global ini_dbglog :
#endif
    
/*-----------------------------------------------*
.* ini: セクション, キーを削除する
.*
.* @prm str  section: セクション
.* @prm[str] key:     キー
.*-----------------------------------------------*/
#deffunc ini_removeSection str sec
    WritePrivateProfileString sec, null, null, _ini_path
    return
    
#deffunc ini_removeKey str sec, str key
    WritePrivateProfileString sec, key, null, _ini_path
    return
    
/*-----------------------------------------------*
.* ini: キーが存在するか否か
.*
.* @prm str section: セクション
.* @prm str key:     キー
.*-----------------------------------------------*/
#defcfunc ini_exists str sec, str key
    return ( ini_geti(sec, key, 0) == 0 && ini_geti(sec, key, 1) == 1 )
    
#global
 
#endif

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43

;#include (上記のモジュール)
 
    sec = "section"
    
    path = "./appdata.ini"        // 絶対パス or 相対パス、ファイル名ではダメ
    ini_setpath path
    ini_dbglog
    
    
    // put & get
    ini_puts sec, "message", "Hello, world!"
    mes "message = " + ini_gets(sec, "message")
    
    ini_puti sec, "x", 42
    mes "x = " + ini_geti(sec, "x")
    
    ini_putd sec, "pi", M_PI
    mes "pi = " + ini_getd(sec, "pi")
    
    
    ini_getsv buf, "text", "LongString"                // 適当に書きこんでおく
    mes buf
    
    logmes "----------------------------"
    ini_dbglog
    
    
    // delete & exists
    mes "exists(x) = " + ini_exists(sec, "x")
    
    key = "x"
    ini_removeKey sec, key                // 特定のキーを削除する
    mes "# remove " + key + " in [" + sec + "]"
    
    mes "exists(x) = " +  ini_exists(sec, "x")        // 消滅後
    
    ini_removeSection sec                // 特定のセクションを削除する
    mes "# remove [" + sec + "]"
    
    mes "exists(pi) = " + ini_exists(sec, "pi")        // セクションごと消滅している
    
    stop

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37

;#include (上記のモジュール)
 
    gsel 0, -1
    gosub *LoadConfig    // 設定を読み込む
    
    // ウィンドウ表示
    screen 1, ginfo_dispx, ginfo_dispy, screen_hide
    title "INIサンプル"
    width windowSize(0), windowSize(1), windowPos(0), windowPos(1)
    gsel 1, 1
    
    mes "load: " + dir_cur + "/sample.ini"
    
    onexit goto *Exit
    stop
    
*Exit
    gosub *SaveConfig    // 終了時に保存する
    end
    
// 読み込み
*LoadConfig
    ini_new cfg, "./sample.ini"
    
    windowPos(0)  = ini_geti( cfg, "Window", "PosX" )    // 位置 (x, y)
    windowPos(1)  = ini_geti( cfg, "Window", "PosY" )
    windowSize(0) = ini_geti( cfg, "Window", "ClientX", 640 )    // 大きさ (x, y)
    windowSize(1) = ini_geti( cfg, "Window", "ClientY", 480 )
    return
    
// 保存
*SaveConfig
    ini_puti cfg, "Window", "ClientX", ginfo_winx
    ini_puti cfg, "Window", "ClientY", ginfo_winy
    ini_puti cfg, "Window", "PosX", ginfo_wx1
    ini_puti cfg, "Window", "PosY", ginfo_wy1
    return