小ワザ/VRAMを直接操作してみる

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54

;===============================================================================
; VRAMを利用した画面描画サンプル
;===============================================================================
#ifndef __vram_draw__
#module _vram_draw_
    #define __vram_draw__
    ;-----------------------------------------------------------------------
    ; VRAMでpset命令を実現する命令
    ; 引  数：px    描画先のx座標
    ;         py    描画先のy座標
    ;-----------------------------------------------------------------------
    #deffunc vram_pset int px, int py
        mref vram, 66
 
        ; 描画先座標より、vramのindexを取得
        ; ※vramの先頭が画面の左上からではなく、右下からB,G,R...となるので注意。
        index = (ginfo(12) * ginfo(13)) - ( (py + 1) * ginfo(12) - px)
 
        ; vramのRGBを書き換え。
        poke vram, index * 3, ginfo(18)     // B要素
        poke vram, index * 3 + 1, ginfo(17) // G要素
        poke vram, index * 3 + 2, ginfo(16) // R要素
 
        ; 処理終了
        ; ※実際にはredraw 1を実行しないと画面に反映されないので注意
        return
#global
#endif
;-------------------------------------------------------------------------------
; 以下サンプルプログラム
;-------------------------------------------------------------------------------
; VRAMのPSET命令で矩形を描いてみる
color 0,0,255
repeat 100
    y = cnt
    repeat 100
        x = cnt
        vram_pset x + 100, y + 100
    loop
loop
redraw 1    ; これを実行しないと画面に反映されない。
 
wait 200
 
; 確認用、HSP標準のpset命令で矩形を描いてみる。
color 255,0,255
repeat 100
    y = cnt
    repeat 100
        x = cnt
        pset x + 100, y + 100
    loop
loop
redraw 1

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47

#module
 
  #deffunc PickRGB str p1
    switch (p1)
      case "R" :case "r" :x = 0 :swbreak
      case "G" :case "g" :x = 1 :swbreak
      default            :x = 2 :swbreak
      swend
    mref BMSCR, 67   // BMSCR構造体を取得します。
    mref VRAM, 66    // VRAM情報を取得します。
    /* 指定された要素以外を取り除きます。*/
    repeat (BMSCR(1)*BMSCR(2)*3/4)
      VRAM(cnt) &= RGB( cnt\3, x )
    loop
    return
 
  #deffunc Initialize
    dim RGB, 3, 3
    RGB(0,0) = 0x00FF0000, 0x0000FF00, 0xFF0000FF // R
    RGB(0,1) = 0x0000FF00, 0xFF0000FF, 0x00FF0000 // G
    RGB(0,2) = 0xFF0000FF, 0x00FF0000, 0x0000FF00 // B
    return
 
#global
 
Initialize       // 初期化します。
 
buffer 1
  picload dirinfo(1)+"/sample/demo/sky_bg.jpg"
  x1 = GINFO_WINX
  y1 = GINFO_WINY
buffer 2
  picload dirinfo(1)+"/sample/demo/jp6girl.bmp"
  x2 = GINFO_WINX
  y2 = GINFO_WINY
 
screen 0, 640, 480
  gmode 0 :gcopy 1, 0, 0, x1, y1
  gmode 2 :gcopy 2, 0, 0, x2, y2
 
  redraw 0
    PickRGB "R"    // 画面のＲ情報だけを抜き出します。
;   PickRGB "G"    // 画面のＧ情報だけを抜き出します。
;   PickRGB "B"    // 画面のＢ情報だけを抜き出します。
  redraw 1
 
// EOF //////////////////////////////////////////

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46

// BMPローダー 24bit Windows BMP専用, RLE非対応版, 画素は下から上方向で。( = 普通の24bitのBMPです)
// picloadを使わない版(VRAMアクセスの実験。)
// ファイルは正しい形式であることが前提です(ファイル形式のチェックは省略してます)
// 不特定のファイルを読む場合は、きちんと形式などのチェックをしましょう。
 
sdim szFileName, 1024 // 画像ファイル名用バッファー
szFileName = "test.bmp" // 別途szFileNameで指定したファイル名のビットマップファイルを用意して下さい。
 
// BMPファイルヘッダ(BITMAPFILEHEADER) と情報ヘッダ(BITMAPINFOHEADER)の読み込み
sdim cBMPHeader, 64 // Windows BMPの場合はヘッダーサイズは54 // bloadが64バイト以上要求するのでサイズは64
bload szFileName, cBMPHeader // 最低64バイトは読まないといけないらしい・・ 
 
bfSize = lpeek(cBMPHeader, 2) // ファイルサイズ(Byte)
bfOffBits = lpeek(cBMPHeader, 10) // ファイル先頭から画像データまでのオフセット(Byte)
 
biWidth = lpeek(cBMPHeader, 18) // 画像の幅 (ピクセル)
biHeight = lpeek(cBMPHeader, 22) // 画像の高さ (ピクセル) // 正なら画像データは下から上 // 負なら上から下ですがほとんど使われないらしいので非対応
 
sdim cBMPData, bfSize - bfOffBits // 画像部分のデータ読み込みようのバッファーを作成します
bload szFileName, cBMPData, (bfSize - bfOffBits), bfOffBits // szFileNameで指定したファイルの画像部分を読み込みます
// (memfileで行こうと思いましたが、memcopyができないので断念)
 
screen 0, biWidth, biHeight // 画面を初期化 // 画面の大きさは画像サイズに合わせてあります
mref mVRAM, 66 // VRAMに直接アクセスするための変数を設定
 
memcpy mVRAM, cBMPData, bfSize - bfOffBits
redraw 1
 
stop
 
// 参考に。ファイル形式チェック用コード // bload szFileName, cBMPHeader以降の場所で使用可。
// BMPのファイル形式は http://www.kk.iij4u.or.jp/~kondo/bmp/ あたりを参考に。
/* // チェック用で1回しか使わない値は変数名全部同じでも良いかも
// BMPかどうかチェックするなら、こんな感じで。
bfType = wpeek(cBMPHeader, 0) // ファイルタイプ："BM"固定。 // 'B' = 0x42, 'M' = 0x4D
if (bfType != 0x4D42) : mes "BMPファイルではありません" // wpeekするとバイトの並び順が逆になるので注意。
// Windows BMPかどうかチェックするなら、こんな感じで。
biSize = lpeek(cBMPHeader, 14) // 情報ヘッダのサイズ (byte)：Windows BMPは40。OS/2 BMPは12
if (biSize != 40) : mes "Window BMPファイルではありません" // エラー処理などをここに。
// 色数をチェックするなら、こんな感じで。
biBitCount = wpeek(cBMPHeader, 28) // 1 画素あたりのデータサイズ (bit) // 通常は1,4,8,24,32のどれか
if (biBitCount != 24) : mes "24bit BMPファイルではありません" // エラー処理などをここに。
// RLE圧縮をチェックするなら、こんな感じで。
biCopmression = lpeek(cBMPHeader, 30) // 圧縮形式 // 0:無圧縮, 1:RLE8, 2:RLE4, 3:Bitfields
if (biCopmression != 0) : mes "RLE圧縮されたファイルです" // エラー処理などをここに。
*/

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34

// BMPローダー 24bit Windows BMP専用, RLE非対応版, 画素は下から上方向で。( = 普通の24bitのBMPです)
// 今回はVRAMに直接読み込みます。BMPファイルを外部から入手した場合は、チェック用コードを入れたほうが良いです。
// 用意するBMPファイルは画面におさまるサイズでお願いします。
 
sdim szFileName, 1024 // 画像ファイル名用バッファー
szFileName = "test.bmp" // 別途szFileNameで指定したファイル名のビットマップファイルを用意して下さい。
 
// BMPファイルヘッダ(BITMAPFILEHEADER) と情報ヘッダ(BITMAPINFOHEADER)の読み込み
sdim cBMPHeader, 64 // Windows BMPの場合はヘッダーサイズは54 // bloadが64バイト以上要求するのでサイズは64
bload szFileName, cBMPHeader // 最低64バイトは読まないといけないらしい・・ 
 
bfSize = lpeek(cBMPHeader, 2) // ファイルサイズ(Byte)
bfOffBits = lpeek(cBMPHeader, 10) // ファイル先頭から画像データまでのオフセット(Byte)
 
biWidth = lpeek(cBMPHeader, 18) // 画像の幅 (ピクセル)
biHeight = lpeek(cBMPHeader, 22) // 画像の高さ (ピクセル) // 正なら画像データは下から上 // 負なら上から下ですがほとんど使われないらしいので非対応
 
// 変更部分　ここから
 
//sdim cBMPData, bfSize - bfOffBits // 画像部分のデータ読み込みようのバッファーを作成します
 
screen 0, biWidth, biHeight // 画面を初期化 // 画面の大きさは画像サイズに合わせてあります
mref mVRAM, 66 // VRAMに直接アクセスするための変数を設定
 
//bload szFileName, cBMPData, (bfSize - bfOffBits), bfOffBits // szFileNameで指定したファイルの画像部分を読み込みます
bload szFileName, mVRAM, (bfSize - bfOffBits), bfOffBits // VRAMに直接画像データを読み込みます // 巨大なファイルを読み込まないように注意！
 
//memcpy mVRAM, cBMPData, bfSize - bfOffBits // VRAMに画像データをコピーします
 
// 変更部分　ここまで
 
redraw 1
 
stop