eseobj/imgbtn3

画像ボタン †

[編集]

　ウィンドウメッセージとモジュール変数を利用した画像ボタンです。
一切のオブジェクトも使用していないため，メモリの許す限りいくつでもボタンを生成可能。ゲーム開発などにどうぞ。スクリプトの書き方によってはアルファブレンドにも対応できるかもしれません。
　複数ウィンドウにも対応しています。

/*********************************************************************************
  画像ボタン imgbtn ver.3 Created By As
 
  画像ボタンの作成
  imgbtn
  ウィンドウメッセージとモジュール変数を利用した画像ボタン,
  ボタンに表示させる文字列, 
  横の長さ, 
  縦の長さ, 
  通常状態の画像ボタンの入ったウィンドウID,
  取得するX座標,
  取得するY座標,
  マウスが重なった場合に表示される画像ボタンの入ったウィンドウID,
  取得するX座標,
  取得するY座標,
  マウスを押した場合に表示される画像ボタンの入ったウィンドウID,
  取得するX座標,
  取得するY座標,
  描画モード  
  (戻り値: 画像ボタンID)
 
  画像ボタンを再描画
  #deffunc imgbtn_draw ウィンドウメッセージ,lparam, ginfo_intid
 
    ウィンドウメッセージは下記の３つを指定します
    oncmd gosub *ON_WM_LBUTTONDOWN, WM_LBUTTONDOWN
    oncmd gosub *ON_WM_LBUTTONUP, WM_LBUTTONUP
    oncmd gosub *ON_WM_MOUSEMOVE, WM_MOUSEMOVE
 
  ボタンの上にカーソルがあるボタンのIDを返す
  #defcfunc imgbtn_check_id lparam, ginfo_intid
  ※WM_LBUTTONUPが受け取られたときに処理することで，ボタンの制御が可能です
 
  ボタンの上にカーソルがあるボタンのテキストを返す
  #defcfunc imgbtn_check_text lparam, ginfo_intid
  ※WM_LBUTTONUPが受け取られたときに処理することで，ボタンの制御が可能です
 
  ボタンのテキストを取得する
  #defcfunc imgbtn_gettext ボタンID
 
  ボタンのテキストを設定する
  #defcfunc imgbtn_gettext ボタンID, テキストに指定する文字列
 
  強制的に指定されたHSPウィンドウIDの全てのボタンの再描画を行う
  #deffunc imgbtn_alldraw HSPウィンドウID
 
  ボタン以外の箇所をクリックしながら，ボタンまで移動していきボタンを離した場合の挙動を取得
  #deffunc imgbtn_bgc lparam, ginfo_intid
 
  ボタン以外の箇所からクリックした場合，0を返す
  #defcfunc imgbtn_bgcc lparam, ginfo_intid
 
  指定したボタンを枠で囲む
  #deffunc imgbtn_select ボタンID, 余白サイズ
  ※ウィンドウメッセージの処理で使用します
 
**********************************************************************************/
    
#module module_imgbtn m_btntext, m_width, m_height, m_btn_default_hspwinid, m_btn_default_width, m_btn_default_height, m_btn_mouse_hspwinid, m_btn_mouse_width, m_btn_mouse_height, m_btn_push_hspwinid, m_btn_push_width, m_btn_push_height, m_cx, m_cy, m_hspwinid, m_hsphwnd, m_drawstat, m_drawstat2, m_id, m_btntext_px, m_btntext_py, m_r, m_g, m_b, m_gmode
#define WM_LBUTTONUP    $00000202
#define WM_LBUTTONDOWN    $00000201
#define WM_MOUSEMOVE    $00000200
#uselib "user32.dll"
#func SetCapture "SetCapture" sptr
#func ReleaseCapture "ReleaseCapture" 
#uselib "gdi32"
#func  GetTextExtentPoint32A "GetTextExtentPoint32A" sptr,sptr,sptr,sptr
 
 
 
 
#modfunc mod_imgbtn_draw int _message, int _lparam, int _ginfo_intid, local s1, local s2, local s3, local s4, local s5, local s6
s1   =  _lparam & 0xFFFF         // カーソルx座標
s2   = (_lparam >> 16) & 0xFFFF  // カーソルy座標
s3 = ginfo_sel                    //現在の描画先ウィンドウを保持
gsel m_hspwinid                    //画像がある描画先ウィンドウに切り替える
 
switch _message
    case 0
        gmode m_gmode
        pos m_cx, m_cy
        gcopy m_btn_default_hspwinid, m_btn_default_width, m_btn_default_height, m_width, m_height         //通常のボタン
        if m_btntext != ""{
            s4 = ginfo_r
            s5 = ginfo_g
            s6 = ginfo_b
            pos m_btntext_px, m_btntext_py
            color m_r, m_g, m_b
            mes m_btntext
            color s4, s5, s6
        }
        pos m_cx, m_cy+m_height
        swbreak
 
    case WM_MOUSEMOVE
        
        if m_hspwinid != _ginfo_intid : swbreak
        if (drawid != m_id)&(drawflag == 1) :swbreak        //ボタンが押されている状態でマウスを動かした場合それ以外のボタンの描画を停止する
        if (m_drawstat!=2)&(s1>=m_cx)&(s1<m_cx+m_width)&(s2>=m_cy)&(s2<m_cy+m_height){
            if m_drawstat=0{
                gmode m_gmode
                pos m_cx, m_cy
                gcopy m_btn_mouse_hspwinid, m_btn_mouse_width, m_btn_mouse_height, m_width, m_height         //マウスが重なっている
                
                if m_btntext != ""{
                    s4 = ginfo_r
                    s5 = ginfo_g
                    s6 = ginfo_b
                    pos m_btntext_px, m_btntext_py
                    color m_r, m_g, m_b
                    mes m_btntext
                    color s4, s5, s6
                }
                m_drawstat = 1        //1 = 重なった画像が表示されている状態
                SetCapture m_hsphwnd
            }
        }else:if m_drawstat = 1{
            gmode m_gmode
            pos m_cx, m_cy
            gcopy m_btn_default_hspwinid, m_btn_default_width, m_btn_default_height, m_width, m_height         //通常のボタン
            if m_btntext != ""{
                s4 = ginfo_r
                s5 = ginfo_g
                s6 = ginfo_b
                pos m_btntext_px, m_btntext_py
                color m_r, m_g, m_b
                mes m_btntext
                color s4, s5, s6
            }
            m_drawstat = 0        //0 = 通常の画像が表示されている状態
            ReleaseCapture
            
            
        }else:if m_drawstat = 2{
            if (s1>=m_cx)&(s1<=m_cx+m_width)&(s2>=m_cy)&(s2<=m_cy+m_height){
                if m_drawstat2 = 0{
                    gmode m_gmode
                    pos m_cx, m_cy
                    gcopy m_btn_push_hspwinid, m_btn_push_width, m_btn_push_height, m_width, m_height         //マウスが押されている
                    
                    if m_btntext != ""{
                        s4 = ginfo_r
                        s5 = ginfo_g
                        s6 = ginfo_b
                        pos m_btntext_px+1, m_btntext_py+1
                        color m_r, m_g, m_b
                        mes m_btntext
                        color s4, s5, s6
                    }
                    m_drawstat2 = 1                    //押されている状態で移動した場合１回だけ描画
                }
            }else{
                if m_drawstat2 == 1{
                    gmode m_gmode
                    pos m_cx, m_cy
                    gcopy m_btn_default_hspwinid, m_btn_default_width, m_btn_default_height, m_width, m_height         //通常のボタン
                    if m_btntext != ""{
                        s4 = ginfo_r
                        s5 = ginfo_g
                        s6 = ginfo_b
                        pos m_btntext_px, m_btntext_py
                        color m_r, m_g, m_b
                        mes m_btntext
                        color s4, s5, s6
                        
                    }
                    m_drawstat2 = 0
                    
                    
                }
                
            }
            
        }
        swbreak
 
    case WM_LBUTTONDOWN
        if m_hspwinid != _ginfo_intid : swbreak
        if (m_drawstat==1)&(s1>=m_cx)&(s1<=m_cx+m_width)&(s2>=m_cy)&(s2<=m_cy+m_height){
            gmode m_gmode
            pos m_cx, m_cy
            gcopy m_btn_push_hspwinid, m_btn_push_width, m_btn_push_height, m_width, m_height         //マウスが押されている
            if m_btntext != ""{
                    s4 = ginfo_r
                    s5 = ginfo_g
                    s6 = ginfo_b
                    pos m_btntext_px+1, m_btntext_py+1
                    color m_r, m_g, m_b
                    mes m_btntext
                    color s4, s5, s6
                }
            m_drawstat = 2        //2 = 押されている状態
            drawflag = 1
            drawid = m_id
        }
        swbreak
 
    case WM_LBUTTONUP
        if m_hspwinid != _ginfo_intid : swbreak
        if (m_drawstat==2)&(s1>=m_cx)&(s1<=m_cx+m_width)&(s2>=m_cy)&(s2<=m_cy+m_height){
            gmode m_gmode
            pos m_cx, m_cy
            gcopy m_btn_mouse_hspwinid, m_btn_mouse_width, m_btn_mouse_height, m_width, m_height         //マウスが重なっている
            if m_btntext != ""{
                    s4 = ginfo_r
                    s5 = ginfo_g
                    s6 = ginfo_b
                    pos m_btntext_px, m_btntext_py
                    color m_r, m_g, m_b
                    mes m_btntext
                    color s4, s5, s6
                }
            m_drawstat = 1        //1 = 重なった画像が表示されている状態
        }else{
            m_drawstat = 0
        }
        drawflag = 0
        ReleaseCapture
        swbreak
swend
 
 
 
gsel s3
return
 
#deffunc imgbtn_draw int _message, int _lparam, int _ginfo_intid
foreach ib
    mod_imgbtn_draw ib(cnt), _message, _lparam, _ginfo_intid
loop
return
 
 
#modfunc mod_imgbtn_check_id var _id, int _lparam, int _ginfo_intid, local s1, local s2
if m_hspwinid != _ginfo_intid : return 0
s1   =  _lparam & 0xFFFF         // カーソルx座標
s2   = (_lparam >> 16) & 0xFFFF  // カーソルy座標
if (s1>=m_cx)&(s1<=m_cx+m_width)&(s2>=m_cy)&(s2<=m_cy+m_height){
    _id = m_id
    return 1
}else{
    return 0
}
//ボタンの上にカーソルがあるボタンのIDを返す
#defcfunc imgbtn_check_id int _lparam, int _ginfo_intid, local s1, local s2
foreach ib
    mod_imgbtn_check_id ib(cnt), s1, _lparam, _ginfo_intid
    if stat == 1 : s2 = 1 : break
loop
if s2 == 1 {
    return s1
}else{
    return -1
}
 
 
#modfunc mod_imgbtn_check_text var _text, int _lparam, int _ginfo_intid, local s1, local s2
if m_hspwinid != _ginfo_intid : return 0
s1   =  _lparam & 0xFFFF         // カーソルx座標
s2   = (_lparam >> 16) & 0xFFFF  // カーソルy座標
if (s1>=m_cx)&(s1<=m_cx+m_width)&(s2>=m_cy)&(s2<=m_cy+m_height){
    _text = m_btntext
    return 1
}else{
    return 0
}
//ボタンの上にカーソルがあるボタンのテキストを返す
#defcfunc imgbtn_check_text int _lparam, int _ginfo_intid, local s1, local s2
foreach ib
    mod_imgbtn_check_text ib(cnt), s1, _lparam, _ginfo_intid
    if stat == 1 : s2 = 1 : break
loop
if s2 == 1 {
    return s1
}else{
    return -1
}
 
 
#modfunc mod_imgbtn_settext str _text, local s1
m_btntext = _text
dim s1, 2
GetTextExtentPoint32A hdc, m_btntext, strlen(m_btntext) , varptr(s1)
m_btntext_px = m_cx + (m_width - s1.0)/2
m_btntext_py = m_cy + (m_height - s1.1)/2
mod_imgbtn_draw thismod
return
//ボタンのテキストを変更する
#deffunc imgbtn_settext int _id, str _text
mod_imgbtn_settext ib(_id), _text
return
 
 
#modfunc mod_imgbtn_gettext
return m_btntext
//ボタンのテキストを取得する
#defcfunc imgbtn_gettext int _id
mod_imgbtn_gettext ib(_id)
return stat
 
#modfunc mod_imgbtn_alldraw int _hspwinid
if m_hspwinid != m_hspwinid : return
mod_imgbtn_draw thismod
return
#deffunc imgbtn_alldraw int _hspwinid
foreach ib
    mod_imgbtn_alldraw ib(cnt), _hspwinid
loop
return
 
 
#defcfunc imgbtn_bgcc int _lparam, int _ginfo_intid
if btnflag {
    if btnid == imgbtn_check_id(_lparam, _ginfo_intid){
        return 1
    }else{
        return 0
    }
}else{
    return 0
}
#deffunc imgbtn_bgc int _lparam, int _ginfo_intid        //(BackGroundCheck)
btnid = imgbtn_check_id(_lparam, _ginfo_intid)
if btnid == -1{
    btnflag = 0
}else{    
    btnflag = 1
}
 
return
 
 
 
#modfunc mod_imgbtn_select int _padding, local s1, local s2, local s3, local s4
s1 = m_cx+2+_padding
s2 = m_cy+2+_padding
s3 = m_width-5-_padding*2
s4 = m_height-5-_padding*2
color
repeat s3/2+1
    pset s1+cnt*2,s2
loop
repeat s3/2+1
    pset s1+cnt*2,s2+s4
loop
repeat s4/2
    pset s1,s2+cnt*2
loop
repeat s4/2-1
    pset s1+s3,s2+cnt*2+2
loop
return
#deffunc imgbtn_select int _id, int _padding
mod_imgbtn_select ib(_id), _padding
return
 
 
#modinit str _btntext, int _width, int _height, int _btn_default_hspwinid, int _btn_default_width, int _btn_default_height, int _btn_mouse_hspwinid, int _btn_mouse_width, int _btn_mouse_height, int _btn_push_hspwinid, int _btn_push_width, int _btn_push_height, int _gmode, local s1
m_btntext = _btntext
m_width = _width
m_height = _height
m_btn_default_hspwinid = _btn_default_hspwinid
m_btn_default_width = _btn_default_width
m_btn_default_height = _btn_default_height
m_btn_mouse_hspwinid = _btn_mouse_hspwinid
m_btn_mouse_width = _btn_mouse_width
m_btn_mouse_height = _btn_mouse_height
m_btn_push_hspwinid = _btn_push_hspwinid
m_btn_push_width = _btn_push_width
m_btn_push_height = _btn_push_height
m_hspwinid = ginfo_sel
m_cx = ginfo_cx
m_cy = ginfo_cy
m_id = idcount
m_hsphwnd  = hwnd
m_gmode = _gmode
dim s1, 2
GetTextExtentPoint32A hdc, m_btntext, strlen(m_btntext) , varptr(s1)
m_btntext_px = m_cx + (m_width - s1.0)/2
m_btntext_py = m_cy + (m_height - s1.1)/2
m_r = ginfo_r
m_g = ginfo_g
m_b = ginfo_b
idcount++
return m_id
 
 
#deffunc imgbtn  str _btntext, int _width, int _height, int _btn_default_hspwinid, int _btn_default_width, int _btn_default_height, int _btn_mouse_hspwinid, int _btn_mouse_width, int _btn_mouse_height, int _btn_push_hspwinid, int _btn_push_width, int _btn_push_height, local s1
newmod ib, module_imgbtn, _btntext, _width, _height, _btn_default_hspwinid, _btn_default_width, _btn_default_height, _btn_mouse_hspwinid, _btn_mouse_width, _btn_mouse_height, _btn_push_hspwinid, _btn_push_width, _btn_push_height
 
s1 = stat
mod_imgbtn_draw ib(s1)
return s1
 
 
 
#global
 
 
 
 
 
 
 
#if 1
////////////////////////////////////////////////////////////////////////////////////////////////////
/// サンプル ///////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
 
#define WM_LBUTTONUP    $00000202
#define WM_LBUTTONDOWN    $00000201
#define WM_MOUSEMOVE    $00000200
 
//ボタンイメージ
buffer 1
color
boxf 1,1,99,20
color 210,210,210
boxf 1,1,98,19
 
color
boxf 1,22,99,41
color 180,180,180
boxf 1,22,98,40
 
color
boxf 0,42,98,61
color 180,180,180
boxf 1,43,98,61
 
screen 0, 200,200, , 10,10
oncmd gosub *ON_WM_LBUTTONDOWN, WM_LBUTTONDOWN
oncmd gosub *ON_WM_LBUTTONUP, WM_LBUTTONUP
oncmd gosub *ON_WM_MOUSEMOVE, WM_MOUSEMOVE
 
color 240,240,240
boxf
 
pos 45,140
color 255
font msgothic, 12
imgbtn "★", 100, 21, /*default*/1, 0, 0, /*mouse*/1, 0, 21, /*push*/1, 0, 42
pos ginfo_cx, ginfo_cy+5
color 0,0,255
imgbtn "", 100, 21, /*default*/1, 0, 0, /*mouse*/1, 0, 21, /*push*/1, 0, 42
 
screen 2, 120,120, , 400,10
oncmd gosub *ON_WM_LBUTTONDOWN, WM_LBUTTONDOWN
oncmd gosub *ON_WM_LBUTTONUP, WM_LBUTTONUP
oncmd gosub *ON_WM_MOUSEMOVE, WM_MOUSEMOVE
pos 10,10
color 240,240,240
boxf
sysfont 17
color
imgbtn "メモ帳を起動", 100, 21, /*default*/1, 0, 0, /*mouse*/1, 0, 21, /*push*/1, 0, 42
imgbtn "ペイントを起動", 100, 21, /*default*/1, 0, 0, /*mouse*/1, 0, 21, /*push*/1, 0, 42
imgbtn "TEST", 100, 21, /*default*/1, 0, 0, /*mouse*/1, 0, 21, /*push*/1, 0, 42
imgbtn "TEST", 100, 21, /*default*/1, 0, 0, /*mouse*/1, 0, 21, /*push*/1, 0, 42
gsel 0
 
 
stop
 
*ON_WM_MOUSEMOVE
    gmode 7
    font msgothic, 12
    imgbtn_draw WM_MOUSEMOVE, lparam, ginfo_intid
    return
 
*ON_WM_LBUTTONUP
    redraw 0
    font msgothic, 12
    imgbtn_draw WM_LBUTTONUP, lparam, ginfo_intid
    //背景をクリックしていないかチェック⇔imgbtn_bgc
    if imgbtn_bgcc(lparam, ginfo_intid){
        //ボタンの上にカーソルがあるボタンIDを取得
        switch imgbtn_check_id(lparam, ginfo_intid)
            case 0
                if flag == 0{
                    flag = 1
                    imgbtn_settext 0, ""
                    imgbtn_settext 1, "★"
                    count++
                }
                swbreak
    
            case 1
                if flag == 1{
                    flag = 0
                    imgbtn_settext 1, ""
                    imgbtn_settext 0, "★"
                    count++
                }
                swbreak
        swend
 
        switch imgbtn_check_text(lparam, ginfo_intid)
            case "メモ帳を起動"
                exec "notepad.exe"
                swbreak
 
            case "ペイントを起動"
                exec "mspaint.exe"
                swbreak
            
        swend
        
        //title ""+imgbtn_check_text(lparam)+" "+imgbtn_check_id(lparam)
        color 240,240,240
        boxf 00, 20, ginfo_winx,ginfo_winy-80
        color
        font msgothic, 100
        pos 90, 24 : mes count
    }
    
    redraw 1
    return
 
*ON_WM_LBUTTONDOWN
    gmode 7
    font msgothic, 12
    imgbtn_draw WM_LBUTTONDOWN, lparam, ginfo_intid
 
    //※この処理はボタン以外の部分をクリックしながらボタンのあるところまで移動した場合に，
    //　ボタンをクリックすることができるバグを回避するためのものです
    imgbtn_bgc lparam, ginfo_intid        //⇔imgbtn_bgcc
    return
 
 
 
#endif

↑

コメント †

[編集]

OFFICIAL/関連

TUTORIAL

TOPICS

ETC

EDIT

REFERENCE

LOG

お知らせ

HSP Web-Ring

最新の40件

画像ボタン †

関連URL †

コメント †