グループボックス

擬似グループボックス †

[編集]

グループボックスとは、コントロールパネルなどでよくみる四角い枠線のことです。
本来はボタンコントロールにメッセージを送って作るものですが、HSPでやるとグループボックスが再描画されないという問題が生じます。
それを防ぐために、HSPではスタティックテキストを下敷きにするのを推奨しているようですが、HSP3でmesbox命令のスタティックテキストがなくなり、グループボックスを作るのにわざわざhsp3util.asを使用しなければいけないようになってしまいました。

「そんなめんどくさいことをするよりは自分で描いたほうがましだ！」ということで自分で作ってみました。(^^;

↑

見出し †

[編集]

擬似グループボックス

↑

モジュール †

[編集]

モジュール

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
|
|
|
|
|
|
|
|
|
|
|
-
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
!

    #module mod_groupbox
 
    ;
    ; 擬似グループボックスを描画 for HSP 3.0
    ;
    ; exgroupbox s1, n2, n3
    ; 
    ; s1    : グループボックス表示文字列
    ; n2,n3 : グループボックスの大きさx,y
    ;
    ; 2005/01/28 QIG/SteepGrade
    ;
    #uselib "gdi32.dll"
    #func GetTextExtentPoint32 "GetTextExtentPoint32A" int,str,int,int
 
    #uselib "UxTheme.dll"
    #cfunc IsThemeActive "IsThemeActive"
    #cfunc IsAppThemed "IsAppThemed"
 
    #deffunc exgroupbox str capt, int xsize, int ysize
        ;XP以降でビジュアルスタイルが有効の場合
        if varptr(IsThemeActive) : vstyle(0) = IsThemeActive()
 
        ;一部の環境で上手く表示されないらしいので追加（情報：hirokiさん）
        if varptr(IsAppThemed) : vstyle(1) = IsAppThemed()
 
        oldcolor = ginfo_r + (ginfo_g << 8) + (ginfo_b << 16)
 
        ;選択されているフォント名取得
        mref bmscr, 67
        dupptr ptrdup, varptr(bmscr(56)), 32, 2 : oldfont = ptrdup
 
        ;描画位置計算
        cx = ginfo_cx : cy = ginfo_cy + 6
        xpos = cx + xsize - 2 : ypos = cy + ysize - 8
 
        redraw 2
 
;		if vstyle {
        if vstyle(0) & vstyle(1) {
            color 208, 208, 191
 
            ;上→下→左→右
            line cx+1, cy, xpos-1, cy
            line cx+1, ypos+1, xpos-1, ypos+1
            line cx, cy+1, cx, ypos-1
            line xpos+1, cy+1, xpos+1, ypos-1
 
            ;左上→右上→左下→右下
            pset cx+1, cy+2   : pset cx+1, cy+1 : pset cx+2, cy+1
            pset xpos-1, cy+1 : pset xpos, cy+1 : pset xpos, cy+2
            pset cx+1, ypos-1 : pset cx+1, ypos : pset cx+2, ypos
            pset xpos-1, ypos : pset xpos, ypos : pset xpos, ypos-1
        } else {
            ;灰色の線
            syscolor 17
 
            ;上→下→左→右
            line cx-1, cy, xpos, cy
            line cx, ypos, xpos, ypos
            line cx, cy, cx, ypos
            line xpos, cy, xpos, ypos
 
            ;白い線
            color 255, 255, 255
 
            line cx, cy+1, xpos-1, cy+1
            line cx-1, ypos+1, xpos+1, ypos+1
            line cx+1, cy+1, cx+1, ypos-1
            line xpos+1, cy-1, xpos+1, ypos+1
        }
 
        ;文字列xサイズ取得
        sysfont 17
        GetTextExtentPoint32 hdc, capt, strlen(capt), varptr(size)
 
        ;文字描画
        syscolor 15 : boxf cx+7, cy-5, cx+size(0)+10, cy+8
;		if vstyle : color 0, 70, 213 : else : color
        if vstyle(0) & vstyle(1) : color 0, 70, 213 : else : color
        pos cx+9, cy-5 : mes capt
 
        redraw
 
        color oldcolor & $FF, oldcolor >> 8 & $FF, oldcolor >> 16 & $FF
        font oldfont
 
        return
 
    #global
 
    ;メモリ確保
    dim size@mod_groupbox,2
    dim vstyle@mod_groupbox,2

↑

サンプル †

[編集]

サンプル

    #define BM_SETSTYLE 0x00F4
    #define BS_GROUPBOX 0x0007
 
    syscolor 15 : boxf
 
    pos 10,10 : exgroupbox "擬似グループボックスです",300,200
 
    ;比較用標準グループボックス
    objsize 300,200
    pos 320,10 : button gosub "純正グループボックスです",*tmp
    sendmsg objinfo(stat,2),BM_SETSTYLE,BS_GROUPBOX,-1
 
    stop
 
*tmp
    return

↑

コメント †

[編集]

間違ったことかいてないかチェック・・・。 -- QIG 2005-12-14 (水) 23:03:52
使える！　今まで．．．って言っても２度だけだけど、lineのオンパレードで作ったことがあります。　それも背景色無視で．．。 -- hiroki? 2005-12-15 (木) 09:17:34
exgroupbox命令実行の前に枠内にmesを入れるのと、実行後に入れるのとでは、フォントサイズが変更されます。^^; -- hiroki? 2005-12-15 (木) 09:18:01
既知のバグです。(^^; 現在選択されているフォント情報を取得する方法はないものかと考えましたが、見つかりませんでした・・・。 -- QIG 2005-12-15 (木) 17:40:41
描画Y位置がおかしかったので修正。 -- QIG 2005-12-15 (木) 18:07:12
LUNAバージョン追加しました。ついでに細かいところを修正・・・。 -- QIG 2005-12-15 (木) 19:57:37
スタイルを自動で判別するようにしました。だいぶ実用的になったと思います。(^_^) -- QIG 2005-12-16 (金) 20:35:24
Windowsクラッシックスタイルなんですが、使っていくうちにＸＰスタイルという判定になり文字が青く枠線もなしになります。実際には引いてるんだろうけど、直すには一端ＸＰスタイルにして再度クラッシックにしなければなりません。どうして．．．(;_;) 組み込み方が悪いのかな -- hiroki? 2005-12-28 (水) 10:57:03

ここが気になりました。

  1
  2
  3

    ;XP以降でビジュアルスタイルが有効の場合
//  if varptr(IsThemeActive) : if IsThemeActive()!0 : vstyle = 1
    vstyle = IsThemeActive()

どうですか？ -- kz3

あっ、if osver(1)>=5 & osver(2)>=1 : if IsThemeActive?()!0 : vstyle = 1 のままでした。　いつのまに変わってる。(-_-;)　ごめんなさいいまのところ正常です。 -- hiroki? 2005-12-28 (水) 12:10:24
でもこれだと、ＸＰ以外はエラー出るんじゃないの。 Win98にIsThemeActive?のAPIあるんですか。 -- hiroki? 2005-12-28 (水) 12:33:44
「Minimum operating systems Windows XP 」無い様ですねぇ･･･ -- kz3 2005-12-28 (水) 12:40:09
Win98が無いからいまとなっては試しようがない -- hiroki? 2005-12-28 (水) 12:48:17

IsThemeActive?関数がないOSでも大丈夫です。

    #uselib "test.dll"
    #func test "test"
 
    mes varptr(test)

が大丈夫ですから。-- QIG 2005-12-28 (水) 13:19:51

ここの他にも細々といじってますので、全部コピーしなおした方がいいかと・・・。 -- QIG 2005-12-28 (水) 13:30:53

'test'は関数ポインタになっていたんですね。

  1
  2
  3

    ;XP以降でビジュアルスタイルが有効の場合
//  if varptr(IsThemeActive) : if IsThemeActive()!0 : vstyle = 1
    if varptr(IsThemeActive): vstyle = IsThemeActive(): else: vstyle=0

でしょうか。Is～は有効であればTRUE(≠0)を返します。!0で「0でない」時に真にするのはそのままBOOL値となるので!0は要らなくてもいいですね。 -- kz3

確かにそうだ、てことで修正。ついでに選択フォント保存機能追加しました。 -- QIG 2005-12-28 (水) 16:50:10
なかなか　ＡＰＩってのは便利なものがありますね。勉強不足です。 -- hiroki? 2005-12-28 (水) 19:02:02
あれから数日、スタイルを変えずに使い続けていると、また表示されなくなりました。　ＸＰのバグかいの？ -- hiroki? 2006-01-02 (月) 12:40:31
vstyleの値を調べると、ＸＰスタイルもクラッシックも１になりましたが、次にクラッシックに戻せば０になりました。 -- hiroki? 2006-01-02 (月) 13:12:05
ち、ちなみに知っているかと思いますがボタンコントロールにWS_CLIPCHILDREN($02000000)スタイルを除くとコントロールの後ろの親ウィンドウの背景も再描画されます。by naznyarkさんより。
このスタイルは子ウィンドウに隠れた部分を再描画対象から除外するというものです。 -- kz3 2006-01-02 (月) 13:13:03
今回はvstyleの値だけ調べたんです -- hiroki? 2006-01-02 (月) 13:19:10
一度終了して起動してもＸＰスタイルと判定される -- hiroki? 2006-01-02 (月) 13:21:51
私はこのモジュールを二週間ほど使い続けていますが、表示されなくなったことはありませんでした。なんでそうなるのかな・・・。 -- QIG 2006-01-02 (月) 13:39:24
いろいろとスタイル変えて試してみましたが、特に変な動作はありませんでした。 -- QIG 2006-01-02 (月) 13:41:18
スタイルも変えずに使い続けると．．．．。(-_-;) -- hiroki? 2006-01-02 (月) 13:43:24
やっぱり日数がたてば、こうなるんですけど。
CPUがダブルコアの６４ビットだからってことはないですよね。^^; by hiroki
やっと見つけました。
異常状態のまま下記を追加(上書)して確かめると、正常に描画しました。
ほとんどネットからのパクリなんですけどね。(^^;)

	#uselib "UxTheme.dll"
	#cfunc IsThemeActive "IsThemeActive"
	#cfunc IsAppThemed "IsAppThemed"

	if varptr(IsThemeActive) : vstyle1 = IsThemeActive()
	if varptr(IsAppThemed)   : vstyle2 = IsAppThemed()
	vstyle = vstyle1 & vstyle2

でも、異常状態のままなんで、vstyle1の値は1のハズでＸＰスタイルの判定なんですが、vstyle2がゼロなので、
クラシックという判定になります。
試しに修正していないもので動作すると描画されない。(^^;)
ちなみに、IsThemeActive?()もIsAppThemed?()も、XPスタイルかどうかの判定のようです。 by hiroki

なぜ・・・(?_?) IsThemeActive?は環境依存なのかな・・・。 -- QIG 2006-01-19 (木) 20:31:37
regionプラグインのテストも兼ねて更新。原因がよく分からないままhirokiさんのコードを追加しました。 -- QIG 2006-01-28 (土) 21:44:34
W2K等でコけるので、最終行のvstyle 配列初期化を追加しました。 -- Chiba-NW? 2007-10-09 (火) 21:09:17

添付ファイル:

gbox.png 724件 [詳細]

グループボックス

OFFICIAL/関連

TUTORIAL

TOPICS

ETC

EDIT

REFERENCE

LOG

お知らせ

HSP Web-Ring

最新の40件

擬似グループボックス †

見出し †

モジュール †

サンプル †

コメント †