小ワザ/ジョイスティック

ジョイスティック †

[編集]

　ゲームに欠かせないゲームパッド（ジョイスティック）入力を手軽に便利に使用するモジュールを作ってみます。

　HSP3にはヘルプブラウザには載っていないモジュールいくつかパッケージに含まれており、非常に便利そうな命令が豊富に隠れているようです。（プログラミング・マニュアル１のプログラミングガイド、HSP3支援モジュールの項目を参照。）
さて、この中にmod_joystick.as（MIAさん作成）というゲームパッドを使用可能にするモジュールが含まれているのですがそのままではちょこっとだけ使いにくいので、今回はこれを拡張したものを作成してみました。

↑

モジュール（stick互換） †

[編集]

このモジュールでは次の特徴があります。

stick命令と同じ感覚で使用することが出来ます。　→　stick命令については「小ワザ/stick命令の使い方」を参照してください。
返り値はstick命令で得られるものに追加する形なので、キーボード入力とゲームパッドのボタン入力は重なりません。ただし方向キーは重なります。
キー配置の変更が出来ます。
ジョイスティックID = コントローラID -1

そのまま実行すれば実行サンプルを見ることが出来ます。ゲームパッドを接続して実行してみてください（実行中に接続してもOKです）。

ジョイスティック情報取得モジュール

joy003.hsp

;
;	ジョイスティック入力モジュール(HSP3)
;
;命令・関数の一覧
;	＜通常使わない命令＞
;	JStickIni	：モジュールの初期化。この命令は通常プログラム中で使用する必要はありません。
;	joyGetPosEx	：ジョイスティックの位置とボタンの状態を取得する命令
;
;	＜通常使用する命令・関数＞
;	JStickGetID()：使用可能なジョイスティックIDを検出する関数
;	JStick		：キー入力情報取得命令
;	JStickCfg	：取得されるキーコードの変更
;
 
 
#module
#define BORDER_LOW  0x3FFF 
#define BORDER_HIGH 0xBFFF
 
#uselib "winmm.dll"
 
#func _joyGetPosEx "joyGetPosEx" int, var
#func joyGetNumDevs "joyGetNumDevs"
 
 
;モジュールの初期化
;JStickIni
;	プログラム中で宣言する必要はありません。
#deffunc JStickIni
    dim getdata, 13
    joyGetNumDevs    ;ジョイスティックドライバにサポートされるジョイスティック数を取得。
    JOYNUMDEV = stat
 
    ;キーコード変換リスト
    dim jchng, 15
    i = 1
    repeat 4
        jchng(cnt) = i
        i *= 2
    loop
    i = 0x800
    repeat 12
        jchng(cnt+4) = i
        i *= 2
    loop
    return
 
 
 
;ジョイスティックの位置とボタンの状態を取得する命令
;joyGetPosEx int p1, var data
;	p1：パッドID
;	data.0 = 常に 52  が入ります
;	data.1 = 常に 255 が入ります
;	data.2 = 第 1 軸の状態（普通のジョイスティックの X 軸）
;	data.3 = 第 2 軸の状態（普通のジョイスティックの Y 軸）
;	data.4 = 第 3 軸の状態（スロットル等）
;	data.5 = 第 4 軸の状態
;	data.6 = 第 5 軸の状態
;	data.7 = 第 6 軸の状態
;	data.8 = ボタンの状態（最大32ボタン）
;	data.9 = 同時に押されているボタンの数
;	data.10 = POV スイッチの状態
;	data.11 = 予備情報1
;	data.12 = 予備情報2
;
;	stat = 0 であれば入力は正常です。
;
;	dataはあらかじめdim data,13として配列を確保しておいてください。
#deffunc joyGetPosEx int p1, array data
    data = 52,255
    _joyGetPosEx p1, data
    return stat
 
 
;使用可能なジョイスティックIDを検出する関数
;	JStickGetID()
;		返り値：使用可能なジョイスティックのIDで
;		数字がもっとも小さいものを捜します。
;		パッドが見つからないときは-1を返します。
#defcfunc JStickGetID
    repeat JOYNUMDEV
        i = cnt
        joyGetPosEx i, data
        if stat=0 : break
    loop
    if stat : return -1 : else : return i
 
 
 
 
;キー入力情報取得命令
;JStick key, antrg, jid
;	key：キー入力情報を読み込むための変数（キーコードが返る）
;	antrg：非トリガータイプキー指定
;	jid：ジョイスティックID
;
;キーコード10進(16進) キーボード操作 ジョイパッド操作
;----------------------------------------------------------------
;      1 (0x1)        カーソル←     左レバー
;      2 (0x2)        カーソル↑     上レバー
;      4 (0x3)        カーソル→     右レバー
;      8 (0x4)        カーソル↓     下レバー
;     16 (0x10)       スペースキー   --
;     32 (0x20)       Enterキー      --
;     64 (0x40)       Ctrlキー       --
;    128 (0x80)       Escキー        --
;    256 (0x100)      左クリック     --
;    512 (0x200)      右クリック     --
;   1024 (0x400)      Tabキー        --
;   2048 (0x800)      --             ボタン１ (△)
;   4096 (0x1000)     --             ボタン２ (○)
;   8192 (0x2000)     --             ボタン３ (×)
;  16384 (0x4000)     --             ボタン４ (□)
;  32768 (0x8000)     --             ボタン５ (L2)
;  65536 (0x10000)    --             ボタン６ (R2)
; 131072 (0x20000)    --             ボタン７ (L1)
; 262144 (0x40000)    --             ボタン８ (R1)
; 524288 (0x80000)    --             ボタン９ (SELECT)
;1048576 (0x100000)   --             ボタン10 (START)
;2097152 (0x200000)   --             ボタン11 (ANALOG-L)
;4194304 (0x400000)   --             ボタン12 (ANALOG-R)
;
#deffunc JStick var key, int antrg, int jid
    key=0
    joyGetPosEx jid, getdata
    if stat : return
    key += getdata.8<<11
    ;方向キーのキーコードへの変換
    ;	アナログ入力でも方向キーとして扱える
    if getdata.2 < BORDER_LOW : key |= 1
    if getdata.3 < BORDER_LOW : key |= 2
    if getdata.2 > BORDER_HIGH : key |= 4
    if getdata.3 > BORDER_HIGH : key |= 8
    ;	POV（ハット）キーも方向キーとして扱う
    if (getdata.10 <= 31500)&(getdata.10 >= 22500) : key |= 1
    if (getdata.10 = 4500)|(getdata.10 = 0)|(getdata.10 = 31500) : key |= 2
    if (getdata.10 <= 13500)&(getdata.10 >= 4500) : key |= 4
    if (getdata.10 <= 22500)&(getdata.10 >= 13500) : key |= 8
 
    ttkey = ttkey0
    ttkey0 = key & antrg ^ key    ;非トリガータイプキーをオフにする。
    key = key & ttkey ^ key    ;トリガーキーをオフにする。
 
    ;キーコード変換
    i = 1 : rkey = 0
    repeat 4
        if key&i : rkey = rkey|jchng(cnt)
        i *= 2
    loop
    i = 0x800
    repeat 12, 4
        if key&i : rkey = rkey|jchng(cnt)
        i *= 2
    loop
    key = rkey
 
    ;stickキーの入力と合わせる。
    stick keyk, antrg
    key = key | keyk
 
    ;相反する方向の同時押しがあったらキーを無効にする。
    if (key&5) = 5 : key^=5
    if (key&10)=10 : key^=10
 
    return
 
 
 
;取得されるキーコードの変更
;JStickCfg kyid, key
;	kyid：変更したいボタンをIDで指定
;	key：返されるキーコードを任意に設定
;
;	kyid	ボタン	key
;--------------------------------------------
;	0		左レバー	1	(0x1)
;	1		上レバー	2	(0x2)
;	2		右レバー	4	(0x3)
;	3		下レバー	8	(0x4)
;	4		ボタン１	2048	(0x800)
;	5		ボタン２	4096	(0x1000)
;	6		ボタン３	8192	(0x2000)
;	7		ボタン４	16384	(0x4000)
;	8		ボタン５	32768	(0x8000)
;	9		ボタン６	65536	(0x10000)
;	10		ボタン７	131072	(0x20000)
;	11		ボタン８	262144	(0x40000)
;	12		ボタン９	524288	(0x80000)
;	13		ボタン１０	1048576	(0x100000)
;	14		ボタン１１	2097152	(0x200000)
;	15		ボタン１２	4194304	(0x400000)
;
;【例】左レバーと右レバーを入れ替える
;	JoyCfg 0, 4
;	JoyCfg 2, 1
#deffunc JStickCfg int kyid, int key
    jchng(kyid) = key
    return
 
 
 
 
#global
JStickIni
;----------------------------------------------------------------
;モジュールここまで
;----------------------------------------------------------------
 
 
 
;################################################################
;
;	モジュール実行サンプル
;
;################################################################
 
    ;	キーの入れ替え例
    ;左レバーと右レバーの入力を入れ替えてみる。
    JStickCfg 0, 4
    JStickCfg 2, 1
    fk = 1
 
    repeat
        redraw 1 : await 32 : redraw 0 : color 255,255,255 : boxf : color
        pos 0,0
 
        jid = JStickGetID()        ;接続されているジョイスティックのidを捜す。
        if stat=-1 {
            mes "err:ジョイスティックが接続されていません。"
        } else {
            mes "ジョイスティックID：" + jid
            JStick key, 0x800000-1, jid        ;キー入力情報取得（全キーを非トリガータイプキーに指定）
            mes "取得したキーコード：" + key
        }
 
 
        gosub *scset    ;画面のリセット
 
        ;ボタンを押したときの効果
        if key& 0x1 :    pos wxx+  0,wyy+ 80 : mes "<<"
        if key& 0x2 :    pos wxx+ 20,wyy+ 60 : mes "▲"
        if key& 0x4 :    pos wxx+ 40,wyy+ 80 : mes ">>"
        if key& 0x8 :    pos wxx+ 20,wyy+100 : mes "▼"
        if key& 0x800 :    pos wxx+150,wyy+ 60 : mes "●"
        if key& 0x1000 :    pos wxx+170,wyy+ 80 : mes "●"
        if key& 0x2000 :    pos wxx+150,wyy+100 : mes "●"
        if key& 0x4000 :    pos wxx+130,wyy+ 80 : mes "●"
        if key& 0x8000 :    pos wxx+ 20,wyy+  0 : mes "●"
        if key& 0x10000 :    pos wxx+150,wyy+  0 : mes "●"
        if key& 0x20000 :    pos wxx+ 20,wyy+ 20 : mes "●"
        if key& 0x40000 :    pos wxx+150,wyy+ 20 : mes "●"
        if key& 0x80000 :    pos wxx+ 70,wyy+ 90 : mes "●"
        if key& 0x100000 :    pos wxx+100,wyy+ 90 : mes "●"
        if key& 0x200000 :    pos wxx+ 60,wyy+120 : mes "●"
        if key& 0x400000 :    pos wxx+110,wyy+120 : mes "●"
 
        ;操作感の確認
        if key& 0x1 : ppx-=3
        if key& 0x2 : ppy-=3
        if key& 0x4 : ppx+=3
        if key& 0x8 : ppy+=3
        if key& 0x800 : JStickCfg 0, 1 : JStickCfg 2, 4 : fk = 0    ;左レバーと右レバーの入力を正常にする。
        if key& 0x1000 : JStickCfg 0, 4 : JStickCfg 2, 1 : fk = 1    ;左レバーと右レバーの入力を入れ替えてみる。
        pos ppx, ppy : mes "＋"
        pos 0, 40 : if fk = 1 : mes "左右キー入れ替え（ボタン１で変更）" : else : mes "左右キー正常（ボタン２で変更）"
 
    loop
;---------------------------------------------------------------------------------
 
 
;画面の初期化
;ボタンの画像を押していない状態にします。
*scset
    wxx=150 : wyy=150
    pos wxx+  0,wyy+ 80 : mes "<"    ;←
    pos wxx+ 20,wyy+ 60 : mes "△"    ;↑
    pos wxx+ 40,wyy+ 80 : mes " >"    ;→
    pos wxx+ 20,wyy+100 : mes "▽"    ;↓
    pos wxx+150,wyy+ 60 : mes "①"    ;1
    pos wxx+170,wyy+ 80 : mes "②"    ;2
    pos wxx+150,wyy+100 : mes "③"    ;3
    pos wxx+130,wyy+ 80 : mes "④"    ;4
    pos wxx+ 20,wyy+  0 : mes "⑤"    ;l2
    pos wxx+150,wyy+  0 : mes "⑥"    ;r2
    pos wxx+ 20,wyy+ 20 : mes "⑦"    ;l1
    pos wxx+150,wyy+ 20 : mes "⑧"    ;r1
    pos wxx+ 70,wyy+ 90 : mes "⑨"    ;SELECT
    pos wxx+100,wyy+ 90 : mes "⑩"    ;START
    pos wxx+ 60,wyy+120 : mes "⑪"    ;l3
    pos wxx+110,wyy+120 : mes "⑫"    ;r3
    return

モジュールの使い方はスクリプト内のコメントを参照してください。

改訂版モジュール
このモジュールから、バグを取り除き、機能の追加とヘルプを追加したパッケージを作成しました。
モジュールの中のことはともかく、ジョイスティックに対応したい方。
サンプルを参考に作ってみたけど、バグに悩ませられている方。
は、こちらをご利用ください。
PAD設定さん：http://homepage3.nifty.com/ghpk/dl/dl11.htm

↑

ボタン配置 †

[編集]

　同じような形、同じようなボタン配置のゲームパッドでもメーカーによってはボタン１～の配置順番が異なっていることがあるようです。
また、PS/PS2コントローラをパソコンに接続するコンバータもメーカーによってボタン配置がことなってしまうようです。
またさらに、ゲームパッドによってはボタン配置場所そのものがことなるものが多数出回っています。（PSやサターンなどのようなタイプ）

　このような理由からPCでのゲーム開発の場合、デフォルトのキー配置以外にユーザーがキー配置を変更する余地を残しておくことが必要でしょう。
もちろんゲームパッドを持っていないキーボードユーザーへの配慮も必要です。

↑

ジョイスティックID †

[編集]

ジョイスティックIDとは…

APIのjoyGetPosEx?、joyGetPos?関数で指定するパラメータuJoyIDのこと。（JOYSTICKID1, JOYSTICKID2で指定すると書かれています。）
0～(ドライバにサポートされるジョイスティック数-1)の整数値。
PCに接続されているゲームパッドにはそれぞれ重複しない0以上のジョイスティックID（番号）がつけられている。
ジョイスティックIDの割り振りはOSによって動作が異なる。
- Win98,ME,2kではコントローラID（＝ジョイスティックID+1）として確認、変更が可能である。
- WinXP以降のOSでは確認することは出来ないかわりに、優先的にジョイスティックIDを小さい番号にする設定は可能。
プログラムではこのID番号で使用するジョイスティックを指定することになる。（APIのjoyGetPosEx?、joyGetPos?関数）

と、このようなものです。
しかし、このジョイスティックIDという呼び名は一般的ではないらしく検索しても出てきません。どなたか一般的な呼び名をご存知でしたら教えてください。

さてジョイスティックIDは普段ユーザーは気にしないでいい値です。そのため、今自分が使っているジョイスティックのIDが何番か？ということも知らなくて当然です。
またジョイスティックを１つしか使っていなくてもIDが0とは限りません。そのためプログラミングする際には何らかの配慮が必要になってきます。
例えば、使えるジョイスティックIDを自動検出して指定するか、使えるジョイスティックIDからユーザーに選択させる方法が考えられます。

蛇足ですが…
joyGetPosEx?、joyGetPos?関数のマニュアルではJOYSTICKID1, JOYSTICKID2としか書かれていません。が、実際には上記のような整数値なので0以上の値を指定して使います。
ちなみに変数の中身はJOYSTICKID1=0, JOYSTICKID2=1となっている。マニュアルを鵜呑みにするとID=1まで、ジョイスティック２個しか使えないことに…なんでこんな書き方なんでしょうね。

↑

XPより前のジョイスティックID †

[編集]

ジョイスティックIDはドライバをインストールされた（認識された）ジョイスティックごとに割り振られ、USBを抜き差ししてもそのジョイスティックのジョイスティックIDは変更されません。
コントロールパネルからIDの確認と変更が可能です。

ジョイスティックを１つしか持たないユーザは通常ID=0がそのジョイスティックのIDになります。
しかし、ゲームパッドを買い換えた（買い足した）ユーザーは、新規に接続したジョイスティックにID=1が割り振られることになります。さらに新規ジョイスティックを接続するとID番号は増えていきます。
このためジョイスティックIDを0で固定してゲームを作ると、ジョイスティックが使えないユーザーが出てくることになります。
このようにせっかくゲームパッドに対応したゲームを作成しても、ゲームパッドを使えないユーザーが出てきてしまうことがあります。（設定変更すればいいということに気付かないユーザーは少なくないでしょう。）

↑

XP以降のジョイスティックID †

[編集]

　詳細未確認のためこの解説は推測です。XPでのジョイスティックIDの挙動の詳細はこれを書いている私にはよくわかりません。（XPユーザではないため）
　ジョイスティックが接続されると自動的に小さい番号のIDが割り振られるようです。
接続したジョイスティックに対するジョイスティックIDは固定ではなく、変動するようです。（IDが飛び飛びになることもなく、番号はつめて配布されるらしいです。）

優先デバイスの設定がされていなければ、接続されたジョイスティックが1個だけなら、ジョイスティックIDは常に0となるようです。

↑

ジョイスティックIDを調べる †

[編集]

↑

XPより古いOSで調べる †

[編集]

XPより古いOSではジョイスティックIDは固定（USBを抜き差ししてもジョイスティックID番号が変わらない）となっています。
各ジョイスティックに割り振られたジョイスティックIDは、コントローラID（＝ジョイスティックID+1）として確認・変更が可能です。
確認・変更するには、ゲームパッドを接続した状態で、[スタート] ボタンから、「設定」→「コントロールパネル」→「ゲームオプション」→「詳細」タブまたは「コントローラ ID」タブとすることで確認できます。
またこのダイアログでIDの割り振りを変更できます。ただし

コントローラID = ジョイスティックID + 1
ジョイスティックID = コントローラID - 1

コントローラIDは1～
ジョイスティックIDは0～
であることに注意してください。

↑

XP以降のOSで調べる †

[編集]

XP以降のOSでは「ゲームコントローラ」でのコントローラIDの確認はできません。その代わり、ジョイスティックが接続されると使っていない一番小さいID番号を割り振るようになっているようです。
優先デバイスの設定がされていなければ接続されたジョイスティックが1個だけなら、ジョイスティックIDは常に0（コントローラIDは常に1）ということになります。

↑

コントローラ変換コネクタ †

[編集]

ゲーム機用のジョイスティックをパソコンへ接続するUSB変換コネクタというものがあります。使い慣れたゲーム機用ジョイスティックをパソコンで使えるという便利なものです。しかし、使用には多少の注意が必要になります。

同じジョイスティックを使っていても変換コネクタによっては、ボタン番号（配置）が変わったりすることがある。
2個以上のジョイスティックを接続できるもののなかには、実際にはジョイスティックを1つしか接続していなくても2つ接続していると認識されてしまうことがある。
変換コネクタ自体をジョイスティックと認識しているようです。つまり変換コネクタに何もつながなくてもジョイスティックを検出する。

↑

ジョイスティックの性能を取得 †

[編集]

APIのjoyGetDevCaps?関数を使用するとジョイスティックの性能情報を取得できます。
構造体からの情報取得方法を間違っていたことが判明したので修正しました。
しかし…szRegKey?とszOEMVxDの意味がさっぱりわかりません。orz

ジョイスティック性能取得テスト

;for HSP3
;joyGetDevCapsを使ってジョイスティックを照会してその性能を調べるサンプルです。
 
#uselib "winmm.dll"
#func _joyGetDevCaps "joyGetDevCapsA" int, int, int
 
    dim joycaps, 404/4    ;JOYCAPS構造体
    uJoyID = 0        ;ジョイスティックのIDです。自分の環境に合わせて変えてください。（0～）
    _joyGetDevCaps uJoyID, varptr(joycaps), length(joycaps)*4
    if stat : mes "ジョイスティックを認識できませんでした。" : stop    ;正常に情報が取得できると0を返します。
 
    ;JOYCAPS構造体から情報を引き出す。
    szPname = "" : szRegKey = "" : szOEMVxD = ""
    inx = 0
    wMid        = wpeek(joycaps,inx) : inx+=2
    wPid        = wpeek(joycaps,inx) : inx+=2
    getstr padname, joycaps, inx,, 32
    szPname     = padname : inx+=32
    wXmin       = lpeek(joycaps,inx) : inx+=4
    wXmax       = lpeek(joycaps,inx) : inx+=4
    wYmin       = lpeek(joycaps,inx) : inx+=4
    wYmax       = lpeek(joycaps,inx) : inx+=4
    wZmin       = lpeek(joycaps,inx) : inx+=4
    wZmax       = lpeek(joycaps,inx) : inx+=4
    wNumButtons = lpeek(joycaps,inx) : inx+=4
    wPeriodMin  = lpeek(joycaps,inx) : inx+=4
    wPeriodMax  = lpeek(joycaps,inx) : inx+=4
    wRmin       = lpeek(joycaps,inx) : inx+=4
    wRmax       = lpeek(joycaps,inx) : inx+=4
    wUmin       = lpeek(joycaps,inx) : inx+=4
    wUmax       = lpeek(joycaps,inx) : inx+=4
    wVmin       = lpeek(joycaps,inx) : inx+=4
    wVmax       = lpeek(joycaps,inx) : inx+=4
    wCaps       = lpeek(joycaps,inx) : inx+=4
    wMaxAxes    = lpeek(joycaps,inx) : inx+=4
    wNumAxes    = lpeek(joycaps,inx) : inx+=4
    wMaxButtons = lpeek(joycaps,inx) : inx+=4
    getstr padname, joycaps, 32
    szRegKey    = padname : inx+=32
    getstr padname, joycaps, 260
    szOEMVxD    = padname : inx+=260
 
    name = "wMid", "wPid", "szPname", "wXmin", "wXmax", "wYmin", "wYmax", "wZmin", "wZmax", "wNumButtons", "wPeriodMin", "wPeriodMax", "wRmin", "wRmax", "wUmin", "wUmax", "wVmin", "wVmax", "wCaps", "wMaxAxes", "wNumAxes", "wMaxButtons", "szRegKey", "szOEMVxD"
    info(0)  = "メーカー識別子"
    info(1)  = "製品識別子"
    info(2)  = "ジョイスティック製品名"
    info(3)  = "X-座標"
    info(4)  = "X-座標"
    info(5)  = "Y-座標"
    info(6)  = "Y-座標"
    info(7)  = "Z-座標"
    info(8)  = "Z-座標"
    info(9)  = "ボタンの数"
    info(10) = "ポーリング間隔の最小値"
    info(11) = "ポーリング間隔の最大値"
    info(12) = "r座標の最小値"
    info(13) = "r座標の最大値"
    info(14) = "u座標の最小値"
    info(15) = "u座標の最大値"
    info(16) = "v座標の最小値"
    info(17) = "v座標の最大値"
    info(18) = "能力フラグ"
    info(19) = "座標軸の最大数"
    info(20) = "座標軸の数"
    info(21) = "ボタンの最大数"
    info(22) = "レジストリキー？"
    info(23) = "ドライバOEM？"
    pos 0,0 : repeat 24 : mes name(cnt) : loop
    pos 300,0 : repeat 24 : mes info(cnt) : loop
    pos 100,0
    mes wMid
    mes wPid
    mes szPname
    mes wXmin
    mes wXmax
    mes wYmin
    mes wYmax
    mes wZmin
    mes wZmax
    mes wNumButtons
    mes wPeriodMin
    mes wPeriodMax
    mes wRmin
    mes wRmax
    mes wUmin
    mes wUmax
    mes wVmin
    mes wVmax
    mes wCaps
    mes wMaxAxes
    mes wNumAxes
    mes wMaxButtons
    mes szRegKey
    mes szOEMVxD

↑

ジョイスティックの接続状態を取得する †

[編集]

XPってジョイパッドIDがどんなふうに割り当てられているのか分からなくて困りますね。これを使えば少しは解決するでしょうか？
ジョイスティックの接続状態を取得するサンプルです。接続されている全てのジョイパッドのIDと名前を取得して表示します。
PCにジョイスティックを接続した状態で実行してみてください。実行中に接続してもダメです。

ジョイスティックの接続状態を取得するサンプル

;for HSP3
;	ジョイパッドの接続状態を取得するサンプルです。
;	PCにジョイパッドを接続した状態で実行してみてください。
;	接続されている全てのジョイパッドのIDと名前を取得して表示します。
 
 
;#####################################################################
#module
#define BORDER_LOW  0x3FFF 
#define BORDER_HIGH 0xBFFF
 
#define global JOYERR_BASE            160
#define global MMSYSERR_NODRIVER     (MMSYSERR_BASE + 6)  /* ジョイスティックドライバが存在しません。 */
#define global MMSYSERR_INVALPARAM   (MMSYSERR_BASE + 11) /* 無効なパラメータが渡されました。 */
#define global MMSYSERR_BADDEVICEID  (MMSYSERR_BASE + 2)  /* 指定されたジョイスティック識別子は無効です。 */
#define global JOYERR_UNPLUGGED      (JOYERR_BASE+7)      /* 指定されたジョイスティックはシステムに接続されていません。 */
#define global JOYERR_NOERROR        0    ;関数が成功
 
#define global JOYERR_PARMS 165      /* 指定されたジョイスティックデバイスの識別子 uJoyID は無効です。 */
 
#uselib "winmm.dll"
 
#func _joyGetPosEx "joyGetPosEx" int, var
#func joyGetNumDevs "joyGetNumDevs"
#func _joyGetDevCaps "joyGetDevCapsA" int, int, int
;joyGetDevCapsA uJoyID, pjc, cbjc
;	uJoyID	:照会するジョイスティック
;	pjc		:JOYCAPS 構造体のアドレス
;	cbjc	:JOYCAPS 構造体のサイズをバイト単位で指定。
 
;-----------------------------------------------
;モジュールの初期化
;JStickIni
;	プログラム中で宣言する必要はありません。
#deffunc JStickIni
    dim joycaps, 404/4    ;JOYCAPS構造体(404byte)
    joyGetNumDevs    ;ジョイスティックドライバにサポートされるジョイスティック数を取得。
    JOYNUMDEV = stat    ;ドライバが存在しない場合は、0 が返ります。
    return JOYNUMDEV
 
;ジョイスティックの位置とボタンの状態を取得する命令
;joyGetPosEx int p1, var data
;	p1：パッドID
;	data.0 = 常に 52  が入ります
;	data.1 = 常に 255 が入ります
;	data.2 = 第 1 軸の状態（普通のジョイスティックの X 軸）
;	data.3 = 第 2 軸の状態（普通のジョイスティックの Y 軸）
;	data.4 = 第 3 軸の状態（スロットル等）
;	data.5 = 第 4 軸の状態
;	data.6 = 第 5 軸の状態
;	data.7 = 第 6 軸の状態
;	data.8 = ボタンの状態（最大32ボタン）
;	data.9 = 同時に押されているボタンの数
;	data.10 = POV スイッチの状態
;	data.11 = 予備情報1
;	data.12 = 予備情報2
;
;	stat = 0 であれば入力は正常です。
;	返り値					説明
;	JOYERR_NOERROR			関数が成功。ジョイスティックは接続され正常に動作しています。
;	MMSYSERR_NODRIVER		ジョイスティックドライバが存在しません。
;	MMSYSERR_INVALPARAM		無効なパラメータが渡されました。
;	MMSYSERR_BADDEVICEID	指定されたジョイスティック識別子は無効です。
;	JOYERR_UNPLUGGED		指定されたジョイスティックはシステムに接続されていません。
;	JOYERR_PARMS			指定されたジョイスティックデバイスの識別子 uJoyID は無効です。
;
;	dataはあらかじめdim data,13として配列を確保しておいてください。
#deffunc joyGetPosEx int p1, array data
    data = 52,255    ;JOYINFOEX構造体:dwSize, dwFlags
    _joyGetPosEx p1, data
    return stat
 
 
;-----------------------------------------------
;使用可能なジョイスティックIDを検出する関数
;	JStickSearchID startnum, joyidlist, number
;		startnum	：検出を開始するID（0～）
;		joyidlist	：検出したIDの一覧を格納する配列変数。
;					　使用可能なジョイスティックのID（0～）をすべて検出します。
;		number		：検出する個数。省略(=0)のときは全て。
;		返り値：検出したIDの個数
#deffunc JStickSearchID int _startnum, array joyidlist, int _number
    startnum = limit(_startnum, 0, JOYNUMDEV)
    if _number<=0 : number = JOYNUMDEV : else : number = _number
    joyidmax = 0
    repeat JOYNUMDEV - startnum, startnum
        joyGetPosEx cnt, data
        if stat = JOYERR_NOERROR {
            joyidlist(joyidmax) = cnt
            joyidmax++
            if joyidmax>=number : break
        }
    loop
    return joyidmax
 
 
;-----------------------------------------------
;ジョイスティックの名称を取得します。
;	name = JStickGetDevCapsPname( _uJoyID )
;		_uJoyID	：(0～)ジョイパッドのid
;		返り値	：取得したジョイパッド名
#defcfunc JStickGetDevCapsPname int _uJoyID
    if ( _uJoyID < 0 )|( _uJoyID >= JOYNUMDEV ) : return -1    ;指定されたidは使用できません。
    _joyGetDevCaps _uJoyID, varptr(joycaps), length(joycaps)*4
    if stat : return ""        ;正常に情報が取得できなかった。
    name = ""
    getstr name, joycaps, 4
    return name
 
 
;-----------------------------------------------
;ジョイスティックの性能を取得します。
;	JStickGetDevCaps _uJoyID, jinfo
;		_uJoyID	：(0～)ジョイパッドのid
;		jinfo	：取得したジョイスティックの性能値。整数型の配列変数。要素の最大は19個。
;				必ず　dim jinfo, 19　として配列を確保しておいてください。
;			jinfo(0)  = wXmin;		/* X-座標 */
;			jinfo(1)  = wXmax;		/* X-座標 */
;			jinfo(2)  = wYmin;		/* Y-座標 */
;			jinfo(3)  = wYmax;		/* Y-座標 */
;			jinfo(4)  = wZmin;		/* Z-座標 */
;			jinfo(5)  = wZmax;		/* Z-座標 */
;			jinfo(6)  = wNumButtons;/* ボタンの数 */
;			jinfo(7)  = wPeriodMin;	/* ポーリング間隔の最小値 */
;			jinfo(8)  = wPeriodMax;	/* ポーリング間隔の最大値 */
;			jinfo(9)  = wRmin;		/* r座標の最小値 */
;			jinfo(10) = wRmax;		/* r座標の最大値 */
;			jinfo(11) = wUmin;		/* u座標の最小値 */
;			jinfo(12) = wUmax;		/* u座標の最大値 */
;			jinfo(13) = wVmin;		/* v座標の最小値 */
;			jinfo(14) = wVmax;		/* v座標の最大値 */
;			jinfo(15) = wCaps;		/* 能力フラグ */
;			jinfo(16) = wMaxAxes;	/* 座標軸の最大数 */
;			jinfo(17) = wNumAxes;	/* 座標軸の数 */
;			jinfo(18) = wMaxButtons;/* ボタンの最大数 */
#deffunc JStickGetDevCaps int _uJoyID, array jinfo
    if ( _uJoyID < 0 )|( _uJoyID >= JOYNUMDEV ) : return -1    ;指定されたidは使用できません。
    uJoyID = _uJoyID        ;0～
    _joyGetDevCaps uJoyID, varptr(joycaps), length(joycaps)*4
    if stat : return stat        ;正常に情報が取得できなかった。
 
    repeat 19
        jinfo(cnt) = lpeek(joycaps, cnt*4+36)
    loop
    return
 
 
 
#global
JStickIni
;OSのジョイパッド最大認識個数
maxjoystick = stat    ;この変数には値を代入しないようにしてください。
 
;モジュールここまで
;#####################################################################
 
;
;	実行サンプル
;
;		「#if 0」を「#if 1」にしてF5キーを押してください。
#if 1;0
 
    ;接続されたジョイスティックを探す
    pos 200,0
    mes "OSのジョイパッド最大認識個数：" + maxjoystick + "個"
    ;使用可能なジョイスティックを検出する
    JStickSearchID 0, joylist
    kosu = stat
    mes "有効なジョイパッドの個数：" + kosu + "個"
    mes "有効なジョイパッドIDとジョイパッド名は次のとおり。"
    repeat kosu
        mes "ID(" + joylist(cnt) + ")：" + JStickGetDevCapsPname(joylist(cnt))
    loop
 
    if kosu>0 {
        mes "\n以上が接続されている有効なジョイパッドIDと\nその名前の全てです。"
    } else {
        mes "\n使用できるゲームパッドがありません。"
    }
 
 
    ;指定したジョイスティックの性能を取得する。
    pos 0,0
    info = "wXmin" ,"wXmax" ,"wYmin" ,"wYmax" ,"wZmin" ,"wZmax" ,"wNumButtons" ,"wPeriodMin" ,"wPeriodMax" ,"wRmin" ,"wRmax" ,"wUmin" ,"wUmax" ,"wVmin" ,"wVmax" ,"wCaps" ,"wMaxAxes" ,"wNumAxes" ,"wMaxButtons"
    dim key, 19        ;性能情報を格納する配列変数
    cmb = "" : msb = ""
    repeat kosu
        cmb += "ID = "+joylist(cnt)+"\n"
    loop
    combox sct, 100, cmb
    gosub *seinou
    mesbox msb, 200,300 : msbid = stat
 
*main
    await 500
    if sct ! sctold : gosub *seinou : objprm msbid, msb
    sctold = sct
    goto *main
 
;性能を取得する
*seinou
    JStickGetDevCaps joylist(sct), key    ;性能取得
    msb = "接続されているジョイスティックの性能"
    repeat 19
        msb += info(cnt)+" : "+key(cnt)+"\n"
    loop
    return
 
#endif

↑

キーボードのキーロールオーバー †

[編集]

　ゲームを作っていて、キーの同時押しが認識されない！と気付いたことはありませんか？

　キーボードのキーを何個まで同時に押して認識できるかをあらわす言葉をキーロールオーバーといいます。
例えば３キーロールオーバーならキーを３つまで同時押ししても認識してくれます。
また、nキーロールオーバーならどのキーをどれだけ同時押ししても全ての押したキーを認識してくれます。
nキーロールオーバーは一部の高級キーボードだけが対応しており、一般ユーザーは３キー～擬似nキーロールオーバーのキーボードを使用しています。

　このようなキーボードの性能の制約によりほとんどの一般ユーザーのキーボードは同時押しを認識しません。
キーボード操作のゲームを作るときは、複数キーの同時押しが必要なルールにならないよう注意しましょう。

どうしても同時押しが必要なゲームを作りたいときは、キーボードではなく、標準で全キー同時押し可能であるジョイスティックを利用することをお勧めします。
ユーザーにnキーロールオーバー対応キーボードを買わせるよりはずっと安く済みます。

↑

コメント †

[編集]

ログ１

命令の仕様などはchokkoさんの「CK JOYFORCE DLL」を参考にしてます。ところでアナログキーとハットスイッチとカーソルキーが同じ方向キーとして同時入力できるんで４方向同時押しとか余裕で出来ちゃうわけですが、これって無茶な仕様でしょうか？ -- GENKI? 2006-11-22 (水) 00:47:20
アナログ入力の検出もできるのですが…最近はアナログ入力対応のゲームパッドも増えてきた印象ですが、実際のところどうなんでしょうね。普及率。 -- GENKI? 2006-11-22 (水) 01:16:04
> ４方向同時押し
仕様としては同時押しを認識できた方が良いと思いますが、モジュール側で相反する方向の同時押しは無効(上右下と入力があった場合は上下の入力を無効として右のみの入力とする)として値を返すモードも用意した方が使い勝手は良さそうに思います。 -- naznyark? 2006-11-22 (水) 01:49:12
なるほどー、無効化する手はよさそうですね。聞いてみてよかったです。早速追加してきました。 -- GENKI? 2006-11-22 (水) 22:45:17
さらに便利さをましたモジュールのセット。つ宣伝 -- GENKI? 2007-05-19 (土) 15:06:28
上にあるモジュールを試してみたのですが、何度試してもジョイパッドを認識してくれません。どうすればいいですか？環境は、WindowsXP.,HSP3 -- バサンバ? 2007-08-12 (日) 21:20:39
すいません ↑の続きです。HORI製の連射機能付きPS2用コントローラーで、SANWA SUPPLY製の変換ケーブルを通して接続しています。　コメント欄を汚してしまってすいません -- バサンバ? 2007-08-12 (日) 21:27:38
ごめんなさい。サンプル内で、JStickGetID()の返り値の処理の仕方を間違えてました。何で気付かなかったんだろう…。orz -- GENKI? 2007-08-13 (月) 13:54:59
修正したのでもう大丈夫なはずです。うちもHORI製パッドを変換機でつないでます。OSの方でちゃんとパッドと認識してくれれば問題ないはずです。 -- GENKI? 2007-08-13 (月) 13:59:20
せっかく修正して頂いたのにまだ動きません OSの方でもプログラムの方でもジョイパッドは認識できているのですが、ジョイパッドからの操作に全く反応してくれません、僕のジョイパッドが壊れてるんですかね -- バサンバ? 2007-08-18 (土) 11:13:50
念のためコントローラに異常がないか確認してみます。次のことをやってみてください。
(1)コントロールパネルからゲームオプションを開いてゲームコントローラの接続状態がOKになっているか確認してみてください。
(2)問題なければ、そのまま接続されているコントローラのプロパティを開いてコントローラの動作テストをしてみてください。
これで問題なければコントローラは正常に動作しています。 -- GENKI? 2007-08-18 (土) 22:49:57
コントローラに異常がなければスクリプトに問題があるはずですね。「ジョイスティックID」と「取得したキーコード」は表示されていますか？キーボードのカーソルキーやスペースキーを押したときにキーコードの値が変化していますか？何が原因なんだろう…。 -- GENKI? 2007-08-18 (土) 22:53:43
コントロールパネルからチェックしてみましたがコントローラーは正常に動作してるみたいです。「ジョイスティックID」と「取得したキーコード」もちゃんと表示されていて、キーボードからの操作には反応してくれるのですが・・・。 -- バサンバ? 2007-08-19 (日) 12:05:19
２つ以上ゲームパッドが接続されていませんか？このもサンプルはコントローラIDが一番小さいもの１つを認識する仕様になっています。ゲームオプションのコントローラIDタブを開いて、つながっているコントローラとIDを確認してみてください。 -- GENKI? 2007-08-19 (日) 16:18:00
ちなみにコントローラIDとジョイスティックIDの関係はコントローラID = ジョイスティックID + 1となっています。使いたいゲームパッドが認識されていますか？ -- GENKI? 2007-08-19 (日) 16:27:31
すいません（汗）↑の「ゲームオプションのコントローラIDタブ」って何ですか？コントロールパネルのゲームコントローラからはコントローラーＩＤらしき物が見つからなかったのですが・・・ -- バサンバ? 2007-08-24 (金) 00:50:02
ごめんなさい。XP以降はゲームオプションがなくなってゲームコントローラになっていたんですね。知りませんでした。このためXP以降ではIDの設定も確認もできなくなっています。（XPでゲームオプションを使う方法が、このページの一番下に記載されています。参考にどうぞ。）
XPでゲームパッドを複数つなぐときに、優先順位（ID）を変更できないのは仕様のようです。どうやらつないだ順番で自動的にIDが割り振られるらしいです。
とりあえず考えられる解決案を２通り考えてみました。（XP環境ないので試せていません。）
- ゲームパッドが複数つながっている場合は、一旦接続されているゲームパッドを全てPCから外してから、こんどは使いたいゲームパッド１つだけを接続してみてください。（ID1が割り振られるハズ…。）
- ゲームコントローラの詳細設定ボタンをクリックし、使いたいコントローラが [優先デバイス] の項目に表示されていることを確認してください。表示されていない場合はメニューから選択してください。 -- GENKI? 2007-08-24 (金) 20:19:12
XPって厄介な仕様なんですね。スクリプトでの対策もちょっと考えてみます。 -- GENKI? 2007-08-24 (金) 20:22:44
「ジョイスティックの接続状態を取得するサンプル」を載せました。これで接続されている全てのゲームパッドのIDと名前がわかるはず。2kではちゃんと動きました。XPでは…どうなんでしょう。（XP環境がない。）ちゃんと認識されてIDと名前出てますか？（XPでの動作が不安です。）使いたいゲームパッドのIDが一番小さい数値になっていますか？ -- GENKI? 2007-08-25 (土) 00:03:48
「動いた！」とか「ちっとも動かん！」など動作チェックと不具合報告は非常にありがたいです。バサンバさんに限らず情報お待ちしてます。 -- GENKI? 2007-08-25 (土) 00:29:48
GENKIさん動きました！！僕の使ってる変換機が二人用だったのが原因みたいです。今までずっと１Ｐの方に繋いでいたので、試しに２Ｐの方に繋いでみた所動いてしまいました。（サンプルの画面とキーの対応はまちまちですが。）その後にコントロールパネルで「優先デバイスの変更」とやらを行ってみると１Ｐの方でも正しく動作するようになりました。でも無知なので詳しい理由などが分かりません。 -- バサンバ? 2007-08-25 (土) 17:25:49
XPで正常に動作することを確認しました。ジョイパッドは1つしか持っていないので、複数つなげた時の動作は分かりませんが……。USB接続、Windows標準のドライバ（？）を使用するタイプです。 -- eller 2007-08-25 (土) 18:37:10
Vistaでも動作することを確認しました。ジョイパッドの型名はELECOMのJC-U812WHです。 -- eller 2007-08-25 (土) 20:09:12
バサンバさんellerさん動作報告ありがとうございます！xp/vistaで動いたということで安心しました。２人用変換機使うとまた挙動が違ったりするんですね。しかし、こういうトラブルをなくすようにゲームパッドへ対応させるのって結構めんどくさそうですね。モジュール作成のしがいがあります。とりあえずいただいた情報はあとで整理しておこう…。 -- GENKI? 2007-08-26 (日) 06:28:02
サンプルの画面とキーの対応はまちまちですが。＜ゲームパッドのボタン配置は一見同じでもメーカーなどによって場所が入れ替わったりしていることはよくあります。なのでボタン配置を入れ替える命令も用意してます。ちなみにここのモジュールでのボタン配置の対応は、CK JOYFORCE DLLの仕様をまねています。 -- GENKI? 2007-08-26 (日) 06:29:56
それにしても…バサンバさんところの動いてよかったです。ほっとしました。 -- GENKI? 2007-08-26 (日) 06:32:13
GENKIさんこれからも頑張って下さい！！僕の方も有力な情報を見つけたら報告していきたいと思います。 -- バサンバ? 2007-09-01 (土) 21:56:50

久しぶりの修正作業。性能取得のサンプルを修正。解説も修正。ふとNキーロールオーバー対応キーボードいくらするのか調べてみたんですが、１万円以上はするようですね。しかもPS/2接続じゃないとNキーロールオーバーにならないようで、USB接続では6キーロールオーバーらしいです。本格的にFPSやる人とかが買うんでしょうか…。 -- GENKI? 2007-11-19 (月) 00:15:46

そういえば最近はアナログ対応コントローラが店頭に増えてきましたね。一方で２ボタンとか４ボタンとか古いデザインのものも出てきてますが。　そろそろアナログ取得にも対応しようかな・・・。問題は未入力状態の設定か。 -- GENKI? 2007-11-19 (月) 00:21:32

良かれと思い、数点レイアウトを変更しました。主に見出しの変更です。
ジョイスティックID＝モジュールで独自に定義した概念という理解で良いのでしょうか？ -- eller 2007-12-03 (月) 07:40:00

ありがとうございます。すごく見やすくなりましたー。 [bsmile2]

ジョイスティックIDってのは…検索してもほとんど出ませんね。呼び方違うのかな？
ここでいうジョイスティックIDとは…

APIのjoyGetPosEx、joyGetPos関数で指定するパラメータuJoyIDのこと。JOYSTICKID。
0～(ドライバにサポートされるジョイスティック数-1)の整数値。
PCに接続されているゲームパッドにはそれぞれ重複しない0以上のジョイスティックID（番号）がつけられている。
Win98,ME,2kではコントローラID（＝ジョイスティックID+1）として確認、変更が可能である。
WinXP以降のOSでは確認することは出来ないかわりに、優先的にジョイスティックIDを小さい番号にする設定は可能。

とまあこんな感じです。この呼び方は検索しても出てこないので独自といえば独自なのかも…、でも概念はjoyGetPos?関数のそれなので独自ではないです。 -- GENKI? 2007-12-03 (月) 22:42:13

回答ありがとうございます。ジョイスティックIDで検索してもほとんどヒットしないので独自だろうかと考えていました。 -- eller 2007-12-04 (火) 07:30:00

コントローラIDが主になっていた文章をジョイスティックIDが主になるように修正しました。あ上のコメントのジョイスティックIDとは…を本文に入れるの忘れた。明日入れよう…。 -- GENKI? 2007-12-04 (火) 00:53:05

つまりｎキーロールオーバーはソフトウェアで回避不可能ってことですかね？ -- 2007-12-08 (土) 01:31:33

そうです。HSPに限らず回避する方法を見かけたことがありません。 -- GENKI? 2007-12-08 (土) 14:23:10

個人サイトのほうで開発中のジョイスティックモジュールのβ版を公開中です。気の向いた方はご意見ください。β版ダウンロード　　…宣伝失礼。 [ojigi]

-- GENKI? 2007-12-27 (木) 01:04:14

試してみました。joyp_test02.hspのサンプルスクリプトで、実際に押しているかどうかにかかわらず↑キーが押されっぱなしの状態になります。ジョイスティックを接続していない状態では問題ありません。環境はVista＆ELECOM「JC-U923WH」です。
使い勝手は良好です。サンプルスクリプト以上の動作確認はできていません。 -- eller 2007-12-29 (土) 09:42:43
動作確認ありがとうございます！↑キーが押されっぱなし＞うーん、こちらでは現象確認できません。キーボードに何か接触してませんでしたか？（↑キーとかテンキーの８付近とか…）キーボード入力も受け付けてるからそれが原因かもしれません。 -- GENKI? 2007-12-29 (土) 23:44:56
もちろん何も触れていない状態です。XPでも上記異常動作を確認しました。
アナログ入力値は正常に取得できているようです。 -- eller 2007-12-30 (日) 10:18:21
状況を確認したいので少し教えて下さい。異常動作が起きているとき、次のことを確認していただけないでしょうか。
- 何も押していないときの「アナログ L」の数値はいくつと表示されてますでしょうか。（出来ればスティックの左上、右下の時の値がもらえると助かります。）
- 「次のボタンが押されています。」の下に「↑：上ボタン」が表示されているのでしょうか。 -- GENKI? 2007-12-30 (日) 15:46:59
- 何も押していないときの「アナログ L」の数値→(32511,32511)
  左上→(0,0)
  右下→(65535,65535)
  「↑：上ボタン」→表示されています。黒丸も描画されています。 -- eller 2007-12-30 (日) 15:58:31

ありがとうございます。POVキー(ハットスイッチ)キーの上(0度)を検出か。JC-U812はハットスイッチないので検出しないはずなのにー。むしろこの辺が原因なのかな…joyp_test03.hspと比較しつつ調べてみます。 -- GENKI? 2007-12-30 (日) 19:15:56

ごめんなさい、後で確認してみますがjoyp_test03.hspでも発生したはずです。 -- eller 2007-12-31 (月) 00:08:17
てことは、念のため…。コントロールパネルからゲームコントローラを開いて、問題のゲームパッドのプロパティを見てもらえませんでしょうか。ここでパッドの動作確認が出来るんですが、ハットスイッチ(POV)で上が入りっぱなしになってませんでしょうか。（本来ならハットスイッチの項目も表示されないはずですけど。）もしそうなら設定タブで調整を行ってみてください。お手数かけます。年末忙しいと思いますのでひまなときで結構です…。というか私も明日から数日何も出来ませんので。 -- GENKI? 2007-12-31 (月) 17:09:00

こちらのモジュールをお借りしたのですが、ジョイスティックを挿していないと、キーボードの入力も受け付けなくなります [sad2]

ジョイスティックを挿してなくてもキーボードの入力を受け付けるようにするには、どの部分をどう修正すればいいのでしょうか？ [ojigi]

-- sumomo? 2009-05-25 (月) 17:29:25

むむ、私の環境でもテストしてみましたが現象確認できませんでした。とりあえずここのに修正やら何やらを追加したものがこちらにありますので、付属のサンプルで確認してみてください。 -- GENKI? 2009-05-26 (火) 00:48:38
素早い返信ありがとうございます。早速ダウンロードさせていただきました。サンプルを試したところ、ジョイスティックを挿してない状態でのキーボードからの入力にもちゃんと反応しました。内容を理解できるかまだ不安ですが、マニュアルをじっくり読んでモジュールを活用できるよう頑張りたいと思います。ありがとうございましたm(_ _)m -- sumomo? 2009-05-26 (火) 02:18:33
解決してよかったです。しかし、自分で作っといて原因が思い当たらない…。中身だいぶ忘れてるなー。 -- GENKI? 2009-05-26 (火) 23:26:06

上記の件の続きなのですが、そのキーボードの反応がどうもおかしいのです。例えば矢印キーの←、↑、→、↓を押すとそれぞれジョイスティックのボタン1、2、3、4の値として出力されている（Z,X,C,Vキーもそれぞれボタン5,6,7,8の値が出力されます）ようで、これはキーボードの問題なのでしょうか？キーボードはこちらhttp://www.ec-current.com/shop/g/g4900849809948を使用しています -- sumomo? 2009-06-01 (月) 22:26:19

もし、padset.iniファイルがあったらこれを削除してからもう一度確認してみてください。padset.iniに変な設定が残ってるのかもしれません。ちなみにどのサンプルで試してみた結果でしょうか？　キーボードのほうは極普通のもののようなので問題ないと思います。 -- GENKI? 2009-06-02 (火) 23:54:36
padset.iniファイルは見当たらず、キーボード入力が出力されるサンプル1,4,5で同様の結果になりました。しかしサンプル2のみ、十字キーそれぞれで1-2-4-8と出力、またZ~Vを押しても反応がありませんでした。いかがでしょうか。 -- sumomo? 2009-06-04 (木) 23:46:33
サンプル２のキーボードはただのstick命令なのでそれは正常に動いているようです。（z～vが反応しないのは正常）
モジュール内でキーボードの情報取得はstickとgetkeyでやっているので、本来問題はないはずなのですが…。難しいですね、何だろう。
古いモジュールのファイルがcommonなどに残っているとか…いったん全部残らず確実に消したのを確認してから最新版を入れてみるといいかもしれません。
すみませんちょっと原因特定が難しいです。 -- GENKI? 2009-06-05 (金) 00:56:13
ダウンロードし直してサンプルを試してみましたが、やはり同じ症状のままでした。原因不明なのは残念ですが、コントローラは問題なく使えますしコンフィグ機能も便利なので、このまま利用させていただこうと思います。ありがとうございました。 -- sumomo? 2009-06-07 (日) 14:34:13

古い話で申し訳ないのですが、↑キーが押されっぱなしになる件は解決されているのでしょうか？ -- 初心者? 2009-09-13 (日) 10:58:48

上記の続き。ELECOMのパッドを使っているのですが同じ症状で、プロパティを確認しましたが、POVキーは検出されませんでした。とりあえずソース中の「POV（ハット）キーも方向キーとして扱う」以下５行を削除したところ正常に動作しました。この使い方で問題ないでしょうか？ -- 初心者? 2009-09-13 (日) 11:07:15

こちらのモジュールセットを使ってみてください。このページで紹介している内容＋αをまとめたものです。「↑キーが押されっぱなし」問題は修正済みです。
中がどうなっているかはだいぶ時間がたって忘れてしまったので、詳しくはこれのスクリプトを見てください。あ、使うだけならスクリプトなんか見なくていいですよ。hsもついてますので。 -- GENKI? 2009-09-15 (火) 21:35:37

GENKIさんありがとうございます [bsmile2]

！…というかすみませんでしたー。すでに解決＋αされていたのですね。ありがたく使わせていただきます！ [ojigi]

-- 初心者? 2009-09-16 (水) 00:00:04

すみません。ちゃんと本文で誘導してませんでした。　いましがた本文でも誘導文入れてきました。 -- GENKI? 2009-09-16 (水) 00:29:03

添付ファイル:

joy003.hsp 864件 [詳細]

小ワザ/ジョイスティック

OFFICIAL/関連

TUTORIAL

TOPICS

ETC

EDIT

REFERENCE

LOG

お知らせ

HSP Web-Ring

最新の40件

ジョイスティック †

モジュール（stick互換） †

joy003.hsp

ボタン配置 †

ジョイスティックID †

XPより前のジョイスティックID †

XP以降のジョイスティックID †

ジョイスティックIDを調べる †

XPより古いOSで調べる †

XP以降のOSで調べる †

コントローラ変換コネクタ †

ジョイスティックの性能を取得 †

ジョイスティックの接続状態を取得する †

キーボードのキーロールオーバー †

コメント †