小ワザ/レーシング/慣性を導入した移動

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
|
|
|
|
|
|
!
 
 
 
-
|
|
|
|
|
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

/* 操作方法
	[Up]          : 加速
	[Left][Right] : 旋回
*/
 
#const PI 3.14159
 
#const AREA_X        320    // 走行エリアの広さ（横）
#const AREA_Y        320    // 走行エリアの広さ（縦）
#const GRID_DISTANCE 32     // グリッドの間隔
#const GRID_NUM_X    11     // グリッドの本数 (= AREA_X / GRID_DISTANCE + 1)
#const GRID_NUM_Y    11     // グリッドの本数 (= AREA_Y / GRID_DISTANCE + 1)
#const CAR_SIZE      12     // 車の長さ
#const ACCELERATION  0.1    // 加速度
#const ANG_SPEED     0.1    // 角速度
#const MAX_SPEED     3.0    // 最高速度
#const AWAIT_TIME    16
 
*init
    screen 0, AREA_X, AREA_Y, 0
    title "慣性を導入した移動"
 
    carX = 10.0 : carY = 10.0   // 車の座標
    carT = PI / 4               // 車の向き
    carSpeed = 0.0              // 車のスピード
    needToDraw = 1              // 描画し直す必要性がある場合は1
 
*main
    gosub *move                 // 車の移動
    gosub *draw                 // 車とグリッドの描画
    await AWAIT_TIME
    goto *main
 
*move
    stick key, %111             // ←↑→が非トリガータイプキー
    gosub *moveCar              // 車の移動
    return
 
*moveCar
    // ■ このサブルーチンが今回のポイント！
 
    // 速度の決定。↑を押せば加速、押さなければ減速
    // "(key & 2) - 1"は↑を押した時は2 - 1 = 1、
    // ↑を押していない時は0 - 1 = -1になる
    carSpeed = limitf(carSpeed + ACCELERATION * ((key & 2) - 1), 0.0, MAX_SPEED)
 
    // 速度がゼロより大きい時は、方向転換を施した上で移動する
    if carSpeed > 0.0 {
        // 方向転換
        carT += ANG_SPEED * ((key & 1) - (key >> 2 & 1))
 
        // 移動（画面からはみ出さないようにlimitf()関数を使っている）
        carX = limitf(carX + carSpeed * cos(carT), 0, AREA_X)
        carY = limitf(carY + carSpeed * sin(carT), 0, AREA_Y)
 
        needToDraw = 1  // 車が移動したので画面を描画し直す必要がある
    }
    return
 
*draw
    if needToDraw {
        redraw 0
        color : boxf
        gosub *drawGrid
        gosub *drawCar
        redraw 1
        if carSpeed == 0.0 : needToDraw = 0
    }
    return
 
// グリッドを描く
*drawGrid
    color 0, 0, 255
    repeat GRID_NUM_Y
        y = cnt * GRID_DISTANCE
        repeat GRID_NUM_X
            x = cnt * GRID_DISTANCE
            line x, AREA_Y, x, 0
            line AREA_X, y, 0, y
        loop
    loop
    return
 
// 車を表示
*drawCar
    color 255
    pos carX, AREA_Y - carY
    line carX - cos(carT + 0.2) * CAR_SIZE, AREA_Y - (carY - sin(carT + 0.2) * CAR_SIZE)
    line carX - cos(carT - 0.2) * CAR_SIZE, AREA_Y - (carY - sin(carT - 0.2) * CAR_SIZE)
    line carX, AREA_Y - carY
    return