移動判定

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
|
|
-
|
|
-
|
|
-
|
|
-
|
|
|
|
-
|
!
-
|
!
!
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
-
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
!
 
 
 
 
 
 

#module SRPGSerch
/*
	マップデータ初期化命令
	srpginit s1, p1, p2
	s1(var) : 文字列型マップデータ格納変数
	p1,p2(int) : マップサイズ(X,Y)
*/
#deffunc srpginit str s1, int p1, int p2
    map = s1                  // マップデータ
    mapsizeX = p1             // マップサイズ（横）
    mapsizeY = p2             // マップサイズ（縦）
    vx = 0, 1, 0, -1          // x + vx(向き) が移動後のX座標を示す
    vy = -1, 0, 1, 0          // y + vy(向き) が移動後のY座標を示す
    return
 
/*
	ロボット調査
	serch p1
	p1(int) : 残り移動量
*/
#deffunc serch@SRPGSerch int power
    poke result, y*mapsizeX+x, power+'0'          // 旗を立て、残っている移動力を記す
    if power > 0 {
        repeat 4                      // cnt = 調査する方向
            step++                    // ステップ数をインクリメント
            serchX = x + vx(cnt)      // 調査対象地点X座標
            serchY = y + vy(cnt)      // 調査対象地点Y座標
            if (serchX<0)|(serchY<0)|(serchX>=mapsizeX)|(serchY>=mapsizeY) {
                                                 // 移動不可能(対象座標がマップ外)
                logmes strf("[step%03d]地点("+serchX+","+serchY+")は移動不可能です", step)
            } else {
                i = power-(peek(map, serchY*mapsizeX+serchX)-'0')
                                                 // 移動力 - 移動先のマスのコスト
                if i>=0 {                        // 移動力は充分
                    j = peek(result, serchY*mapsizeX+serchX)-'0'     // 移動先に立っている旗に書かれている数
                                                                     // 旗が立っていない場合は半角スペースが記録されているので、j = -16
                    if j<i {                     // 移動可能
                        x = serchX : y = serchY                      // 移動
                        logmes strf("[step%03d]地点("+serchX+","+serchY+")は移動可能です", step)
                        serch i                                      // ロボットの新しい調査開始
                        x -= vx(cnt) : y -= vy(cnt)                  // 戻ってきたら元の場所に戻る（x,yを元の値に戻す）
                    } else {                     // 移動不可能（“移動力 - 移動先のマスのコスト”以上の値が書かれた旗が既に立っている）
                        logmes strf("[step%03d]地点("+serchX+","+serchY+")は既に調査完了しています", step)
                    }
                } else {                         // 移動不可能（移動力が足りない）
                    logmes strf("[step%03d]地点("+serchX+","+serchY+")は移動不可能です", step)
                }
            }
        loop
    }
    return
 
/*
	ロボット出発
	mapserch v1, p2, p3, p4
	v1(var) : 探索データ（旗）格納変数
	p2,p3(int) : 出発地点(X,Y)
	p4(int) : 移動量
*/
#deffunc mapserch var v1, int p2, int p3, int p4
    sdim result, mapsizeX*mapsizeY+1
    memset result, ' ', mapsizeX*mapsizeY         // 最初旗は1本も立っていない（半角スペースで初期化）
    x = p2 : y = p3                               // ロボットの場所を指定
    step = 0                                      // 何ステップ目かをカウントする変数
    serch p4                                      // ロボット発進！
    sdim v1, mapsizeX*mapsizeY+1
    memcpy v1, result, mapsizeX*mapsizeY          // v1に探索データをコピー
    return
 
/*
	正方形を描く
	draw_sq p1, p2, p3
	p1,p2(int) : 左上座標
	p3(int) : マス1辺の長さ
*/
#deffunc draw_sq int p1, int p2, int p3
    line p1*p3+2, p2*p3+2, (p1+1)*p3-3, p2*p3+2
    line (p1+1)*p3-3, p2*p3+2, (p1+1)*p3-3, (p2+1)*p3-3
    line (p1+1)*p3-3, (p2+1)*p3-3, p1*p3+2, (p2+1)*p3-3
    line p1*p3+2, (p2+1)*p3-3, p1*p3+2, p2*p3+2
    return
#global
 
 
#define MAPX   11             // マップの横方向の大きさ
#define MAPY   11             // マップの縦方向の大きさ
#define MOVE    4             // 移動力
#define SQSIZE 32             // タイルの一辺の大きさ
    screen 0, MAPX*SQSIZE, MAPY*SQSIZE
    title "クリックでユニット位置変更"
    randomize
    sdim map, MAPX*MAPY+1
    repeat MAPX*MAPY          // マップ自動生成
        if rnd(4)==0 {
            poke map, cnt, '2'
        } else {
            poke map, cnt, '1'
        }
    loop
    srpginit map, MAPX, MAPY  // マップのデータと大きさをモジュールに渡す
    onclick goto *click
 
*click
    mx = limit(mousex/SQSIZE, 0, MAPX-1)
    my = limit(mousey/SQSIZE, 0, MAPY-1)
    mapserch s, mx, my, MOVE  // 変数sに探索データ代入
 
    redraw 0
    repeat MAPY : c1 = cnt
        repeat MAPX
            // マップ描画（矩形塗りつぶし）・消費する移動力が大きいほど暗く塗る
            a = 255-64*(peek(map, c1*MAPX+cnt)-'0')         // マップの色
            color a, a, a : boxf cnt*SQSIZE, c1*SQSIZE, (cnt+1)*SQSIZE, (c1+1)*SQSIZE
 
            // 移動可能な地点に四角形を描く
            i = strf("%c", peek(s, c1*MAPX+cnt))  // 探索データ取り出し
            if (i != " ") {                       // 旗が立っている
                color 255, 255, 255 : draw_sq cnt, c1, SQSIZE
                pos cnt*SQSIZE+12, c1*SQSIZE+8 : mes i      // 残り移動力を表示
            }
        loop
    loop
    color 255, 255, 255       // 現在地表示
    circle mx*SQSIZE, my*SQSIZE, (mx+1)*SQSIZE, (my+1)*SQSIZE
    redraw 1
    stop