マップ内での移動

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
!
 
-
|
|
|
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
-
-
|
-
|
|
-
-
-
|
|
!
-
|
!
!
!
-
|
|
|
|
!
-
|
-
|
-
|
!
!
 
 
 
 
 
 
 
 
 
 
 

/*--------------------------------------------------------------------------*/
 
#module mod_rcmap
 
/*------------------------------------------------------------*/
 
//	初期化。
#deffunc Init@mod_rcmap
    PointCount = 0
    dim PointList, 3, 1024
    dim TmpData, 3
    return
 
/*--------------------------------------------*/
 
//	特殊地形を示す値。
//	移動開始地点。
#const  STARTPOINT      -99
//	進入不可。
#const  NOMOVEPOINT     -1
 
/*--------------------------------------------*/
 
//	到達コストマップの作成。
//
//	指定した地点からマップ内の各地点への到達コスト(そこに移動するのに必要な総移動コスト)を求めます。
//	経路により到達コストが変わる場合はその中での最小値になります。
//
//  array RCMap_    : 各地点への到達コストが代入される変数。
//  array Map_      : 各地点ごとの移動コスト(隣接する地点からそこに移動するのに必要な移動力)が
//                  : 代入された整数型二次元配列変数。
//  int X_          : 移動基点の横座標。
//  int Y_          : 移動基点の縦座標。
//  int Move_       : 移動一回あたりの移動力。(負値の場合は無制限。)
//  int Turn_       : 移動回数。(負値の場合は無制限。)
#deffunc CreateRCMap array RCMap_, array Map_, int X_, int Y_, int Move_, int Turn_
 
    mx = length( Map_ )
    my = length2( Map_ )
    dim RCMap_, mx, my
 
    if ( ( X_ < 0 ) || ( X_ >= mx ) || ( Y_ < 0 ) || ( Y_ >= my ) ) { return }
    RCMap_( X_, Y_ ) = STARTPOINT
    if ( Map_( X_, Y_ ) == NOMOVEPOINT ) { return }
 
    PointList( 0, 0 ) = X_, Y_, 0
    PointCount = 1
 
*crcmloop@mod_rcmap
    PointCount --
    if ( PointCount < 0 ) { goto *crcmret@mod_rcmap }
 
    //	調査対象地点リストの中から到達コストが一番少ない要素を探す。
    i = PointCount
    cost = PointList( 2, PointCount )
    repeat PointCount
        if ( PointList( 2, cnt ) < cost ) {
            cost = PointList( 2, cnt )
            i = cnt
        }
    loop
    if ( i != PointCount ) {
        //	到達コストが一番少ない要素をリストの末尾要素と交換する。
        memcpy TmpData, PointList, 12, 0, PointCount * 12
        memcpy PointList, PointList, 12, PointCount * 12, i * 12
        memcpy PointList, TmpData, 12, i * 12, 0
    }
 
    x = PointList( 0, PointCount )
    y = PointList( 1, PointCount )
    cost = PointList( 2, PointCount )
 
    //	四方向の調査。
    ax = x - 1 : ay = y     : gosub *crcmsub@mod_rcmap
    ax = x     : ay = y - 1 : gosub *crcmsub@mod_rcmap
    ax = x + 1 : ay = y     : gosub *crcmsub@mod_rcmap
    ax = x     : ay = y + 1 : gosub *crcmsub@mod_rcmap
 
    goto *crcmloop@mod_rcmap
 
*crcmret@mod_rcmap
    return
 
*crcmsub@mod_rcmap
    //	調査対象地点リストに登録するかどうか調べる。
 
    if ( ( ax < 0 ) || ( ax >= mx ) || ( ay < 0 ) || ( ay >= my ) ) { return }
        //	マップ範囲外。
    if ( RCMap_( ax, ay ) ) { return }
        //	調査済みか調査対象地点リストに登録済み。
 
    c1 = Map_( ax, ay ) //	この地点の移動コスト。
    c2 = cost + c1 //	この地点の到達コスト。
    if ( c1 > 0 ) {
        //	通常地形。
        f = 0
        if ( Move_ == 0 ) {
        } else : if ( Move_ < 0 ) {
            f = 1
        } else : if ( Move_ >= c1 ) {
            //	移動力がこの地点の移動コストより大きい。
            //	(例えば移動力３のユニットは移動コストが４以上の地点には実際には決して移動できない。)
            if ( Turn_ == 0 ) {
            } else {
                if ( Move_ - cost \ Move_ < c1 ) {
                    //	残り移動力が移動コストに足りない。
                    c2 = ( cost / Move_ + 1 ) * Move_ + c1
                }
                if ( ( Turn_ == -1 ) || ( Move_ * Turn_ >= c2 ) ) {
                    f = 1
                }
            }
        }
        if ( f ) {
            //	調査対象地点リストに登録。
            RCMap_( ax, ay ) = c2
            PointList( 0, PointCount ) = ax, ay, c2
            PointCount ++
        }
    } else {
        //	特殊地形。
        if ( c1 == NOMOVEPOINT ) {
            RCMap_( ax, ay ) = NOMOVEPOINT
        } else {
            RCMap_( ax, ay ) = NOMOVEPOINT
        }
    }
    return
 
/*------------------------------------------------------------*/
 
#global
 
/*--------------------------------------------------------------------------*/
 
    Init@mod_rcmap
 
/*--------------------------------------------------------------------------*/

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
-
|
-
|
-
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

//	mod_reachcostmap.hsp
//	到達コスト計算のサンプル。
//
//	任意の地点で左クリックするとその地点からマップ内の他の地点への到達コストを計算・表示します。
//
//	各地点の上段に黒で表示されているのはその地形の移動コスト、
//	下段に赤で表示されるのは左クリックした地点からの到達コスト。
//
//	移動コスト・到達コスト -1 は進入不可地点、
//	到達コスト 0 は到達不可地点、
//	到達コスト -99 は到達コスト計算の基点(左クリックした地点)を示しています。
 
    #include "mod_reachcostmap.hsp"
 
#const  MAP_W   24
#const  MAP_H   24
#const  CHIP    20
 
    randomize
    screen 0, MAP_W * CHIP, MAP_H * CHIP, 0
    title "到達コスト計算"
 
    //	マップデータを生成。
    dim map, MAP_W, MAP_H
    dim rcmap, MAP_W, MAP_H
    repeat MAP_H
        i = cnt
        repeat MAP_W
            c = rnd( 4 ) + 1
            if ( c == 4 ) { c = -1 }
            map( cnt, i ) = c
        loop
    loop
 
    gosub *drawmap
 
    //	左クリックを待つ。
    repeat
        wait 3
        stick keystk, 0
        if ( keystk & 0x0100 ) { gosub *calc_reachcost }
    loop
    stop
 
*calc_reachcost
    px = mousex / CHIP
    py = mousey / CHIP
    if ( ( px < 0 ) || ( px >= MAP_W ) || ( py < 0 ) || ( py >= MAP_H ) ) { return }
 
    //	指定した地点からの到達コストを求める。
    CreateRCMap rcmap, map, px, py, -1, -1
 
    gosub *drawmap
    return
 
*drawmap
    //	マップ描画。
    redraw 0
 
    font msgothic, CHIP / 2, 0
    repeat MAP_H
        i = cnt
        repeat MAP_W
            if ( rcmap( cnt, i ) == -99 ) {
                color 0, 255, 0
            } else : if ( rcmap( cnt, i ) > 0 ) {
                color 255, 255, 255
            } else : if ( map( cnt, i ) == -1 ) {
                color 0, 0, 255
            } else {
                color 191, 191, 191
            }
            boxf cnt * CHIP, i * CHIP, ( cnt + 1 )* CHIP - 1, ( i + 1 ) * CHIP - 1
            color 0, 0, 0
            pos cnt * CHIP + 2, i * CHIP
            mes map( cnt, i )
            color 255, 0, 0
            mes rcmap( cnt, i )
        loop
    loop
 
    color 0, 0, 0
    repeat MAP_W
        line cnt * CHIP, MAP_H * CHIP, cnt * CHIP, 0
    loop
    repeat MAP_H
        line MAP_W * CHIP, cnt * CHIP, 0, cnt * CHIP
    loop
 
    redraw 1
    return

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
-
|
-
|
-
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

//	mod_reachcostmap.hsp
//	移動可能範囲の判定サンプル。
//
//	任意の地点で左クリックするとその地点から今の移動力で移動可能な範囲を示します。
//
//	各地点の上段に黒で表示されているのはその地形の移動コスト、
//	下段に赤で表示されるのは左クリックした地点からの到達コスト。
//
//	移動コスト・到達コスト -1 は進入不可地形、
//	到達コスト 0 は到達不可地点、
//	到達コスト -99 は到達コスト計算の基点(左クリックした地点)を示しています。
 
    #include "mod_reachcostmap.hsp"
 
#const  MAP_W   24
#const  MAP_H   24
#const  CHIP    20
 
    randomize
    screen 0, MAP_W * CHIP, MAP_H * CHIP + 24, 0
    title "移動可能範囲検索"
 
    //	マップデータを生成。
    dim map, MAP_W, MAP_H
    dim rcmap, MAP_W, MAP_H
    repeat MAP_H
        i = cnt
        repeat MAP_W
            c = rnd( 4 ) + 1
            if ( c == 4 ) { c = -1 }
            map( cnt, i ) = c
        loop
    loop
 
    gosub *drawmap
 
    mv = 6
    tr = 1
 
    //	移動力指定用入力ボックス
    font msgothic, 16, 0
    color 0, 0, 0
    pos 0, MAP_H * CHiP
    mes "移動力"
    pos 64, MAP_H * CHiP
    input mv
 
    //	左クリックを待つ。
    repeat
        wait 3
        stick keystk, 0
        if ( keystk & 0x0100 ) { gosub *calc_reachcost }
    loop
    stop
 
*calc_reachcost
    px = mousex / CHIP
    py = mousey / CHIP
    if ( ( px < 0 ) || ( px >= MAP_W ) || ( py < 0 ) || ( py >= MAP_H ) ) { return }
 
    //	指定した地点からの到達コストを求める。
    CreateRCMap rcmap, map, px, py, mv, tr
 
    gosub *drawmap
    return
 
*drawmap
    //	マップ描画。
    redraw 0
 
    font msgothic, CHIP / 2, 0
    repeat MAP_H
        i = cnt
        repeat MAP_W
            if ( rcmap( cnt, i ) == -99 ) {
                color 0, 255, 0
            } else : if ( rcmap( cnt, i ) > 0 ) {
                color 255, 255, 255
            } else : if ( map( cnt, i ) == -1 ) {
                color 0, 0, 255
            } else {
                color 191, 191, 191
            }
            boxf cnt * CHIP, i * CHIP, ( cnt + 1 )* CHIP - 1, ( i + 1 ) * CHIP - 1
            color 0, 0, 0
            pos cnt * CHIP + 2, i * CHIP
            mes map( cnt, i )
            color 255, 0, 0
            mes rcmap( cnt, i )
        loop
    loop
 
    color 0, 0, 0
    repeat MAP_W
        line cnt * CHIP, MAP_H * CHIP, cnt * CHIP, 0
    loop
    repeat MAP_H
        line MAP_W * CHIP, cnt * CHIP, 0, cnt * CHIP
    loop
 
    redraw 1
    return

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
!
 
 
 
 
 
 
 
-
|
|
!
 
 
 
 
 
 
 

/*--------------------------------------------------------------------------*/
 
#module mod_mcroute
 
/*------------------------------------------------------------*/
 
//	特殊地形を示す値。
//	移動開始地点。
#const  STARTPOINT      -99
//	進入不可。
#const  NOMOVEPOINT     -1
 
/*--------------------------------------------*/
 
//	到達コストマップを使って目標地点への最小コスト経路を求める。
//
//	作成済みの到達コストマップの移動基点から目標地点へ最小コストで移動する経路を求めます。
//
//  Route_      : 経路が代入される変数。
//                ( 0, 0 ) に経路上の経由地点数が代入されます。
//                目標地点に到達不可能の場合は 0、移動基点と目標地点が同じ場合は 1 になります。
//                ( 0, 1 )( 1, 1 ) から ( 0, Route_( 0, 0 ) )( 1, Route_( 0, 0 ) ) へ
//                目標地点からさかのぼる形で各経由地点の座標が代入されます、
//  RCMap_      : 各地点への到達コストが代入された変数。
//  X_          : 目標地点の横座標。
//  Y_          : 目標地点の縦座標。
#deffunc FindRoute array Route_, array RCMap_, int X_, int Y_
 
    mx = length( RCMap_ )
    my = length2( RCMap_ )
    dim Route_, 2, 256
 
    if ( ( X_ < 0 ) || ( X_ >= mx ) || ( Y_ < 0 ) || ( Y_ >= my ) ) { return }
    if ( RCMap_( X_, Y_ ) == 0 ) { return }
    if ( RCMap_( X_, Y_ ) == NOMOVEPOINT ) { return }
 
    Route_( 0, 0 ) = 1
    Route_( 0, 1 ) = X_, Y_
    count = 1
    repeat
        x = Route_( 0, count )
        y = Route_( 1, count )
        if ( RCMap_( x, y ) == STARTPOINT ) { break }
 
        count ++
        Route_( 0, count ) = x, y
        cost = RCMap_( x, y )
 
        //	四方向を調べて到達コストが最小の方向に進む(戻る)。
        ax = x - 1 : ay = y     : gosub *frsub@mod_mcroute
        ax = x     : ay = y - 1 : gosub *frsub@mod_mcroute
        ax = x + 1 : ay = y     : gosub *frsub@mod_mcroute
        ax = x     : ay = y + 1 : gosub *frsub@mod_mcroute
 
        if ( ( Route_( 0, count ) == x ) && ( Route_( 1, count ) == y ) ) {
            count = 0
            break
        }
    loop
 
    Route_( 0, 0 ) = count
    return
 
*frsub@mod_mcroute
    if ( ( ax < 0 ) || ( ax >= mx ) || ( ay < 0 ) || ( ay >= my ) ) { return }
    if ( ( RCMap_( ax, ay ) == STARTPOINT ) || ( ( RCMap_( ax, ay ) > 0 ) && ( RCMap_( ax, ay ) < cost ) ) ) {
        cost = RCMap_( ax, ay )
        Route_( 0, count ) = ax, ay
    }
    return
 
/*------------------------------------------------------------*/
 
#global
 
/*--------------------------------------------------------------------------*/

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
-
|
-
|
-
|
!
 
 
 
 
 
 
 
 
 
 
-
|
-
|
|
|
|
|
|
!
|
|
|
|
|
|
|
|
|
|
|
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

//	mod_mincostroute.hsp
//	最小コスト経路の検索サンプル。
//
//	任意の地点で左クリックするとその地点を移動基点に設定し、
//	その地点から今の移動力で移動可能な範囲を示します。
//	移動基点設定後に移動可能な任意の地点で右クリックすると
//	移動基点からその地点までの経路を示します。
//
//	各地点の上段に黒で表示されているのはその地形の移動コスト、
//	下段に赤で表示されるのは左クリックした地点からの到達コスト。
//
//	移動コスト・到達コスト -1 は進入不可地形、
//	到達コスト 0 は到達不可地点、
//	到達コスト -99 は到達コスト計算の基点(左クリックした地点)を示しています。
 
    #include "mod_reachcostmap.hsp"
    #include "mod_mincostroute.hsp"
 
#const  MAP_W   24
#const  MAP_H   24
#const  CHIP    20
 
    randomize
    screen 0, MAP_W * CHIP, MAP_H * CHIP + 24, 0
    title "最小コスト経路検索"
 
    //	マップデータを生成。
    dim map, MAP_W, MAP_H
    dim rcmap, MAP_W, MAP_H
    repeat MAP_H
        i = cnt
        repeat MAP_W
            c = rnd( 4 ) + 1
            if ( c == 4 ) { c = -1 }
            map( cnt, i ) = c
        loop
    loop
 
    //	経路用配列。
    //	経路上の各地点の座標が代入されます。
    dim route, 2, 256
 
    gosub *drawmap
 
    mv = 6
    tr = 1
 
    //	移動力指定用入力ボックス
    font msgothic, 16, 0
    color 0, 0, 0
    pos 0, MAP_H * CHiP
    mes "移動力"
    pos 64, MAP_H * CHiP
    input mv
    pos 192, MAP_H * CHiP
    mes "移動回数"
    pos 256, MAP_H * CHiP
    input tr
 
    //	クリックを待つ。
    repeat
        wait 3
        stick keystk, 0
        if ( keystk & 0x0100 ) { gosub *calc_reachcost }
        if ( keystk & 0x0200 ) { gosub *search_route }
    loop
    stop
 
*calc_reachcost
    px = mousex / CHIP
    py = mousey / CHIP
    if ( ( px < 0 ) || ( px >= MAP_W ) || ( py < 0 ) || ( py >= MAP_H ) ) { return }
 
    route( 0, 0 ) = 0
 
    //	指定した地点からの到達コストを求める。
    CreateRCMap rcmap, map, px, py, mv, tr
 
    gosub *drawmap
    return
 
*drawmap
    //	マップ描画。
    redraw 0
 
    font msgothic, CHIP / 2, 0
    repeat MAP_H
        i = cnt
        repeat MAP_W
            if ( rcmap( cnt, i ) == -99 ) {
                color 0, 255, 0
            } else : if ( rcmap( cnt, i ) > 0 ) {
                color 255, 255, 255
            } else : if ( map( cnt, i ) == -1 ) {
                color 0, 0, 255
            } else {
                color 191, 191, 191
            }
            boxf cnt * CHIP, i * CHIP, ( cnt + 1 )* CHIP - 1, ( i + 1 ) * CHIP - 1
            color 0, 0, 0
            pos cnt * CHIP + 2, i * CHIP
            mes map( cnt, i )
            color 255, 0, 0
            mes rcmap( cnt, i )
        loop
    loop
 
    //	ルート描画
    if ( route( 0, 0 ) > 1 ) {
        //	経由地点。
        if( route( 0, 0 ) > 2 ) {
            color 255, 255, 0
            repeat route( 0, 0 ) - 2, 2
                i = route( 1, cnt )
                j = route( 0, cnt )
                boxf j * CHIP, i * CHIP, ( j + 1 )* CHIP - 1, ( i + 1 ) * CHIP - 1
            loop
        }
        //	終点
        color 0, 255, 255
        boxf route( 0, 1 ) * CHIP, route( 1, 1 )* CHIP, ( route( 0, 1 ) + 1 )* CHIP - 1, ( route( 1, 1 ) + 1 ) * CHIP - 1
        repeat route( 0, 0 ), 1
            i = route( 1, cnt )
            j = route( 0, cnt )
            color 0, 0, 0
            pos j * CHIP + 2, i * CHIP
            mes map( j, i )
            color 255, 0, 0
            mes rcmap( j, i )
        loop
    }
 
    color 0, 0, 0
    repeat MAP_W
        line cnt * CHIP, MAP_H * CHIP, cnt * CHIP, 0
    loop
    repeat MAP_H
        line MAP_W * CHIP, cnt * CHIP, 0, cnt * CHIP
    loop
 
    redraw 1
    return
 
*search_route
    rx = mousex / CHIP
    ry = mousey / CHIP
    if ( ( rx < 0 ) || ( rx >= MAP_W ) || ( ry < 0 ) || ( ry >= MAP_H ) ) { return }
 
    FindRoute route, rcmap, rx, ry
 
    gosub *drawmap
    return