小ワザ/デスクトップを表示

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44

;---------------------------------------------------------------------
;
;	タスクバーの[デスクトップを表示]を実現してみる
;
;---------------------------------------------------------------------
 
    ;hscallbk.dll が必要です
    #include "hscallbk.as"
 
    #uselib "user32.dll"
    #func GetWindowText "GetWindowTextA" int, int, int
    #func EnumWindows "EnumWindows" int, int
    #func IsIconic "IsIconic" int
    #func IsWindowVisible "IsWindowVisible" int
    #func CloseWindow "CloseWindow" int
 
    ;コールバック関数定義
    #uselib ""
    #func proto_EnumWindowsProc "" int, int
 
    sdim tmp, 129
 
    ;ウィンドウ列挙開始
    setcallbk pEnumWindowsProc, proto_EnumWindowsProc, *EnumWindowsProc
    mes "処理中..." : EnumWindows varptr(pEnumWindowsProc)
    mes "処理完了"
 
    stop
 
*EnumWindowsProc
    hWindow = callbkarg(0)
 
    ;名前のないウィンドウは無視する(高速化)
    GetWindowText hWindow, varptr(tmp), 128
    if tmp = "" : return 1
 
    ;ウィンドウの状態を調べる
    IsIconic hWindow : isicon = stat
    IsWindowVisible hWindow : isvisible = stat
 
    ;最小化されていない & 可視 & IMEではない = 最小化
    if (isicon = 0) & isvisible & (instr(tmp, 0, "IME") = -1) : CloseWindow hWindow
 
    return 1

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35

#uselib "user32.dll"
#func global GetWindowLong "GetWindowLongA" sptr, sptr
#func global FindWindowEx  "FindWindowExA"  sptr, sptr, sptr, sptr
#func global PostMessage   "PostMessageA"   sptr, sptr, sptr, sptr
 
#define WS_VISIBLE          0x10000000
#define WS_CAPTION          0x00C00000
#define WS_SYSMENU          0x00080000
#define WS_MINIMIZEBOX      0x00020000
 
#define WM_SYSCOMMAND                   0x0112
#define SC_MINIMIZE     0xF020
 
    hwndCA=0
 
*main
    repeat
        FindWindowEx 0 ,hwndCA, 0, 0
        hwndCA=stat
        if hwndCA=0 : break
 
        ;    親ウィンドウか?
        GetWindowLong hwndCA, -8
        if stat!=0 : continue
 
        ;    可視で最小化ボタンのあるウィンドウか?
        GetWindowLong hwndCA, -16
        if (stat & 0x10CA0000)!=0x10CA0000 : continue
 
        ;    自分自身は最小化しないとき
        ;if hwnd=hwndCA : continue
        PostMessage hwndCA, WM_SYSCOMMAND, SC_MINIMIZE, 0
    loop
    ;   システムに制御を返してメッセージを処理してもらう
    wait 0