将棋 - HSP開発wiki

なんとなく将棋を作ってみました for HSP3 †

[編集]

HSP2用だったサンプルスクリプトをHSP3用に変更。
単純な移植ではなく、一部仕様変更を入れてスクリプトも読みやすいように変更しました。

＜主な機能＞

CPU対戦機能なし。
持ち駒が使えます。
成駒が使えます。（HSP2版での一部間違いを修正）
移動可能なマスが分かります。
何処にでも置けてしまえるのは仕様です。
ぶっちゃけただの将棋盤だと思ってください。

↑

サンプル †

[編集]

[hsp3]
モジュール部分です。

将棋モジュール

mod_syougi.hsp

;
;[ Infomation ]
; Name      : 将棋モジュール
; SubName   : -
; Version   : 2.01
; copyright : GENKI
;
;[ Update history ]
;yyyy/mm/dd : ver : comment
;2012/12/27 : 2.01 : SyougiGetKomaStepを実装。駒の移動可能領域を取得できるようにした。
;2012/12/23 : 2.00 : HSP2版を参考にしつつ全部作り直し。
;                    駒の移動可能領域取得機能はオミット。
;
;[ comment ]
;将棋を作成するためのモジュールです。
;
;成駒の判定や簡単な移動可能範囲のチェックなど、ごく簡単なルール判定が行えます。
;細かなルール判定の能力はありません。
;
;モジュールを読み込んだら、最初に SyougiIni を実行してモジュール内変数を初期化してください。
;駒の情報は配列変数を通してやり取りします。
;
;	dim koma,4,40
;
;などとしてあらかじめ配列変数を用意しておいてください。
;
 
 
;#ifndef __MOD_SYOUGI__
;#define global __MOD_SYOUGI__
#module "syougi"
;---------------------------------------------------------------------------------------------------
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	定数の定義
;
;#const global 
;#enum global 
 
 
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	モジュール初期化
;
;[ Infomation ]
;	SyougiIni
;
;	return : 0
;
;[ comment ]
;モジュールを読み込んだら最初に1回だけ実行してください。
;
 
#deffunc SyougiIni
    ;	駒の名称と略称
    sdim sgKomaNames, 4, 2, 15
    
    ;	駒の名称と略称
    i=0 : sgKomaNames(0, i) = "玉将", "玉"
    i++ : sgKomaNames(0, i) = "金将", "金"
    i++ : sgKomaNames(0, i) = "銀将", "銀"
    i++ : sgKomaNames(0, i) = "桂馬", "桂"
    i++ : sgKomaNames(0, i) = "香車", "香"
    i++ : sgKomaNames(0, i) = "歩兵", "歩"
    i++ : sgKomaNames(0, i) = "飛車", "飛"
    i++ : sgKomaNames(0, i) = "角行", "角"
    i++ : sgKomaNames(0, i) = "と金", "と"
    i++ : sgKomaNames(0, i) = "成香", "成香"
    i++ : sgKomaNames(0, i) = "成桂", "成桂"
    i++ : sgKomaNames(0, i) = "成銀", "成銀"
    i++ : sgKomaNames(0, i) = "竜馬", "馬"
    i++ : sgKomaNames(0, i) = "竜王", "竜"
    i++ : sgKomaNames(0, i) = "王将", "王"
 
 
 
    ;	駒の動きの定義
    dim sgKomaMove, 14
    ;移動方法の設定は次のように記号を割り振っている。
    ;1～A：指定駒にのみ移動可能
    ;B～F：無限に移動可能。敵を飛び越すことはない。
    ;   0：元の位置
    ;
    ;        C
    ;    D 6 A 6 D
    ;    7 3 1 3 7
    ;    E 4 0 4 E
    ;    8 5 2 5 8
    ;    F 9 B 9 F
    ;
    ;この情報を1個の変数に収納する際は次のようにビットと記号を対応付けた。
    ;
    ; FEDCBA987654321
    ;%000000000000000
    ;
 
 
    ;%000000000000000
    ; FEDCBA987654321
    sgKomaMove( 0) = %000000000011111    ;玉：1 + 2 + 3 + 4 + 5
    sgKomaMove( 1) = %000000000001111    ;金：1 + 2 + 3 + 4
    sgKomaMove( 2) = %000000000010101    ;銀：1 + 3 + 5
    sgKomaMove( 3) = %000000000100000    ;桂：6
    sgKomaMove( 4) = %000100000000000    ;香：C
    sgKomaMove( 5) = %000000000000001    ;歩：1
    sgKomaMove( 6) = %010110000000000    ;飛：C + B + E
    sgKomaMove( 7) = %101000000000000    ;角：D + F
    ;成駒
    sgKomaMove( 8) = %000000000001111    ;と    ：1 + 2 + 3 + 4
    sgKomaMove( 9) = %000000000001111    ;成香  ：1 + 2 + 3 + 4
    sgKomaMove(10) = %000000000001111    ;成桂  ：1 + 2 + 3 + 4
    sgKomaMove(11) = %000000000001111    ;成銀  ：1 + 2 + 3 + 4
    sgKomaMove(12) = %101000000011111    ;馬(角)：1 + 2 + 3 + 4 + 5 + D + F
    sgKomaMove(13) = %010110000011111    ;龍(飛)：1 + 2 + 3 + 4 + 5 + C + B + E
 
 
    ;	作業用の将棋盤配列
    dim sgBanTableTmp, 9, 9
 
    return
 
 
 
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	駒情報を初期化
;
;[ Infomation ]
;	SyougiIniKoma array koma
;	koma : 駒情報を収納した配列変数
;
;	return : 0
;
;[ comment ]
;指定した配列変数に駒の初期情報を設定します。
;通常ルールでゲーム開始する場合の駒配置です。
;
;配列は事前の初期化が必要。
;	dim koma,4,40
;
;配列変数の内容は次の通り。
;	koma( (0:横)/(1:縦)/(2:駒)/(3:自0/敵1), (駒ID) )
;	例：koma(0,0) = 8, 3, 0, 1
;	koma(0,0) = 8	;駒位置。横。-1のとき持ち駒。
;	koma(1,0) = 3	;駒位置。縦。-1のとき持ち駒。
;	koma(2,0) = 0	;駒の種類
;	koma(3,0) = 1	;駒の持ち主(自分=0、相手=1)
;
;    駒の種類
;     0 : 玉将
;     1 : 金将
;     2 : 銀将
;     3 : 桂馬
;     4 : 香車
;     5 : 歩兵
;     6 : 飛車
;     7 : 角行
;     8 : と金
;     9 : 成香
;    10 : 成桂
;    11 : 成銀
;    12 : 竜馬
;    13 : 竜王
;
#deffunc SyougiIniKoma array koma
 
    ;	自分の駒
    i = 0
    ;玉
    koma(0,i) = 5, 9, 0
    i++
 
    ;金
    repeat 2
        koma(0,i) = cnt * 2 + 4, 9, 1
        i++
    loop
 
    ;銀
    repeat 2
        koma(0,i) = cnt * 4 + 3, 9, 2
        i++
    loop
 
    ;桂
    repeat 2
        koma(0,i) = cnt * 6 + 2, 9, 3
        i++
    loop
 
    ;香
    repeat 2
        koma(0,i) = cnt * 8 + 1, 9, 4
        i++
    loop
 
    ;歩
    repeat 9
        koma(0,i) = cnt + 1, 7, 5
        i++
    loop
 
    ;飛
        koma(0,i) = 2, 8, 6
        i++
 
    ;角
        koma(0,i) = 8, 8, 7
        i++
 
    all = i
    repeat all
        koma(3,cnt) = 0
    loop
 
 
    ;	相手方の駒
    ;自分の駒と上下位置をひっくり返しています。
    i = all
    j = 0
    repeat all
        koma(0,i) = 10 - koma(0, j)
        koma(1,i) = 10 - koma(1, j)
        koma(2,i) = koma(2, j)
        koma(3,i) = 1    ;相手駒
        i++ : j++
    loop
 
    return
 
 
 
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	駒の種類名を取得
;
;[ Infomation ]
;	res = SyougiConvertKomaName( int typeID, int outf )
;	typeID=0～(0) : 駒の種類
;	outf : 出力フラグ
;
;	return : 駒の名称文字列
;
;[ comment ]
;駒の種類IDから駒の名称を判定して出力します。
;名称は正式名称、略称が選べます。
;
;outfに相手駒を指定した場合は、typeID=0のとき「王」ではなく「玉」を返します。
;それ以外の場合は同じ結果を返します。
;
;outf
;	0:駒の正式名称
;	1:駒の略称
;	2:相手駒
;となります。
;相手駒の玉の略称なら、次のようになります。
;	res = SyougiConvertKomaName( 0, 3 )
;
#defcfunc SyougiConvertKomaName int typeID, int outf
    ;	引数チェック
    if ( typeID<0 )&( typeID>13 ) : return "E"
    
    t = typeID
    f = 0
    if outf & 1 : f = 1    ;略称
    if ((outf & 2)=2) & (t = 0) : t = 14    ;王将（相手駒）
    
    return sgKomaNames(f, t)
 
 
 
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	移動した駒が成駒となる条件を満たしているか判定
;
;[ Infomation ]
;	SyougiValidateNarigoma int typeID, var typeIDNew, int masuXold, int masuYold, int masuX, int masuY, int komaUser
;	typeID=0～(0)      : 駒の種類
;	typeIDNew          : 新しい駒の種類を取得する変数
;	masuXold, masuYold : 動かす前の駒の位置（1～9）
;	masuX,    masuY    : 新しい駒の移動先（1～9）
;	komaUser : 駒の持ち主（0=自分、1=相手）
;
;	return : 0,1,2
;		0 = 成れない
;		1 = 成れる
;		2 = 取られている（持駒）
;
;[ comment ]
;駒の成・不成の条件判定をして、成れる場合は成駒の駒の種類を返します。
;
;typeIDNewには成駒になった新しい駒の種類を返します。
;駒が取られていた（持駒）場合は、成駒を解除した結果を返します。
;
;
#deffunc SyougiValidateNarigoma int typeID, var typeIDNew, int masuXold, int masuYold, int masuX, int masuY, int komaUser
    res = 0
    typeIDNew = typeID
 
    ;
    ;	成駒に成るための条件を満たしているか判定
    ;
    ;	・規定外の間違った駒の種類が指定されている場合。
    ;	・そもそも移動していない場合は成れない。
    if (typeID<0) | (13<typeID) | ( (masuXold = masuX) & (masuYold = masuY) ){
        ;	成れない場合はそのままを返す
        return 0
    }
 
 
    ;
    ;	成駒を解除
    ;
    ;取られて持ち駒になった駒
    if masuY < 0 {
        ;成を元に戻す
        if typeID =11 : typeIDNew = 2    ;銀←成銀
        if typeID =10 : typeIDNew = 3    ;桂←成桂
        if typeID = 9 : typeIDNew = 4    ;香←成香
        if typeID = 8 : typeIDNew = 5    ;歩←と
        if typeID =13 : typeIDNew = 6    ;飛←龍
        if typeID =12 : typeIDNew = 7    ;角←馬
        return 2
    }
    
    
    ;
    ;	成駒に成れない駒を除外
    ;
    ;・駒の種類によって選別。既に成駒のものや成れないものを除外
    ;・持ち駒を打ったときは必ず成れない
    ;
    if (typeID<2) | (7<typeID) | (masuYold<0): return 0
 
 
    ;
    ;	移動前後の位置から成駒に成れるか判定
    ;
    ;成駒の条件はこうなる。
    ;  ・移動先が陣内 or 移動前が陣内
    ;
    ;条件を満たしていたら fjin=1 にする。
    fjin = 0
    if komaUser&1 {
        ;	相手
        if masuYold >= 7 : fjin = 1    ;移動元が陣内
        if masuY    >= 7 : fjin = 1    ;移動先が陣内
    } else {
        ;	自分
        if masuYold <= 3 : fjin = 1    ;移動元が陣内
        if masuY    <= 3 : fjin = 1    ;移動先が陣内
    }
    
 
    ;
    ;	判定結果を反映
    ;
    if fjin&1 {
        ;成りに変換
        if typeID = 2 : typeIDNew = 11    ;銀→成銀
        if typeID = 3 : typeIDNew = 10    ;桂→成桂
        if typeID = 4 : typeIDNew = 9    ;香→成香
        if typeID = 5 : typeIDNew = 8    ;歩→と
        if typeID = 6 : typeIDNew = 13    ;飛→龍
        if typeID = 7 : typeIDNew = 12    ;角→馬
        res = 1
    }
 
    return res
 
 
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	成駒をもとに戻す
;
;[ Infomation ]
;	res = SyougiConvertUnNarigoma( int typeID )
;	typeID=0～(0)      : 駒の種類
;
;	return : 成駒に成る前の駒の種類
;
;[ comment ]
;成駒を通常に戻す。
;
;
#defcfunc SyougiConvertUnNarigoma int typeID
    typeIDNew = typeID
 
    ;成を元に戻す
    if typeID =11 : typeIDNew = 2    ;銀←成銀
    if typeID =10 : typeIDNew = 3    ;桂←成桂
    if typeID = 9 : typeIDNew = 4    ;香←成香
    if typeID = 8 : typeIDNew = 5    ;歩←と
    if typeID =13 : typeIDNew = 6    ;飛←龍
    if typeID =12 : typeIDNew = 7    ;角←馬
 
    return typeIDNew
 
 
 
 
 
 
 
;///////////////////////////////////////////////////////////////////////////////////////////////////
;
;	移動可能座標テーブルを取得
;
;[ Infomation ]
;	SyougiGetKomaStep array p1, array koma, int kmid, int iset, int vrkx, int vrky
;	p1   : 移動可能座標テーブル 配列変数
;	koma=0～39
;        : 駒情報を収納した配列変数
;	kmid : 移動する駒ID
;	iset : セットする値
;	vrkx : 仮座標X
;	vrky : 仮座標Y
;
;	return : 0
;
;[ comment ]
;全ての駒情報を収納した配列変数komaから状況を判断し、駒ID=kmidの駒を移動した場合の
;移動可能座標を取得します。
;
;結果はp1に9*9の配列変数として出力されます。
;配列番号0～8は+1して1～9として利用してください。
;移動可能な座標にisetで指定した値をor演算で書き込みます。
;
;or演算で書き込むため、通常は事前に次のように出力先配列変数をリセットして利用します。
;	memset p1, 0, 324
;
;vrkx, vrkyに1～9の値を指定すると、kmidの駒を仮にその座標に移動した場合の
;移動可能座標テーブルを出力します。
;
#deffunc SyougiGetKomaStep array p1, array koma, int kmid, int iset, int vrkx, int vrky
    ;	引数チェック
    if (kmid < 0) | (39 < kmid) : return
    
    ;	引数に仮座標が設定されているかチェック
    if (0<vrkx)&(vrkx<10) & (0<vrky)&(vrky<10) : flgTempPos = 1 : else : flgTempPos = 0
    
    ;	持駒で仮座標も設定されていない場合
    if (flgTempPos = 0) & (koma(0,kmid)<0) : return
    
    ;	駒の所有権
    ;	処理の都合上、±1の方がいいのでこういう処理をしています。
    ;	 1 : 自分
    ;	-1 : 相手
    if koma(3,kmid) : komaUser = -1 : else : komaUser = 1
    
    
    
    ;
    ;	作業用将棋盤を作成
    ;
    ;盤テーブルには盤上にある駒が自分か相手かだけを書き込む。
 
    ;	作業領域初期化
    ;	 1 : 自分
    ;	-1 : 相手
    ;	 0 : 空白
    memset sgBanTableTmp, 0, 324    ;9*9*4 byte = 324 byte
 
    ;	駒を将棋盤に反映
    repeat 40
        ;	変換：1-9 → 0-8
        i = koma(0,cnt) - 1
        j = koma(1,cnt) - 1
        if (i>=0) & (j>=0) {
            if koma(3,cnt) : sgBanTableTmp(i,j) = -1 : else : sgBanTableTmp(i,j) = 1
        }
    loop
 
 
    ;	駒の移動先を出力
    ;sgKomaMove : 駒の動き定義
    ;kmvx, kmvy : 駒の移動相対座標
 
 
 
    if sgKomaMove( koma(2, kmid) ) & 1    : kmvx = 0 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
    if sgKomaMove( koma(2, kmid) ) & 2    : kmvx = 0 : kmvy = 1 : gosub *l_SyougiGetKomaStep_sub
    if sgKomaMove( koma(2, kmid) ) & 4 {;3
        kmvx =-1 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 1 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & 8 {;4
        kmvx =-1 : kmvy = 0 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 1 : kmvy = 0 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & 16 {;5
        kmvx =-1 : kmvy = 1 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 1 : kmvy = 1 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & 32 {;6
        kmvx =-1 : kmvy =-2 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 1 : kmvy =-2 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & 64 {;7
        kmvx =-2 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 2 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & 128 {;8
        kmvx =-2 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 2 : kmvy =-1 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & 256 {;9
        kmvx =-1 : kmvy = 2 : gosub *l_SyougiGetKomaStep_sub
        kmvx = 1 : kmvy = 2 : gosub *l_SyougiGetKomaStep_sub
    }
    if sgKomaMove( koma(2, kmid) ) & %000010000000000 {;B(11)
        fkstp = 0    ;無限移動ストップフラグ
        kmvx = 0 : kmvy = 0
        repeat 8
            kmvy++ : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
    }
    if sgKomaMove( koma(2, kmid) ) & %000100000000000 {;C(12)
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvy-- : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
    }
    if sgKomaMove( koma(2, kmid) ) & %001000000000000 {;D(13)
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvx++ : kmvy-- : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvx-- : kmvy-- : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
    }
    if sgKomaMove( koma(2, kmid) ) & %010000000000000 {;E(14)
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvx++ : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvx-- : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
    }
    if sgKomaMove( koma(2, kmid) ) & %100000000000000 {;F(15)
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvx++ : kmvy++ : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
        fkstp = 0 : kmvx = 0 : kmvy = 0
        repeat 8
            kmvx-- : kmvy++ : gosub *l_SyougiGetKomaStep_sub
            if fkstp = 1 : break
        loop
    }
 
    return
 
 
 
;
;	SyougiGetKomaStep用のサブルーチン
;
*l_SyougiGetKomaStep_sub
 
    if flgTempPos {
        ;仮想駒座標が設定されている場合
        i = vrkx + kmvx
        j = vrky + kmvy * komaUser        ;先手、後手で向きが逆になる。
    } else {
        ;現在の駒の座標で移動先を探す
        i = koma(0,kmid) + kmvx
        j = koma(1,kmid) + kmvy * komaUser        ;先手、後手で向きが逆になる。
    }
    ;予想位置には1が入り、それ以外は0
    if (0<i)&(i<10) & (0<j)&(j<10) {
        ;盤座標は1-9なのでi,jは-1して0-8になるようにする。
        i-- : j--
        
        ;	移動先が味方でなければ移動できる
        if sgBanTableTmp(i,j) ! komaUser : p1(i,j) |= iset
        
        ;	移動先が空白でない場合、無限移動を停止
        if sgBanTableTmp(i,j) ! 0 : fkstp = 1
    }
    
    return
 
 
;---------------------------------------------------------------------------------------------------
#global
;#endif	;__MOD_SYOUGI__

サンプル部分です。モジュールと同じフォルダにおいて実行してください。
長いですがHSP2版よりは読みやすいと思います。

将棋サンプル

syougi02.hsp

;
;[ Infomation ]
; Name      : 将棋盤
; SubName   : 
; Version   : 2.0
; copyright : GENKI
;
;[ Update history ]
;yyyy/mm/dd : ver : comment
;2012/12/27 : 2.01: 座標を表示するようにした。
;2012/12/25 : 2.0 : HSP2版を参考にしつつ全部作り直し。
;                   ・細部で仕様が異なる。
;                   ・何でもかんでもモジュールに突っ込んでいたのを、将棋の機能部分に限定してモジュール化した。
;
 
;-------------------------------------------------------------------------------
;
;	モジュール、プラグインの読み込み
;
;#include ""
#module
;----------------------------------------
;矩形の枠のみを描画する
;    パラメータはboxfと同じ
#deffunc boxl int x1, int y1, int x2, int y2
    ;mref x1, 0
    ;mref y1, 1
    ;mref x2, 2
    ;mref y2, 3
 
    line x1, y1, x2, y1
    line x2, y1, x2, y2
    line x2, y2, x1, y2
    line x1, y2, x1, y1
    return
#global
 
 
#include "mod_syougi.hsp"
 
 
 
 
;-------------------------------------------------------------------------------
;
;	初期化
;
 
 
 
    ;-----------------------------------
    ;
    ;	
    ;
    SyougiIni
 
    ;	将棋盤
    ;サイズ
    sgBanSizeWidth  = 9*32
    sgBanSizeHeight = sgBanSizeWidth
    sgBanSizeMasu   = double(sgBanSizeWidth) / 9
    ;表示位置
    sgBanPosX = 220
    sgBanPosY = 180
 
    ;	駒台
    ;サイズ
    sgDaiASizeWidth  = 100
    sgDaiASizeHeight = sgBanSizeHeight
    sgDaiBSizeWidth  = 100
    sgDaiBSizeHeight = sgBanSizeHeight
    ;表示位置
    sgDaiAPosX = sgBanPosX + sgBanSizeWidth + 10
    sgDaiAPosY = sgBanPosY
    sgDaiBPosX = sgBanPosX - sgDaiBSizeWidth - 10
    sgDaiBPosY = sgBanPosY
 
    ;	将棋盤配列（移動可能座標取得用）
    ;右上（1,1）がsgBanTableMove(0,0)となる。
    ;駒の移動可能領域を取得する際に使用します。
    dim sgBanTableMove, 9, 9
 
 
    ;	駒
    ;全ての駒のパラメータを格納している変数
    ;
    ;sgKoma( (0:横)/(1:縦)/(2:駒)/(3:自0/敵1), (駒ID) )
    ;例：sgKoma(0,0) = 8, 3, 0, 1
    ;sgKoma(0,0) = 8	;駒位置。横。-1で持ち駒？
    ;sgKoma(1,0) = 3	;駒位置。縦
    ;sgKoma(2,0) = 0	;駒種類
    ;sgKoma(3,0) = 1	;駒の持ち主(自分+1、相手-1)
    ;
    dim sgKoma,4,40
 
    ;	駒情報を初期化
    SyougiIniKoma sgKoma
 
 
    ;mousePosX, mousePosY
    ;	盤上のマウス位置
    ;	右上が0,0、左下が9,9となる。
    ;	盤上にマウスがない場合は-1
    ;mousePosKomaID
    ;	マウス位置の駒ID
    ;	マウスが当たっている駒の駒ID
    ;	当たっていない時は-1
    ;selectionKomaID
    ;	選択した駒ID
    ;	通常、動かすために選択する。
    ;	選択している駒が無い時は -1
    ;
    mousePosX = -1
    mousePosY = -1
    mousePosKomaID  = -1
    selectionKomaID = -1
 
 
    ;	ターン
    ;	0 : 自分
    ;	1 : 相手
    sgTurn  = 0
    sgTurn0 = 0    ;ループ処理用。前のループでのターン状態
 
 
 
;-------------------------------------------------------------------------------
;
;	ウィンドウ作成
;
    ;-----------------------------------
    ;
    ;	駒台から駒を取るボタン
    ;
    ;作りこんでもサンプルとしてわかりにくくなるのでボタンでの実装
    pos sgDaiAPosX, sgDaiAPosY - 24
    button gosub "駒台（自分）", *l_SyougiKomadaiA
    pos sgDaiBPosX, sgDaiBPosY - 24
    button gosub "駒台（相手）", *l_SyougiKomadaiB
 
 
;-------------------------------------------------------------------------------
;
;	データ読み込み
;
    ;-----------------------------------
    ;
    ;	
    ;
 
 
 
;-------------------------------------------------------------------------------
;
;	メインループ
;
*main
    redraw 1 : await 33 : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
    
    sgTurn0 = sgTurn
    
    ;-----------------------------------
    ;
    ;	入力を取得
    ;
    stick key
    mx = mousex
    my = mousey
 
    if key&128 : end
 
 
 
 
    ;-----------------------------------
    ;
    ;	マウス位置の情報を取得
    ;
    
    ;
    ;	マウスの盤上での位置を取得
    ;
    ;マウスの盤上の座標を取得。
    ;右上が1,1、左下が9,9となる。将棋盤の外は-1。
    ;	mousePosX : 1～9
    ;	mousePosX : 1～9
    ;
    x = double(mx - sgBanPosX) / sgBanSizeMasu
    y = double(my - sgBanPosY) / sgBanSizeMasu
    if x<0 : mousePosX = -1 : else : mousePosX = 9 - x
    if y<0 : mousePosY = -1 : else : mousePosY = 1 + y
    if (mousePosX<1) | (9<mousePosX) | (mousePosY<1) | (9<mousePosY) : mousePosX = -1 : mousePosY = -1
 
 
    ;
    ;	マウス位置の駒IDを取得
    ;
    ;結果はmousePosKomaIDに代入される。
    ;マウスが盤上にない場合は -1 になる。
    mousePosKomaID = -1
    repeat 40
        if (sgKoma(0,cnt) = mousePosX) & (sgKoma(1,cnt) = mousePosY) {
            if mousePosX >= 0 {
                mousePosKomaID = cnt
                break
            }
        }
    loop
    
    
    
    
    ;-----------------------------------
    ;
    ;	マウス操作
    ;
    
    ;
    ;	駒を選択　操作
    ;
    if key&256 {    ;	左クリック
        if selectionKomaID < 0 {
            ;	駒を持っていない場合
            ;マウスが当たっている駒を選択
            ;そこに駒がなければ-1
            selectionKomaID = mousePosKomaID
        } else {
            ;	駒を持った状態だった場合
            ;盤上かどうかチェック
            ;元の場所と同じでないかチェック
            if (mousePosX>=0) & (mousePosY>=0) & (selectionKomaID ! mousePosKomaID) {
                ;
                ;	ルール判定
                ;
                
                ;	ここで駒がここに置けるかどうかの判定が必要。でも省略。
                
                ;	駒の成・不成の条件判定
                SyougiValidateNarigoma sgKoma(2, selectionKomaID), typeID, sgKoma(0, selectionKomaID), sgKoma(1, selectionKomaID), mousePosX, mousePosY, sgKoma(3, selectionKomaID)
                r = stat
 
 
                ;
                ;	移動先にある駒の情報を更新
                ;
                ;	持ち駒にする。所有権の書き換え
                repeat 40
                    if (sgKoma(0, cnt) = mousePosX) & (sgKoma(1, cnt) = mousePosY) {
                        ;	持ち駒にする
                        sgKoma(0, cnt) = -1
                        sgKoma(1, cnt) = -1
                        ;	所有権変更
                        sgKoma(3, cnt) = sgKoma(3, selectionKomaID)
                        ;	成駒解除
                        sgKoma(2, cnt) = SyougiConvertUnNarigoma( sgKoma(2, cnt) )
                        ;	駒の種類を成駒→通常に変換。これも省略。
                        break
                    }
                loop
 
 
                ;
                ;	選択駒の情報を更新
                ;
                ;	選択した駒を指定した場所へ置く
                sgKoma(0, selectionKomaID) = mousePosX
                sgKoma(1, selectionKomaID) = mousePosY
    
 
                ;
                ;	成駒の判定結果を反映
                ;
                
                ;	成駒の条件を満たす場合
                if r = 1 {
                    dialog "成りますか？", 2, "成駒判定"
                    if stat = 6 : sgKoma(2, selectionKomaID) = typeID
                }
                ;	駒が取られていた場合
                ;if r = 2 : sgKoma(2, selectionKomaID) = typeID
 
 
                ;
                ;	ターンエンド
                ;
                selectionKomaID = -1
                sgTurn ^= 1
                
            } else {
                ;	・盤上以外
                ;	・元の場所
                ;	をクリックした場合
                ;	選択解除
                selectionKomaID = -1
            }
        }
    }
    
    ;
    ;	駒の選択解除　操作
    ;
    if key&512 {    ;	右クリック
        selectionKomaID = -1
    }
 
 
 
 
    ;-----------------------------------
    ;
    ;	移動可能座標を取得
    ;
    ;指定した駒の移動可能座標をsgBanTableMoveに取得
    ;	0:置けない
    ;	1:１手先。選択中またはカーソルが乗っている駒。
    ;	2:２手先。選択中またはカーソルが乗っている駒。
    ;	4:１手先。選択中の駒（カーソルと一緒に動きます）
    ;
 
    ;入れ物をリセットしてから使う必要がある。
    memset sgBanTableMove, 0, 324    ;9*9*4 byte = 324 byte
 
    ;	カーソル位置の駒
    if selectionKomaID < 0 {
        ;	駒が選択されていない場合は、カーソルが当たっている駒の移動可能座標を取得
        km = mousePosKomaID
    } else {
        ;	選択された駒がある場合は、選択された駒の元の位置からの移動可能座標を取得
        km = selectionKomaID
    }
    if km >= 0 {
        ;	1手先の移動可能座標を取得
        SyougiGetKomaStep sgBanTableMove, sgKoma, km, 1
        
        ;	2手先の移動可能座標を取得
        repeat 9
            i = cnt
            repeat 9
                if sgBanTableMove(i,cnt) & 1 {
                    SyougiGetKomaStep sgBanTableMove, sgKoma, km, 2, i+1, cnt+1
                }
            loop
        loop
    }
    
    ;	選択駒の次の移動先
    if selectionKomaID >= 0 {
        SyougiGetKomaStep sgBanTableMove, sgKoma, selectionKomaID, 4, mousePosX, mousePosY
    }
 
 
 
 
 
    ;-----------------------------------
    ;
    ;	画面の描画
    ;
 
 
    ;
    ;	将棋盤の描画
    ;
    ;	座標
    color 127,127,127
    repeat 9
        pos sgBanPosX + sgBanSizeWidth - (0.5+cnt)*sgBanSizeMasu, sgBanPosY - 17
        mes (cnt+1)
        pos sgBanPosX + sgBanSizeWidth + 1 , sgBanPosY + cnt*sgBanSizeMasu + 6
        mes (cnt+1)
    loop
    ;	枠線を引くだけ
    color
    s = sgBanSizeMasu
    repeat 10
        line         sgBanPosX, s*cnt + sgBanPosY, sgBanSizeWidth + sgBanPosX, s*cnt           + sgBanPosY
        line s*cnt + sgBanPosX,         sgBanPosY, s*cnt          + sgBanPosX, sgBanSizeHeight + sgBanPosY
    loop
    ;	星を描画
    s = sgBanSizeMasu * 3
    circle s*1 + sgBanPosX -2, s*1 + sgBanPosY -2, s*1 + sgBanPosX +3, s*1 + sgBanPosY +3
    circle s*2 + sgBanPosX -2, s*1 + sgBanPosY -2, s*2 + sgBanPosX +3, s*1 + sgBanPosY +3
    circle s*1 + sgBanPosX -2, s*2 + sgBanPosY -2, s*1 + sgBanPosX +3, s*2 + sgBanPosY +3
    circle s*2 + sgBanPosX -2, s*2 + sgBanPosY -2, s*2 + sgBanPosX +3, s*2 + sgBanPosY +3
 
 
    ;
    ;	駒台の描画
    ;
    ;これも枠線を引くだけ
    boxl sgDaiAPosX, sgDaiAPosY, sgDaiAPosX + sgDaiASizeWidth, sgDaiAPosY + sgDaiASizeHeight
    boxl sgDaiBPosX, sgDaiBPosY, sgDaiBPosX + sgDaiBSizeWidth, sgDaiBPosY + sgDaiBSizeHeight
    
 
 
    ;
    ;	移動可能座標を表示
    ;
    repeat 9
        i = cnt
        repeat 9
            ;	2手先
            if sgBanTableMove(i, cnt) & 2 {
                ;	左上0,0の座標に変換
                kx = 8 - i
                ky = cnt
                ;	枠描画座標
                x1 = sgBanSizeMasu * kx + sgBanPosX
                y1 = sgBanSizeMasu * ky + sgBanPosY
                x2 = x1 + sgBanSizeMasu
                y2 = y1 + sgBanSizeMasu
                ;	描画
                color 0,255,255
                boxf x1 + 1, y1 + 1, x2 - 1, y2 - 1
            }
            
            ;	1手先
            if sgBanTableMove(i, cnt) & 1 {
                ;	左上0,0の座標に変換
                kx = 8 - i
                ky = cnt
                ;	枠描画座標
                x1 = sgBanSizeMasu * kx + sgBanPosX
                y1 = sgBanSizeMasu * ky + sgBanPosY
                x2 = x1 + sgBanSizeMasu
                y2 = y1 + sgBanSizeMasu
                ;	描画
                color 0,0,255
                boxf x1 + 1, y1 + 1, x2 - 1, y2 - 1
            }
 
            ;	選択駒の１手先
            if sgBanTableMove(i, cnt) & 4 {
                ;	左上0,0の座標に変換
                kx = 8 - i
                ky = cnt
                ;	枠描画座標
                x1 = sgBanSizeMasu * kx + sgBanPosX
                y1 = sgBanSizeMasu * ky + sgBanPosY
                x2 = x1 + sgBanSizeMasu
                y2 = y1 + sgBanSizeMasu
                ;	描画
                color 0,255,0
                boxf x1 + 1, y1 + 1, x2 - 1, y2 - 1
            }
 
        loop
    loop
    
 
 
 
    ;
    ;	駒の描画
    ;
    ka = 0 : kb = 0    ;持ち駒のためのカウンタ
    repeat 40
        if sgKoma(0, cnt)<0 {
            ;
            ;	持ち駒
            ;
            ;ソートとかそういうのはとりあえず無視。
            color
            if sgKoma(3, cnt)&1 {
                ;	相手駒
                pos sgDaiBPosX + int(kb/9)*20, sgDaiBPosY + kb\9 * 25
                mes "" + SyougiConvertKomaName( sgKoma(2, cnt), 1)
                kb++
            } else {
                ;	自分駒
                pos sgDaiAPosX + int(ka/9)*20, sgDaiAPosY + ka\9 * 25
                mes "" + SyougiConvertKomaName( sgKoma(2, cnt), 3)
                ka++
            }
        } else {
            ;
            ;	盤上の駒
            ;
    
            ;	駒の配置から描画座標を算出
            x = sgBanSizeMasu * (10 - sgKoma(0, cnt) -1) + sgBanPosX
            y = sgBanSizeMasu * (     sgKoma(1, cnt) -1) + sgBanPosY
            pos x, y
            ;	相手駒かどうかチェック
            m = ""
            if sgKoma(3, cnt)&1 {
                f = 2
                m = "▽"
            } else {
                f = 0
                m = "▲"
            }
            ;	成駒は赤く表示
            if sgKoma(2, cnt) >= 8 : color 255 : else : color
            ;	駒の略称をそのまま描画
            mes m + SyougiConvertKomaName( sgKoma(2, cnt), f | 1)
        }
    loop
 
 
 
 
    ;
    ;	盤上のカーソル描画
    ;
 
    ;	マウスが盤上のマスを指す場合のみカーソルを表示
    if mousePosX > 0 {
        ;	左上0,0の座標に変換
        kx = 9 - mousePosX
        ky = mousePosY - 1
        ;	枠描画座標
        x1 = sgBanSizeMasu * kx + sgBanPosX
        y1 = sgBanSizeMasu * ky + sgBanPosY
        x2 = x1 + sgBanSizeMasu
        y2 = y1 + sgBanSizeMasu
        ;	描画
        color 255,0,0
        boxl x1 + 1, y1 + 1, x2 - 1, y2 - 1
    }
    
 
 
 
    ;
    ;	選択中の駒を描画
    ;
    color
    if selectionKomaID >= 0 {
        pos mx, my - 20
        if sgKoma(3, selectionKomaID)&1 : f = 2 : else : f = 0
        m = SyougiConvertKomaName( sgKoma(2, selectionKomaID), f|1)
        ;	自分/相手どっちの駒か表示
        if sgKoma(3, selectionKomaID) = 0 : m += "▲"    ;自分
        if sgKoma(3, selectionKomaID) = 1 : m += "▽"    ;相手
        mes m
    }
 
 
 
    ;
    ;	デバッグ用状態表示
    ;
    pos 0,0 : color
    if sgTurn=0 : m = "自分" : else : m = "相手"
    mes "ターン：" + m + " (" + sgTurn + ")"
    
    ;	マウス位置
    mes "マウスの位置情報"
    mes "Pos : " + mousePosX + ", " + mousePosY
    ;	選択中の駒の情報を表示
    if selectionKomaID>=0 {
        m = SyougiConvertKomaName( sgKoma(2, selectionKomaID), 0)
        if sgKoma(3, selectionKomaID) = 0 : m += "▲"    ;自分
        if sgKoma(3, selectionKomaID) = 1 : m += "▽"    ;相手
    } else {
        m = " - "
    }
    m += "(" + selectionKomaID + ")"
    mes "選択中の駒：" + m
    
    ;	マウスが当たっている駒の情報を表示
    mes "マウスカーソルが当たっている駒の情報"
    mes "駒 ID : " + mousePosKomaID
    if mousePosKomaID < 0 {
        mes "Pos : -, -"
        mes "選択した駒 : none"
        mes "所有権 : ?"
    } else {
        mes "Pos : " + sgKoma(0, mousePosKomaID) + ", " + sgKoma(0, mousePosKomaID)
        if sgKoma(3, mousePosKomaID)&1 : f = 2 : else : f = 0
        mes "選択した駒 : " + SyougiConvertKomaName( sgKoma(2, mousePosKomaID), f)
        if sgKoma(3, mousePosKomaID)&1 : m = "相手" : else : m = "自分"
        mes "所有権 : " + m
    }
 
 
 
 
 
 
    ;
    ;	ターンエンド処理
    ;
    if sgTurn0 ! sgTurn {
        komadaiACount = 0
        komadaiBCount = 0
    }
 
 
    goto *main
 
stop
 
 
;-------------------------------------------------------------------------------
;
;	サブルーチン
;
 
 
;/////////////////////////////////////////////////
;
;	自分の駒台から駒をゲット
;
;ボタンを押すたびに持駒を順番に持ち替えます。
;持った駒は通常と同じように選択した駒として扱えます。
;
*l_SyougiKomadaiA
 
    ;	選択を解除
    selectionKomaID = -1
 
 
    ;-----------------------------------
    ;
    ;	持駒を選択
    ;
    ;komadaiACountはこのルーチンが実行されるたびに1増えます。
    ;クリックするたびに次の持駒に持ち替えています。
    ;
    ;持駒を持っていない場合は-1のままになります。
    i = 0
    repeat 40
        if ( sgKoma(0, cnt) < 0 ) & ( sgKoma(3, cnt) = 0) {
            if i >= komadaiACount {
                selectionKomaID = cnt
                komadaiACount++
                break
            }
            i++
        }
    loop
    if selectionKomaID = -1 : komadaiACount = 0    ;選べる駒がなくなったらカウンタリセット
 
    return
 
 
 
 
;/////////////////////////////////////////////////
;
;	相手の駒台から駒をゲット
;
;ボタンを押すたびに持駒を順番に持ち替えます。
;持った駒は通常と同じように選択した駒として扱えます。
;
*l_SyougiKomadaiB
 
    ;	選択を解除
    selectionKomaID = -1
 
 
    ;-----------------------------------
    ;
    ;	持駒を選択
    ;
    ;komadaiBCountはこのルーチンが実行されるたびに1増えます。
    ;クリックするたびに次の持駒に持ち替えています。
    ;
    ;持駒を持っていない場合は-1のままになります。
    i = 0
    repeat 40
        if ( sgKoma(0, cnt) < 0 ) & ( sgKoma(3, cnt) = 1) {
            if i >= komadaiBCount {
                selectionKomaID = cnt
                komadaiBCount++
                break
            }
            i++
        }
    loop
    if selectionKomaID = -1 : komadaiBCount = 0    ;選べる駒がなくなったらカウンタリセット
 
    return

名前入れていますが、好きに改造して好きに使っていただくことができます。
NYSLです。 -- GENKI?
変数sgKomaとsgBanTableMove?、mousePosX 、mousePosY 、mousePosKomaID、selectionKomaID　あたりが重要な変数です。その辺を注意しながら読めば理解しやすいかと思います。 -- GENKI?

↑

遊び方 †

[編集]

マウス操作です。
適当に操作して遊んでください。
ルール無用で何処にでも置けます。ずっと俺のターンでもOK。
遊ぶだけなら単純に無電源の将棋盤の代わり程度と思ってください。
サンプルとして作成しています。サンプルとして遊んでください。

↑

解説 †

[編集]

解説文については基本的には下記のHSP2版と同じです。
「駒がもつ情報」の駒の持ち主だけ説明の仕様を変更しています。

HSP2版：駒の持ち主(先手+1、後手-1)
HSP3版：駒の持ち主(自分=0、相手=1)

実装の違いは結構あるので説明は省略します。HSP3版だけみてください。

↑

なんとなく将棋を作ってみました for HSP2 †

[編集]

動かし方すら知らなかったので今回改めて動かし方知りました。（ォィ
将棋ゲームを作る際の参考になれば幸いです。
＜更新内容＞

持ち駒使えます。
成ります。

＜主な機能＞

速度面一切考慮なし。
CPU対戦機能なし。
え、それって普通の将棋盤と駒のセットと変わらないんじゃ…？ -- はい。そのとおりです。

↑

サンプル †

[編集]

cpu対戦機能なし！
モジュール部分

syogi_m.as

将棋モジュール

遊び方 †

[編集]

マウスだけで操作します。
将棋盤と駒があるだけなのでどこにでも置けます。
一人二役対戦です。(^ ^;
駒の動かし方は覚えてなくても使えます。
詰将棋ぐらいなら使えます。

↑

解説 †

[編集]

長いスクリプトだなぁ…。m(_ _)mすんません
半分以上が前処理で埋まってます。メインループだけならそれほど行数はないんですが…。

将棋盤
将棋盤の座標は次のようにして扱っています。
基本的には一般的な将棋の盤の見方にあわせています。

9	8	7	6	5	4	3	2	1
9,1	8,1	7,1	6,1	5,1	4,1	3,1	2,1	1,1	一
9,2	8,2	7,2	6,2	5,2	4,2	3,2	2,2	1,2	二
9,3	8,3	7,3	6,3	5,3	4,3	3,3	2,3	1,3	三
9,4	8,4	7,4	6,4	5,4	4,4	3,4	2,4	1,4	四
9,5	8,5	7,5	6,5	5,5	4,5	3,5	2,5	1,5	五
9,6	8,6	7,6	6,6	5,6	4,6	3,6	2,6	1,6	六
9,7	8,7	7,7	6,7	5,7	4,7	3,7	2,7	1,7	七
9,8	8,8	7,8	6,8	5,8	4,8	3,8	2,8	1,8	八
9,9	8,9	7,9	6,9	5,9	4,9	3,9	2,9	1,9	九

通常は(1,1)-(9,9)で扱っていますが、一部処理の都合で右上を(0,0)とした(0,0)-(8,8)で扱っている場合もあります。
配列変数の要素をそのまま座標に当てはめて処理している部分などを(0,0)-(8,8)としています。
モジュール内の内部処理では左上を基準点(0,0)として扱っていますが、通常はそれは意識せずに全て右上を基準点として扱います。

駒の動き駒の動きは基本的に

左右対称
敵の有無に関係なく置ける場所は同じである場合と、
敵が途中にいるとその先には移動できない場合がある。
これらの複数の組み合わせで移動方法を表現できる。

基本的にはチェスも同じらしい。
というわけで、次のように定義しました。

		CC
LD	L6	CA	R6	RD
L7	L3	C1	R3	R7
LE	L4	C0	R4	RE
L8	L5	C2	R5	R8
LF	L9	CB	R9	RF

記号の意味

1-A	指定駒にのみ移動可能
B-F	無限に移動可能、敵を飛び越すことは出来ない。
C0	元の位置
L	左
R	右
C	中心

チェスに拡張した場合に容易に対応できるようにちょっぴり多めです。

駒の種類と移動の組み合わせは次のとおり。

駒の種類番号	駒の種類	移動方法組み合わせ
0	玉	1,2,3,4,5
1	金	1,2,3,4
2	銀	1,3,5
3	桂	6
4	香	C
5	歩	1
6	飛	C,B,E
7	角	D,F
8	と	1,2,3,4
9	成香	1,2,3,4
10	成桂	1,2,3,4
11	成銀	1,2,3,4
12	馬	1,2,3,4,5,D,F
13	龍	1,2,3,4,5,C,B,E

駒がもつ情報。駒の数は全部で40個。
１つの駒ごとID番号が与えてあり、それぞれIDごとに下記の情報をもっています。
- 横座標(-1のときは盤上に載っていない)
- 縦座標
- 駒の種類
- 駒の持ち主(先手+1、後手-1)
  
  ん～あとはもうそれほど特殊なことはしてなかったような気がします。

↑

コメント †

[編集]

E3D関連のモデルデータならE3Dサンプルwikiの方を利用されてはどうでしょうか？E3DたんってHSP開発wikiじゃなくってE3Dサンプルwikiの方のマスコット(違?)ですし笑--kz3
なるほど。モデルデータはE3Dサンプルwikiに置いてそれを参照すれば良いですね。 -- ジオ
パイプに挑戦してみましたが…動いているのかいないのかよく分からなかったです。pipeexec命令は資料少ないし…。
さくらさんとこのパイプによるコンソールリダイレクトで実験してみました。
- 「bonanza csa_shogi」でバージョン情報取得成功！
- 「bonanza csa_shogi|display」でgame.csa出力成功！
- あとのは動いてるのかどうかすらさっぱり…もうだめだ_|￣|○
  参考資料：パイプ -- GENKI? 2007-03-22 (木) 22:01:00
さくらさんの所のＨＳＰサンプル蔵の「GUIからコンソールを操作する」というサンプルも試しましたがダメでした；；エラーが出ないのでBonanzaの呼び出しは出来ているみたいですけど、「手を指す」などのBonanzaのコマンドが実行できません。何も返って来なかったです。 -- ジオ 2007-03-22 (木) 23:15:37
bonanzaをHSPから操作するサンプルをアップしました。bonanzaが反応することを確認するだけのスクリプトです。
bonanza.hsp
つーさのくーかんからダウンロードしたWin32コンソール向きパイプ通信モジュールのpipe2.hspとbonanza.hspをbonanza.exe(Ver2.1)と同じフォルダに置いて、bonanza.hspを実行します。 -- ジオ 2008-03-16 (日) 00:10:10
bonanzaをHSPから操作するサンプルをバージョンアップしました。現在の盤面をbonanzaの命令で得られるようになりました。また、インプットボックスから指し手を入力するようになりました。
bonanza3.hsp
つーさのくーかんからダウンロードしたWin32コンソール向きパイプ通信モジュールのpipe2.hspとbonanza3.hspをbonanza.exe(Ver2.1)と同じフォルダに置いて、bonanza3.hspを実行します。 -- ジオ 2008-11-13 (木) 18:19:29
画像で描画するようにしました。
bonanza4.lzh
bonanza4.lzhに入っている画像は、はむの頭脳 [奇襲戦法と将棋素材のHP]で配布されている画像を加工した画像です。 -- ジオ 2008-11-15 (土) 07:07:49
AquesTalk - テキスト音声合成ミドルウェア
 それをHSPで利用するためのLet's HSP!で配布されているサンプルコード

ご'て、ごーな'な/かく。せんて'、いちさ'ん/けい'/な'る。これよ'り、/い'って/<NUMK VAL=10 COUNTER=びょー>'/み'まんでおねがいします。た'だし、/<NUMK VAL=1 COUNTER=ふん>'たんいで/ごうけー/<NUMK VAL=10 COUNTER=か'い>の/こうりょ/じ'かんがあります。、じゅ'う/びょーー。、にじゅ'う/びょーー。い'ち、に'ー、さ'ん、し'ー、ご'ー、ろ'く、し'ち、は'ち、きゅ'ー、

　 -- ジオ 2008-11-15 (土) 12:14:59

↑

E3Dたんと将棋☆ †

[編集]

E3Dたんと将棋したくなったので作りました。3D描画だけしかプログラムしてません。気が向いたら将棋機能もこのページを参考にして作りたいと思います。
現在はソースを整理してないので公開はしていません。気が向いたら整理して公開するかも知れません。
E3Dたんの手や腕や肩を動かして駒を指す動きを試してみたけどイケてませんでした。 -- ジオ

↑

思考部分 †

[編集]

良いのを見付けました！Bonanzaという思考部分専用のフリーウェアです。パイプで連絡するのですが、文字列型の変数をパイプ入力する方法が分からなかったのであきらめました＾＾；それに他にしたいことがあるので。
ウェブサイトを見ると分かりますが、将棋倶楽部24でレートは約2400だそうです。実際強かったです。
私たちは、私がE3Dを使っているように、思考部分以外をプログラムすれば良いということです。
あと、気が向いたらフリー素材で作った3D描画用の駒なども修正してここで公開したいとも思います。 -- ジオ

Bonanzaが渡辺竜王と指してくしくも負けてしまったそうです。でも素晴らしい使用実績が残りましたね。開発者の名誉だと思います。
そうですね。調子が良かった佐藤さんの竜王奪取を退けた渡辺さんと良い勝負だったみたいですね。Bonanzaがここまで出来るとは思いませんでした。１秒間で４００万局面読めるコンピュータで対局したそうですが、逆に人の素晴らしさも感じました。どうなっているんだろうってｗ -- ジオ

添付ファイル:

syougi02.hsp 52件 [詳細]

mod_syougi.hsp 55件 [詳細]

bonanza4.lzh 440件 [詳細]

bonanza3.hsp 497件 [詳細]

bonanza2.hsp 268件 [詳細]

bonanza.hsp 544件 [詳細]

syogi_m.as 1339件 [詳細]

syogi02.as 1140件 [詳細]

syogi01.as 405件 [詳細]

shogi3.png 545件 [詳細]

shogi2.png 547件 [詳細]

9	8	7	6	5	4	3	2	1
9,1	8,1	7,1	6,1	5,1	4,1	3,1	2,1	1,1	一
9,2	8,2	7,2	6,2	5,2	4,2	3,2	2,2	1,2	二
9,3	8,3	7,3	6,3	5,3	4,3	3,3	2,3	1,3	三
9,4	8,4	7,4	6,4	5,4	4,4	3,4	2,4	1,4	四
9,5	8,5	7,5	6,5	5,5	4,5	3,5	2,5	1,5	五
9,6	8,6	7,6	6,6	5,6	4,6	3,6	2,6	1,6	六
9,7	8,7	7,7	6,7	5,7	4,7	3,7	2,7	1,7	七
9,8	8,8	7,8	6,8	5,8	4,8	3,8	2,8	1,8	八
9,9	8,9	7,9	6,9	5,9	4,9	3,9	2,9	1,9	九

9	8	7	6	5	4	3	2	1
9,1	8,1	7,1	6,1	5,1	4,1	3,1	2,1	1,1	一
9,2	8,2	7,2	6,2	5,2	4,2	3,2	2,2	1,2	二
9,3	8,3	7,3	6,3	5,3	4,3	3,3	2,3	1,3	三
9,4	8,4	7,4	6,4	5,4	4,4	3,4	2,4	1,4	四
9,5	8,5	7,5	6,5	5,5	4,5	3,5	2,5	1,5	五
9,6	8,6	7,6	6,6	5,6	4,6	3,6	2,6	1,6	六
9,7	8,7	7,7	6,7	5,7	4,7	3,7	2,7	1,7	七
9,8	8,8	7,8	6,8	5,8	4,8	3,8	2,8	1,8	八
9,9	8,9	7,9	6,9	5,9	4,9	3,9	2,9	1,9	九

将棋

OFFICIAL/関連

TUTORIAL

TOPICS

ETC

EDIT

REFERENCE

LOG

お知らせ

HSP Web-Ring

最新の40件

なんとなく将棋を作ってみました for HSP3 †

サンプル †

mod_syougi.hsp

syougi02.hsp

遊び方 †

解説 †

なんとなく将棋を作ってみました for HSP2 †

サンプル †

syogi_m.as

syogi02.as

遊び方 †

解説 †

コメント †

E3Dたんと将棋☆ †

思考部分 †

9	8	7	6	5	4	3	2	1
9,1	8,1	7,1	6,1	5,1	4,1	3,1	2,1	1,1	一
9,2	8,2	7,2	6,2	5,2	4,2	3,2	2,2	1,2	二
9,3	8,3	7,3	6,3	5,3	4,3	3,3	2,3	1,3	三
9,4	8,4	7,4	6,4	5,4	4,4	3,4	2,4	1,4	四
9,5	8,5	7,5	6,5	5,5	4,5	3,5	2,5	1,5	五
9,6	8,6	7,6	6,6	5,6	4,6	3,6	2,6	1,6	六
9,7	8,7	7,7	6,7	5,7	4,7	3,7	2,7	1,7	七
9,8	8,8	7,8	6,8	5,8	4,8	3,8	2,8	1,8	八
9,9	8,9	7,9	6,9	5,9	4,9	3,9	2,9	1,9	九